openwebrx: add package

lists/to-release

@@ -0,0 +1,5 @@
+owrx_connector
+python-js8py
+python-pycsdr
+csdr
+openwebrx

packages/csdr/PKGBUILD

@@ -0,0 +1,47 @@
+# This file is part of BlackArch Linux ( https://www.blackarch.org/ ).
+# See COPYING for license details.
+
+pkgname=csdr
+pkgver=0.18.2.r68.g1f15b8c
+pkgrel=1
+pkgdesc='A simple DSP library and command-line tool for Software Defined Radio.'
+arch=('x86_64' 'aarch64')
+groups=('blackarch' 'blackarch-radio')
+url='https://github.com/jketterl/csdr'
+license=('GPL-3.0')
+depends=('fftw' 'libsamplerate')
+makedepends=('git' 'gcc')
+source=("git+https://github.com/jketterl/$pkgname.git")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+
+  ( set -o pipefail
+    git describe --long --tags --abbrev=7 2>/dev/null |
+      sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+    printf "%s.%s" "$(git rev-list --count HEAD)" \
+      "$(git rev-parse --short=7 HEAD)"
+  )
+}
+
+build() {
+  cd $pkgname
+
+  mkdir build
+  cd build
+  cmake -DCMAKE_INSTALL_PREFIX=/usr ..
+
+  make
+}
+
+package() {
+  cd $pkgname/build
+
+  make DESTDIR="$pkgdir" install
+
+  cd ..
+
+  install -Dm 644 -t "$pkgdir/usr/share/doc/$pkgname/" *.md
+}
+

packages/openwebrx/PKGBUILD

@@ -0,0 +1,45 @@
+# This file is part of BlackArch Linux ( https://www.blackarch.org/ ).
+# See COPYING for license details.
+
+pkgname=openwebrx
+pkgver=1.2.2.r387.ga9f47be
+pkgrel=1
+pkgdesc='Open source, multi-user SDR receiver software with a web interface.'
+arch=('any')
+groups=('blackarch' 'blackarch-radio')
+url='https://github.com/jketterl/openwebrx'
+license=('AGPL-3.0')
+depends=('python' 'python-pycsdr' 'csdr' 'airspyhf' 'libsdrplay' 'rtl-sdr'
+         'python-js8py' 'owrx_connector' 'netcat')
+makedepends=('git' 'python-setuptools')
+optdepends=('sox' 'mbelib' 'digiham' 'dsd' 'codec2' 'direwolf')
+backup=('etc/openwebrx/openwebrx.conf')
+source=("git+https://github.com/jketterl/$pkgname.git")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+
+  ( set -o pipefail
+    git describe --long --tags --abbrev=7 2>/dev/null |
+      sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+    printf "%s.%s" "$(git rev-list --count HEAD)" \
+      "$(git rev-parse --short=7 HEAD)"
+  )
+}
+
+build() {
+  cd $pkgname
+
+  python setup.py build
+}
+
+package() {
+  cd $pkgname
+
+  python setup.py install --root="$pkgdir" --prefix=/usr -O1 --skip-build
+  install -Dm 644 openwebrx.conf "$pkgdir/etc/openwebrx/openwebrx.conf"
+  install -Dm 644 systemd/openwebrx.service "$pkgdir/usr/lib/systemd/system/openwebrx.service"
+  install -dm 755 "$pkgdir/var/lib/openwebrx"
+}
+

packages/owrx_connector/PKGBUILD

@@ -0,0 +1,46 @@
+# This file is part of BlackArch Linux ( https://www.blackarch.org/ ).
+# See COPYING for license details.
+
+pkgname=owrx_connector
+pkgver=0.6.2.r26.g03d5b97
+pkgrel=1
+pkgdesc='Connectors used by OpenWebRX to interface with SDR hardware.'
+arch=('x86_64')
+url='https://github.com/jketterl/owrx_connector'
+license=('GPL-3.0')
+depends=('csdr' 'libsamplerate')
+makedepends=('git' 'cmake')
+optdepends=(
+	'rtl-sdr: RTLSDR dongles support.'
+	'soapysdr: Allows interfacing with SDRs of many vendors.'
+)
+source=("git+https://github.com/jketterl/$pkgname.git")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+
+  ( set -o pipefail
+    git describe --long --tags --abbrev=7 2>/dev/null |
+      sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+    printf "%s.%s" "$(git rev-list --count HEAD)" \
+      "$(git rev-parse --short=7 HEAD)"
+  )
+}
+
+build() {
+  cd $pkgname
+
+  cmake -B build \
+	  -DCMAKE_INSTALL_PREFIX=/usr \
+	  -Wno-dev
+
+  make -C build
+}
+
+package() {
+  cd $pkgname
+
+  make -C build DESTDIR="$pkgdir" install
+}
+

packages/python-js8py/PKGBUILD

@@ -0,0 +1,46 @@
+# This file is part of BlackArch Linux ( https://www.blackarch.org/ ).
+# See COPYING for license details.
+
+pkgname=python-js8py
+_pkgname=${pkgname#python-}
+pkgver=0.1.2.r6.gf7e394b
+pkgrel=1
+pkgdesc='Python module for parsing messages from the "js8" command line decoder.'
+arch=('x86_64')
+url="https://github.com/jketterl/js8py"
+license=('GPL-3.0')
+makedepends=('git' 'python-setuptools' 'python-nose')
+depends=('python')
+provides=('js8py')
+source=("git+https://github.com/jketterl/$_pkgname.git")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd $_pkgname
+
+  ( set -o pipefail
+    git describe --long --tags --abbrev=7 2>/dev/null |
+      sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+    printf "%s.%s" "$(git rev-list --count HEAD)" \
+      "$(git rev-parse --short=7 HEAD)"
+  )
+}
+
+check(){
+  cd $_pkgname
+
+  nosetests
+}
+
+build() {
+  cd $_pkgname
+
+  python setup.py build
+}
+
+package() {
+  cd $_pkgname
+
+  python setup.py install --root="$pkgdir" --prefix=/usr -O1 --skip-build
+}
+

packages/python-pycsdr/PKGBUILD

@@ -0,0 +1,40 @@
+# This file is part of BlackArch Linux ( https://www.blackarch.org/ ).
+# See COPYING for license details.
+
+pkgname=python-pycsdr
+_pkgname=${pkgname#python-}
+pkgver=0.18.2.r44.g041986e
+pkgrel=1
+pkgdesc='Python bindings for the csdr library.'
+arch=('x86_64' 'aarch64')
+groups=('blackarch' 'blackarch-radio')
+url='https://github.com/jketterl/pycsdr'
+license=('AGPL-3.0')
+depends=('python')
+makedepends=('git' 'csdr' 'python-setuptools')
+source=("git+https://github.com/jketterl/$_pkgname.git")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd $_pkgname
+
+  ( set -o pipefail
+    git describe --long --tags --abbrev=7 2>/dev/null |
+      sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+    printf "%s.%s" "$(git rev-list --count HEAD)" \
+      "$(git rev-parse --short=7 HEAD)"
+  )
+}
+
+build() {
+  cd $_pkgname
+
+  python setup.py build
+}
+
+package() {
+  cd $_pkgname
+
+  python setup.py install --root="$pkgdir" --prefix=/usr -O1 --skip-build
+}
+