build.gradle

plugins {
    id 'application'
    id 'checkstyle'
    id 'jacoco'
    id 'org.springframework.boot' version '2.5.6'
    id 'io.spring.dependency-management' version '1.0.11.RELEASE'
    id 'com.adarshr.test-logger' version '2.1.1'
    id 'com.github.ben-manes.versions' version '0.38.0'
    id 'org.liquibase.gradle' version '2.0.4'
    // Плагины для openapi
    id 'com.github.johnrengelman.processes' version '0.5.0'
    id 'org.springdoc.openapi-gradle-plugin' version '1.3.3'
    // Сборщик фронтенда
    id 'org.siouan.frontend-jdk11' version '6.0.0'
}

group = 'hackathon.ru'

application {
    mainClass = 'hackathon.ru.AppApplication'
}

repositories {
    mavenCentral()
}

dependencies {
    testImplementation 'org.projectlombok:lombok:1.18.22'
    compileOnly 'org.projectlombok:lombok:1.18.22'

    annotationProcessor(
            'org.projectlombok:lombok:1.18.22',
            'com.querydsl:querydsl-apt:5.0.0:jpa',
            'javax.annotation:javax.annotation-api:1.3.2',
            'org.hibernate.javax.persistence:hibernate-jpa-2.1-api:1.0.2.Final'
    )
    developmentOnly 'org.springframework.boot:spring-boot-devtools'

    implementation(
            'org.springframework.boot:spring-boot-starter-mail',
            'org.springframework.boot:spring-boot-starter-data-jpa',
            'org.springframework.boot:spring-boot-starter-web',
            'org.springframework.boot:spring-boot-starter-actuator',
            'org.springframework.boot:spring-boot-starter-validation',
            'org.springframework.boot:spring-boot-starter-security',
            'io.jsonwebtoken:jjwt:0.9.1',
            'org.springdoc:springdoc-openapi-ui:1.5.12',
            'org.liquibase:liquibase-core:4.6.1',
            'com.querydsl:querydsl-core:5.0.0',
            'com.querydsl:querydsl-jpa:5.0.0',
            'com.rollbar:rollbar-spring-boot-webmvc:1.8.1',

            'com.google.api-client:google-api-client:2.0.0',
            'com.google.oauth-client:google-oauth-client-jetty:1.34.1',
            'com.google.apis:google-api-services-calendar:v3-rev20220715-2.0.0'
    )

    liquibaseRuntime(
            sourceSets.main.output,
            'org.liquibase:liquibase-core:4.6.1',
            'org.liquibase.ext:liquibase-hibernate5:4.5.0',
            'org.springframework.boot:spring-boot-starter-data-jpa'
    )

    runtimeOnly (
            'com.h2database:h2:1.4.200',
            'org.postgresql:postgresql:42.2.24'
    )

}

task stage(dependsOn: [clean, installDist])
installDist.mustRunAfter clean

wrapper {
    gradleVersion = '7.6'
    distributionType = Wrapper.DistributionType.ALL
}

compileJava {
    options.release = 17
    options.encoding = 'UTF-8'
}


// Настраиваем таску diffChangeLog таким образом,
// чтобы миграции учитывали изменения в моделях
diffChangeLog {
    dependsOn compileJava
}

// Настраиваем Liquibase
liquibase {
    activities {
        main {
            // Указываем путь, по которому будет сгенерирован файл миграции
            changeLogFile 'src/main/resources/db/changelog/changelog-master.xml'
            // Указывем источник, с которым будут сравниваться изменения
            // Это база данных, изначально она пустая
            url 'jdbc:h2:./hrManager'
            // Имя пользователя и пароль для подключения к базе
            username 'sa'
            password ''
            // Сравниваем с моделями, задавая пакет
            referenceUrl 'hibernate:spring:hackathon.ru.data.model' +
                    // Указываем диалект
                    '?dialect=org.hibernate.dialect.H2Dialect' +
                    // Указываем правила именования таблиц и столбцов,
                    // чтобы они соответствовали правилам Spring
                    '&hibernate.physical_naming_strategy=org.springframework.boot.orm.jpa.hibernate.SpringPhysicalNamingStrategy'
        }
    }
}