Objects.simba

type
  TRSObject = record
    ID: Int32;
    Tile: RSTile;
    ObjectType: RSObjectType;
    Name: String;
  end;

{*
R_FindObject
~~~~~~~~~~~~~~~~~~~~~~
Returns a TRSObject of object on a specific tile.
  RSObjectTypes:
    - GAME_OBJECT
    - WALL_DECORATION
    - BOUNDARY_OBJECT
    - FLOOR_DECORATION

Example:
  Bank := R_FindObject(GAME_OBJECT, 2403, 3452);
*}
Function R_FindObject(ObjectType: RSObjectType; X, Y: Int32): TRSObject;
var
  Obj: RSObject;
  Definition: RSObjectDefinition;
begin
  Obj := RSObject.Get(ObjectType, X, Y);
  if Obj.ref <> nil then
  begin
    Definition := Obj.Definition;
    Result.ID := Obj.ID;
    Result.Tile := Obj.Tile;
    Result.ObjectType := ObjectType;

    if Definition.ref <> nil then
    begin
      Result.Name := Definition.Name;
      Definition.Free;
    end;

    Obj.Free;
  end;
end;

{*
R_FindObject
~~~~~~~~~~~~~~~~~~~~~~
Returns an array of TRSObject of the specified ID and Object Type.
  RSObjectTypes:
    - GAME_OBJECT
    - WALL_DECORATION
    - BOUNDARY_OBJECT
    - FLOOR_DECORATION

Example:
  Trees := R_FindObject(1342, GAME_OBJECT);
*}
Function R_FindObjects(ID: Int32; ObjectType: RSObjectType): Array of TRSObject; overload;
var
  I, J: Int32;
  Objects: Array of RSObject;
  Definition: RSObjectDefinition;
begin
  Objects := RSObject.Get(ObjectType);
  SetLength(Result, Length(Objects));

  For I := 0 to High(Objects) do
  begin
    If Objects[I].ID = ID then
    begin
      Definition := Objects[I].Definition;
      Result[J].ID := ID;
      Result[J].Tile := Objects[I].Tile;
      Result[J].ObjectType := ObjectType;

      if Definition.ref <> nil then
      begin
        Result[J].Name := Definition.Name;
        Definition.Free;
      end;
      Inc(J);
    end;
    Objects[I].Free;
  end;
  SetLength(Result, J);
end;

{*
R_FindObject
~~~~~~~~~~~~~~~~~~~~~~
Returns an array of TRSObject of the specified Object Type.
  RSObjectTypes:
    - GAME_OBJECT
    - WALL_DECORATION
    - BOUNDARY_OBJECT
    - FLOOR_DECORATION

Example:
  AllObjects := R_FindObject(GAME_OBJECT);
*}
Function R_FindObjects(ObjectType: RSObjectType): Array of TRSObject; overload;
var
  I: Int32;
  Objects: Array of RSObject;
  Definition: RSObjectDefinition;
begin
  Objects := RSObject.Get(ObjectType);
  SetLength(Result, Length(Objects));

  For I := 0 to High(Objects) do
  begin
    Definition := Objects[I].Definition;
    Result[I].ID := Objects[I].ID;
    Result[I].Tile := Objects[I].Tile;
    Result[I].ObjectType := ObjectType;

    if Definition.ref <> nil then
    begin
      Result[I].Name := Definition.Name;
      Definition.Free;
    end;
    Objects[I].Free;
  end;
end;