Error in QT when include target_link_libraries(cloud_analizer PUBLIC CGAL::CGAL_Basic_viewer) in CMakeLists.txt

[DarkSun812]

I have tried to add CGAL in a project that I have in Qt6 but if I include CGAL I get an error that according to my research, is because it does not find QObject, but I am also including Core which is supposed to be where QObject goes.

CMakeLists.txt file

cmake_minimum_required(VERSION 3.5)

project(cloud_analizer VERSION 0.1 LANGUAGES CXX)

set(CMAKE_AUTOUIC ON)
set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTORCC ON)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

find_package(QT NAMES Qt6 Qt5 REQUIRED COMPONENTS Widgets Core Gui Concurrent Sql WebSockets WebChannel WebEngineWidgets WebView)
find_package(Qt${QT_VERSION_MAJOR} REQUIRED COMPONENTS Widgets Core Gui Concurrent Sql WebSockets WebChannel WebEngineWidgets WebView)

set(CGAL_DIR "C:/dev/CGAL-6.0/lib/cmake/CGAL")
find_package(CGAL REQUIRED COMPONENTS Qt6 Core)

include_directories("C:/Program Files/MySql/MySQL Server 8.0/include")
include_directories("C:/Program Files/boost/boost_1_83_0")

link_directories("C:/Program Files/MySql/MySQL Server 8.0/lib")
link_directories("C:/Program Files/boost/boost_1_83_0/lib")


set(PROJECT_SOURCES
        main.cpp
        mainwindow.cpp
        mainwindow.h
        mainwindow.ui
)

if(${QT_VERSION_MAJOR} GREATER_EQUAL 6)
    qt_add_executable(cloud_analizer
        MANUAL_FINALIZATION
        ${PROJECT_SOURCES}
        api.h api.cpp
        funciones_standar.h funciones_standar.cpp
        cloudfunctions.h cloudfunctions.cpp
        cloudserver.h cloudserver.cpp
    )
# Define target properties for Android with Qt 6 as:
#    set_property(TARGET cloud_analizer APPEND PROPERTY QT_ANDROID_PACKAGE_SOURCE_DIR
#                 ${CMAKE_CURRENT_SOURCE_DIR}/android)
# For more information, see https://doc.qt.io/qt-6/qt-add-executable.html#target-creation
else()
    if(ANDROID)
        add_library(cloud_analizer SHARED
            ${PROJECT_SOURCES}
        )
# Define properties for Android with Qt 5 after find_package() calls as:
#    set(ANDROID_PACKAGE_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/android")
    else()
        add_executable(cloud_analizer
            ${PROJECT_SOURCES}
        )
    endif()
endif()

if(CGAL_Qt6_FOUND)
  target_link_libraries(cloud_analizer PRIVATE Qt${QT_VERSION_MAJOR}::Widgets Qt6::WebView Qt6::Core Qt6::Gui Qt6::Concurrent Qt6::Sql Qt6::WebSockets Qt6::WebChannel Qt6::WebEngineWidgets mysqlclient)
  target_link_libraries(cloud_analizer PRIVATE CGAL::CGAL_Basic_viewer)
else()
  target_link_libraries(cloud_analizer PRIVATE Qt${QT_VERSION_MAJOR}::Widgets Qt6::WebView Qt6::Core Qt6::Gui Qt6::Concurrent Qt6::Sql Qt6::WebSockets Qt6::WebChannel Qt6::WebEngineWidgets mysqlclient)
  message(STATUS "NOTICE: Several examples require Qt6 and will not be compiled.")
endif()
# Qt for iOS sets MACOSX_BUNDLE_GUI_IDENTIFIER automatically since Qt 6.1.
# If you are developing for iOS or macOS you should consider setting an
# explicit, fixed bundle identifier manually though.
if(${QT_VERSION} VERSION_LESS 6.1.0)
  set(BUNDLE_ID_OPTION MACOSX_BUNDLE_GUI_IDENTIFIER com.example.cloud_analizer)
endif()
set_target_properties(cloud_analizer PROPERTIES
    ${BUNDLE_ID_OPTION}
    MACOSX_BUNDLE_BUNDLE_VERSION ${PROJECT_VERSION}
    MACOSX_BUNDLE_SHORT_VERSION_STRING ${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR}
    MACOSX_BUNDLE TRUE
    WIN32_EXECUTABLE TRUE
)

include(GNUInstallDirs)
install(TARGETS cloud_analizer
    BUNDLE DESTINATION .
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)


if(QT_VERSION_MAJOR EQUAL 6)
    qt_finalize_executable(cloud_analizer)
endif()

By adding the lines

set(CGAL_DIR "C:/dev/CGAL-6.0/lib/cmake/CGAL")
find_package(CGAL REQUIRED COMPONENTS Qt6 Core)

mainwindows.h File

#ifndef MAINWINDOW_H
#define MAINWINDOW_H

#include <QMainWindow>
#include <QObject>
#include <QtWebSockets/QtWebSockets>
#include "cloudfunctions.h"

QT_BEGIN_NAMESPACE
namespace Ui {
class MainWindow;
}
QT_END_NAMESPACE
class CloudFunctions;

class MainWindow : public QMainWindow
{
    Q_OBJECT

public:

    MainWindow(QWidget *parent = nullptr);
    ~MainWindow();
private slots:
    void testSlot();


private:
    Ui::MainWindow *ui;
    CloudFunctions *mCloud;

};

class DataObject : public QObject
{
    Q_OBJECT
public:

    Q_INVOKABLE QStringList getData() const {

        return QStringList() <<"value1";
    }
};
#endif // MAINWINDOW_H

From these two lines, you start to ignore private slots: and many other lines.

[lrineau]

That is because CGAL::CGAL_Basic_viewer enforces the definition of the preprocessor macro QT_NO_KEYWORDS.

That means you need to replace:

• slots by Q_SLOTS
• signals by QSIGNALS,
• emit by Q_EMIT, and
• foreach by Q_FOREACH.

... I wonder if that should be considered as a bug for CGAL. We should not enforce our choices to CGAL users.

[DarkSun812]

I don't know if it should be a bug, but at least there should be that warning along with an example of how QObject should be used for users who want to do that integration.

Before reading your answer, I changed CGAL::CGAL_Basic_viewer to CGAL::CGAL and it no longer gave me errors, but I would like to know what is involved in making this change, what differences are there when using one or the other in QT6?

[lrineau]

The target CGAL::CGAL_Basic_viewer is created there, in lib/cmake/CGAL/CGALConfig.cmake:

cgal/Installation/lib/cmake/CGAL/CGALConfig.cmake

Lines 200 to 203 in 50cfbde

	add_library(CGAL::CGAL_Basic_viewer INTERFACE IMPORTED GLOBAL)
	set_target_properties(CGAL::CGAL_Basic_viewer PROPERTIES
	INTERFACE_COMPILE_DEFINITIONS "CGAL_USE_BASIC_VIEWER;QT_NO_KEYWORDS"
	INTERFACE_LINK_LIBRARIES CGAL::CGAL_Qt6)

(Sorry for the wrong indentation.) Line 200 creates the target as an imported INTERFACE target (an "empty" target). Lines 201-202 make the consumers of that target add CGAL_USE_BASIC_VIEWER and QT_NO_KEYWORDS as defined preprocessor macros. And the line 203 make consumers link with CGAL::CGAL_Qt6 (that itself depends on CGAL::CGAL).

[DarkSun812]

By simply using

set(CGAL_DIR «C:/dev/CGAL-6.0/lib/cmake/CGAL»)
find_package(CGAL COMPONENTES REQUERIDOS Qt6 Core)
target_link_libraries(cloud_analizer PRIVATE CGAL::CGAL)

I received no more error messages from QT and managed to do a delauny triangulation. The only inconvenience I had now was that the time increased drastically in the construction of the triangle in the Qt implementation being a time of 76 seconds, but in the tests that I had made in VisualStudio 2022 from the example Triangulation_2/terrain that was in CGAL 6.0, it took only 11 seconds, this increase of time can be due to that I incorporate only CGAL::CGAL instead of doing it as you just showed me?

[lrineau]

No, your program probably does not use the CGAL Qt6 support, or even CGAL Core library. You should simplify to:

set(CGAL_DIR "C:/dev/CGAL-6.0/lib/cmake/CGAL")
find_package(CGAL REQUIRED)
target_link_libraries(cloud_analizer PRIVATE CGAL::CGAL)

The difference in timing cannot be explained by any of this. You should check if you are always comparing timings with the same compilation type (Release, Debug and so on). The timings between Debug and Release builds are expected to be very different.

[lrineau]

... I wonder if that should be considered as a bug for CGAL. We should not enforce our choices to CGAL users.

I created the issue #8574.