umpire-config.cmake.in

##############################################################################
# Copyright (c) 2016-23, Lawrence Livermore National Security, LLC and Umpire
# project contributors. See the COPYRIGHT file for details.
#
# SPDX-License-Identifier: (MIT)
##############################################################################
@PACKAGE_INIT@
  
include(CMakeFindDependencyMacro)

if (@UMPIRE_NEEDS_BLT_TPLS@)
  set(BLT_TGTS "${CMAKE_CURRENT_LIST_DIR}/bltTargets.cmake")
  if(EXISTS "${BLT_TGTS}")
  include("${BLT_TGTS}")
  endif()
  unset(BLT_TGTS)

  if (@UMPIRE_ENABLE_CUDA@ OR @UMPIRE_ENABLE_MPI@)
    find_dependency(Threads)
  endif ()
endif()

if (NOT TARGET camp)
  set(UMPIRE_CAMP_DIR "@camp_DIR@")
  if(NOT camp_DIR) 
    set(camp_DIR ${UMPIRE_CAMP_DIR}) 
  endif()

  find_dependency(camp CONFIG NO_DEFAULT_PATH PATHS 
    ${camp_DIR}
    ${camp_DIR}/lib/cmake/camp
    @PACKAGE_CMAKE_INSTALL_PREFIX@
    @PACKAGE_CMAKE_INSTALL_PREFIX@/lib/cmake/camp)
endif ()

if (@UMPIRE_ENABLE_SQLITE_EXPERIMENTAL@)
  find_package(SQLite3 REQUIRED)
endif()

include("${CMAKE_CURRENT_LIST_DIR}/umpire-targets.cmake")

check_required_components(@PROJECT_NAME@)