build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    ext.kotlin_version = '1.5.31'
    repositories {
        google()
        mavenCentral()
        maven {
            url  "https://dl.bintray.com/ferranpons/maven"
        }
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:7.0.3'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.8.4'
        classpath "org.jfrog.buildinfo:build-info-extractor-gradle:4.9.0"
        classpath "org.jlleitschuh.gradle:ktlint-gradle:10.0.0"
        classpath 'com.ferranpons:twitter-gradle-plugin:1.1.0'

        classpath "io.github.gradle-nexus:publish-plugin:1.1.0"
        classpath("io.codearte.gradle.nexus:gradle-nexus-staging-plugin:0.22.0")
    }
}

plugins {
    id "io.gitlab.arturbosch.detekt" version "1.14.1"
}

detekt {
    failFast = true
    buildUponDefaultConfig = true
    input = files("$projectDir/src/main/java")
    config = files("$rootDir/config/detekt.yml")
    reports {
        xml {
            enabled = true
            destination = file("$projectDir/build/reports/detekt/detekt.xml")
        }
        html {
            enabled = true
            destination = file("$projectDir/build/reports/detekt/detekt.html")
        }
    }
}

allprojects {
    repositories {
        google()
        mavenCentral()
        maven {
            url 'https://artifacts.schibsted.io/artifactory/libs-release'
            credentials {
                username = project.hasProperty('artifactory_user') ? project.artifactory_user :
                        System.getenv()['ARTIFACTORY_USER']
                password = project.hasProperty('artifactory_password') ? project.artifactory_password :
                        System.getenv()['ARTIFACTORY_PWD']
            }
        }
    }
}

tasks.detekt.jvmTarget = "1.8"

apply plugin: 'io.github.gradle-nexus.publish-plugin'
apply from: "${rootDir}/scripts/publish-root.gradle"

task clean(type: Delete) {
    delete rootProject.buildDir
}