build.gradle

plugins {
	id 'fabric-loom' version '1.6-SNAPSHOT'
	id 'maven-publish'
	id "me.modmuss50.mod-publish-plugin" version "0.5.1"
}

version = project.mod_version
group = project.maven_group

base {
	archivesName = project.archives_base_name
}

repositories {
	// Add repositories to retrieve artifacts from in here.
	// You should only use this when depending on other mods because
	// Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
	// See https://docs.gradle.org/current/userguide/declaring_repositories.html
	// for more information about repositories.
	maven { url "https://maven.wispforest.io" }
	maven { url "https://maven.axoga.to/releases" }
	maven { url "https://api.modrinth.com/maven" }
}

loom {
	accessWidenerPath = file("src/main/resources/particular.accesswidener")
}

dependencies {
	// To change the versions see the gradle.properties file
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

	// Fabric API. This is technically optional, but you probably want it anyway.
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

	include "io.wispforest:owo-sentinel:${project.owo_version}"
	annotationProcessor modImplementation("io.wispforest:owo-lib:${project.owo_version}")

	modImplementation "com.chailotl:sushi_bar:${project.sushi_version}"

	//modCompileOnly "io.github.lucaargolo:fabric-seasons:${project.seasons_version}"
}

processResources {
	inputs.property "version", project.version
	inputs.property "name", project.mod_name

	filesMatching("fabric.mod.json") {
		expand "version": project.version,
				"name": project.mod_name
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.release = 17
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()

	sourceCompatibility = JavaVersion.VERSION_17
	targetCompatibility = JavaVersion.VERSION_17
}

jar {
	from("LICENSE") {
		rename { "${it}_${project.base.archivesName.get()}"}
	}
}

// configure the maven publication
publishing {
	publications {
		create("mavenJava", MavenPublication) {
			artifactId = project.archives_base_name
			from components.java
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	repositories {
		// Add repositories to publish to here.
		// Notice: This block does NOT have the same function as the block in the top level.
		// The repositories here will be used for publishing your artifact, not for
		// retrieving dependencies.
	}
}

publishMods {
	File changelogFile = new File("CHANGELOG.md")

	file = remapJar.archiveFile
	changelog = changelogFile.exists() ? changelogFile.text : ""
	type = STABLE
	displayName = "${project.mod_name} ${project.mod_version}"
	modLoaders.add("fabric")

	modrinth {
		accessToken = providers.gradleProperty("modrinth_token").get()
		projectId = "B1CcCd9h"
		minecraftVersionRange {
			start = "1.20"
			end = "1.20.4"
		}
		requires("fabric-api")
		requires("owo-lib")
		requires("sushi-bar")
		optional("modmenu")
	}
}