-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathforth.s
4467 lines (3897 loc) · 62.7 KB
/
forth.s
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#define wp a0
#define xp a1
#define yp a2
#define tos a3
#define st a4
#define ss a5
#define rp s0
#define ip s1
#define up tp
.equ sscomp, (1 << 0)
.equ ssdund, (1 << 1)
.equ addrsize, 4
.equ stksize, 20
.equ tasksize, 8
.equ tibsize, 31
.equ RAMBAK_ADDR, 0x3800
.equ RAMBAK_SIZE, 0x800
.equ tip, (0 * addrsize)
.equ tss, (1 * addrsize)
.equ tsp, (2 * addrsize)
.equ tst, (3 * addrsize)
.equ trp, (4 * addrsize)
.equ tnp, (5 * addrsize)
.global _start
_start:
.option norvc;
j reset
.option rvc;
reset:
.equ RCC_BASE, 0x40021000
.equ RCC_CTLR, 0x00
.equ RCC_PLLRDY, (1 << 25)
.equ RCC_PLLON, (1 << 24)
li wp, RCC_BASE
lw xp, RCC_CTLR(wp)
li yp, RCC_PLLON
or xp, xp, yp
sw xp, RCC_CTLR(wp)
li yp, RCC_PLLRDY
.macro nop2
nop
nop
.endm
.macro nop4
nop2
nop2
.endm
.macro nop8
nop4
nop4
.endm
.macro nop16
nop8
nop8
.endm
1:
nop16
lw xp, RCC_CTLR(wp)
and xp, xp, yp
beqz xp, 1b
.equ RCC_CFGR0, 0x04
.equ RCC_SW_MASK, (0x3 << 0)
.equ RCC_SW_PLL, (0x2 << 0)
lw xp, RCC_CFGR0(wp)
li yp, RCC_SW_MASK
xori yp, yp, -1
and xp, xp, yp
ori xp, xp, RCC_SW_PLL
sw xp, RCC_CFGR0(wp)
.equ RCC_HPRE_MASK, (0xF << 4)
.equ RCC_HPRE_NODIV, (0 << 4)
lw xp, RCC_CFGR0(wp)
li yp, RCC_HPRE_MASK
xori yp, yp, -1
and xp, xp, yp
ori xp, xp, RCC_HPRE_NODIV
sw xp, RCC_CFGR0(wp)
.equ RCC_RSTSCKR, 0x24
.equ RCC_LSION, (1 << 0)
.equ RCC_LSIRDY, (1 << 1)
lw xp, RCC_RSTSCKR(wp)
or xp, xp, RCC_LSION
sw xp, RCC_RSTSCKR(wp)
1:
lw xp, RCC_RSTSCKR(wp)
andi xp, xp, RCC_LSIRDY
beqz xp, 1b
# SYSCLK: 48Mhz
# HCLK: 48Mhz
# HSI: 128Khz
.equ RCC_APB2PCENR, 0x18
.equ RCC_AFIOEN, (1 << 0)
.equ RCC_IOPAEN, (1 << 2)
.equ RCC_IOPDEN, (1 << 5)
.equ RCC_USART1EN, (1 << 14)
lw xp, RCC_APB2PCENR(wp)
li yp, RCC_AFIOEN | RCC_IOPAEN | RCC_IOPDEN | RCC_USART1EN
or xp, xp, yp
sw xp, RCC_APB2PCENR(wp)
.equ AFIO_BASE, 0x40010000
.equ AFIO_PCFR1, 0x04
.equ AFIO_UART_MASK, (1 << 21) | (1 << 2)
.equ AFIO_UART_D6TX, (1 << 21) | (0 << 2)
li wp, AFIO_BASE
lw xp, AFIO_PCFR1(wp)
li yp, AFIO_UART_MASK
xori yp, yp, -1
and xp, xp, yp
li yp, AFIO_UART_D6TX
or xp, xp, yp
sw xp, AFIO_PCFR1(wp)
.equ GPIOA_BASE, 0x40010800
.equ GPIO_CFGLR, 0x00
.equ GPIOA2_CFGMASK, (0xF << 8)
.equ GPIOA2_PPOUT_30M, (0x3 << 8)
.equ GPIO_OUTDR, 0x0C
li wp, GPIOA_BASE
lw xp, GPIO_CFGLR(wp)
li yp, GPIOA2_CFGMASK
xori yp, yp, -1
and xp, xp, yp
ori xp, xp, GPIOA2_PPOUT_30M
sw xp, GPIO_CFGLR(wp)
.equ GPIOD_BASE, 0x40011400
.equ GPIOD6_CFGMASK, (0xF << 24)
.equ GPIOD6_ODOUT_MU_30M, (0xF << 24)
li wp, GPIOD_BASE
lw xp, GPIO_CFGLR(wp)
li yp, GPIOD6_CFGMASK
xori yp, yp, -1
and xp, xp, yp
li yp, GPIOD6_ODOUT_MU_30M
or xp, xp, yp
sw xp, GPIO_CFGLR(wp)
// wchlinke max baudrate is 921600
// ch32v003 max baudrate is 3000000
// UART:
// HCLK / (16 * UARTDIV) = BAUDRATE
// 48Mhz / (16 * 3.255) = 921658
// UARTDIV = DIV_M + (DIV_F / 16)
// 3.25 = 3 + (4 / 16)
// DIV_M = 3
// DIV_F = 4
.equ UART1_BASE, 0x40013800
.equ UART_DATAR, 0x04
.equ UART_BRR, 0x08
.equ UART_CTLR1, 0x0C
.equ UART_UE, (1 << 13)
.equ UART_TE, (1 << 3)
.equ UART_RE, (1 << 2)
.equ UART_CTLR3, 0x14
.equ UART_HDSEL, (1 << 3)
.equ BAUD_921600, (3 << 4) | (4 << 0)
.equ BAUD_3000000, (1 << 4) | (0 << 0)
li wp, UART1_BASE
li xp, BAUD_921600
sw xp, UART_BRR(wp)
lw xp, UART_CTLR1(wp)
li yp, UART_UE | UART_TE | UART_RE
or xp, xp, yp
sw xp, UART_CTLR1(wp)
lw xp, UART_CTLR3(wp)
ori xp, xp, UART_HDSEL
sw xp, UART_CTLR3(wp)
// IWDG
.equ IWDG_BASE, 0x40003000
.equ IWDG_CTLR_R16, 0x00
.equ IWDG_PSCR_R16, 0x04
.equ IWDG_RLDR_R16, 0x08
.equ IWDG_STATR_R16, 0xC
.equ IWDG_RVU, (1 << 1)
.equ IWDG_PVU, (1 << 0)
.equ IWDG_KEYFEED, 0xAAAA
.equ IWDG_KEYUNLOCK, 0x5555
.equ IWDG_KEYON, 0xCCCC
li wp, IWDG_BASE
li xp, IWDG_KEYUNLOCK
sh xp, IWDG_CTLR_R16(wp)
.equ IWDG_DIVMASK, 0x7
.equ IWDG_DIV256, 0x6
1:
lhu xp, IWDG_STATR_R16(wp)
andi xp, xp, IWDG_PVU
bnez xp, 1b
li yp, IWDG_DIVMASK
xori yp, yp, -1
lhu xp, IWDG_PSCR_R16(wp)
and xp, xp, yp
li yp, IWDG_DIV256
or xp, xp, yp
sh xp, IWDG_PSCR_R16(wp)
1:
lw xp, IWDG_STATR_R16(wp)
andi xp, xp, IWDG_RVU
bnez xp, 1b
li xp, -1
sh xp, IWDG_RLDR_R16(wp)
// set vector
la wp, _ram_entry
ori wp, wp, 0x2
csrw mtvec, wp
// enable global interrupt and configure privileged mode
li wp, 0x1880
csrw mstatus, wp
// not enable hardware stack, mainline gcc compiler not suppot this
// not enable interrupt nesting
// PFIC
.equ PFIC_BASE, 0xE000E000
.equ PFIC_IENR1,0x100
.equ IRQ_STK, 12
li wp, PFIC_BASE
lw xp, PFIC_IENR1(wp)
li yp, (1 << IRQ_STK)
or xp, xp, yp
sw xp, PFIC_IENR1(wp)
.equ PFIC_IENR2,0x104
.equ IRQ_UART1, 0
lw xp, PFIC_IENR2(wp)
li yp, (1 << IRQ_UART1)
or xp, xp, yp
sw xp, PFIC_IENR2(wp)
// systick
.equ STK_BASE, 0xE000F000
.equ STK_CTLR, 0x00
.equ STK_SR, 0x04
.equ STK_CNTL, 0x08
.equ STK_CMPLR,0x10
.equ STK_SWIE, (1 << 31)
.equ STK_STRE, (1 << 3)
.equ STK_HCLK, (1 << 2)
.equ STK_HCLKDIV8, (0 << 2)
.equ STK_STIE, (1 << 1)
.equ STK_STEN, (1 << 0)
.equ ESIG_BASE, 0x1FFFF700
.equ ESIG_UNIID1, 0xE8
.equ ESIG_UNIID2, 0xEC
.equ ESIG_UNIID3, 0xF0
.macro next
j a_next
.endm
.equ sram_base, 0x20000000
.equ sram_size, (2 * 1024)
li wp, sram_base
li xp, sram_size
li yp, -1
// fill 0xFF into sram
2:
beqz xp, 1f
sw yp, 0(wp)
addi wp, wp, addrsize
addi xp, xp, -addrsize
j 2b
1:
la wp, ycount
sw zero, 0(wp)
la wp, irqcount
sw zero, 0(wp)
la wp, mscountl
sw zero, 0(wp)
la wp, mscounth
sw zero, 0(wp)
la wp, _ram_entry
la xp, irq_handler
sw xp, 0(wp)
// jump to forth
la wp, forth
csrw mepc, wp
mret
.set lastword, 0
.equ link_mask, (0x20003FFC)
.equ nlen_shift, 16
.equ nlen_mask, (0xF << nlen_shift)
.equ attr_immed, (1 << 0)
.macro wdef label, name, entry, link, attr
.p2align 2, 0xFF
h_\label:
.word \link + nlen_shift_\label + \attr
f_\label:
.word \entry
n_\label:
.ascii "\name"
n_end_\label:
.set nlen_\label, (n_end_\label - n_\label)
.set nlen_shift_\label, (nlen_\label << nlen_shift)
.set lastword, f_\label
.p2align 2, 0xFF
p_\label:
.endm
.equ UART_STATR, 0x00
.equ UART_TC, (1 << 6)
early_txc:
li wp, UART1_BASE
1:
lw xp, UART_STATR(wp)
andi xp, xp, UART_TC
beqz xp, 1b
sw tos, UART_DATAR(wp)
ret
wdef fail, "fail", a_fail, 0, 0
a_fail:
li tos, 'F'
call early_txc
li tos, 'A'
call early_txc
li tos, 'I'
call early_txc
li tos, 'L'
call early_txc
1:
j 1b
wdef okay, "okay", a_okay, f_fail, 0
a_okay:
li tos, 'O'
call early_txc
li tos, 'K'
call early_txc
1:
j 1b
wdef next, "next", a_next, f_okay, 0
a_next:
lw wp, 0(ip)
addi ip, ip, addrsize
lw xp, 0(wp)
jr xp
dpop:
addi sp, sp, addrsize
ble sp, st, 1f
ori ss, ss, ssdund
1:
lw tos, 0(sp)
ret
dpush:
sw tos, 0(sp)
addi sp, sp, -addrsize
ret
rpop:
addi rp, rp, addrsize
lw tos, 0(rp)
ret
rpush:
sw tos, 0(rp)
addi rp, rp, -addrsize
ret
wdef call, "call", a_call, f_next, 0
a_call:
mv tos, ip
call rpush
lw xp, -addrsize(wp)
li yp, nlen_mask
and xp, xp, yp
srli xp, xp, nlen_shift
addi xp, xp, ((-1) + addrsize + addrsize)
andi xp, xp, -addrsize
add ip, wp, xp
next
wdef exit, "exit", a_exit, f_call, 0
a_exit:
call rpop
mv ip, tos
next
wdef noop, "noop", a_call, f_exit, 0
.word f_exit
wdef branch, "branch", a_branch, f_noop, 0
a_branch:
lw ip, 0(ip)
next
wdef branch0, "branch0", a_branch0, f_branch, 0
a_branch0:
call dpop
bnez tos, 1f
lw ip, 0(ip)
next
1:
addi ip, ip, addrsize
next
wdef lit, "lit", a_lit, f_branch0, 0
a_lit:
lw tos, 0(ip)
call dpush
addi ip, ip, addrsize
next
tasksave:
sw ip, tip(up)
sw ss, tss(up)
sw sp, tsp(up)
sw st, tst(up)
sw rp, trp(up)
ret
taskload:
lw ip, tip(up)
lw ss, tss(up)
lw sp, tsp(up)
lw st, tst(up)
lw rp, trp(up)
ret
wdef yield, "yield", a_yield, f_lit, 0
a_yield:
call tasksave
la wp, ycount
lw xp, 0(wp)
addi xp, xp, 1
sw xp, 0(wp)
lw up, tnp(up)
call taskload
next
wdef txava, "tx?", a_txava, f_yield, 0
a_txava:
li wp, UART1_BASE
lw xp, UART_STATR(wp)
andi xp, xp, UART_TC
bnez xp, 1f
mv tos, zero
call dpush
next
1:
li tos, -1
call dpush
next
wdef drop, "drop", a_drop, f_txava, 0
a_drop:
call dpop
next
wdef dup, "dup", a_dup, f_drop, 0
a_dup:
call dpop
call dpush
call dpush
next
wdef equ, "=", a_equ, f_dup, 0
a_equ:
call dpop
mv wp, tos
call dpop
beq wp, tos, 1f
mv tos, zero
call dpush
next
1:
li tos, -1
call dpush
next
wdef 2lit, "2lit", a_2lit, f_equ, 0
a_2lit:
lw tos, 0(ip)
call dpush
addi ip, ip, addrsize
lw tos, 0(ip)
call dpush
addi ip, ip, addrsize
next
wdef failez, "failez", a_call, f_2lit,0
.word f_lit
.word 0
.word f_equ
.word f_branch0
.word 1f
.word f_fail
1:
.word f_exit
wdef failnz, "failnz", a_call, f_failez, 0
.word f_lit
.word 0
.word f_equ
.word f_branch0
.word 1f
.word f_exit
1:
.word f_fail
.word f_exit
wdef txfill, "txfill", a_txfill, f_failnz, 0
a_txfill:
li wp, UART1_BASE
call dpop
sw tos, UART_DATAR(wp)
next
wdef txwait, "txwait", a_call, f_txfill, 0
1:
.word f_yield
.word f_txava
.word f_branch0
.word 1b
.word f_exit
wdef txc, "txc", a_call, f_txwait, 0
.word f_txwait
.word f_txfill
.word f_txwait
.word f_exit
wdef emit, "emit", a_call, f_txc, 0
.word f_txc
.word f_exit
wdef add, "+", a_add, f_emit, 0
a_add:
call dpop
mv wp, tos
call dpop
add tos, tos, wp
call dpush
next
wdef inc, "1+", a_call, f_add, 0
.word f_lit
.word 1
.word f_add
.word f_exit
wdef sub, "-", a_sub, f_inc, 0
a_sub:
call dpop
mv wp, tos
call dpop
sub tos, tos, wp
call dpush
next
wdef dec, "1-", a_call, f_sub, 0
.word f_lit
.word 1
.word f_sub
.word f_exit
wdef cload, "c@", a_cload, f_dec, 0
a_cload:
call dpop
lbu tos, 0(tos)
call dpush
next
wdef 2drop, "2drop", a_call, f_cload, 0
.word f_drop
.word f_drop
.word f_exit
wdef swap, "swap", a_swap, f_2drop, 0
a_swap:
call dpop
mv wp, tos
call dpop
mv xp, tos
mv tos, wp
call dpush
mv tos, xp
call dpush
next
wdef type, "type", a_call, f_swap, 0
2:
.word f_dup
.word f_branch0
.word 1f
.word f_dec
.word f_swap
.word f_dup
.word f_cload
.word f_emit
.word f_inc
.word f_swap
.word f_branch
.word 2b
1:
.word f_2drop
.word f_exit
wdef stget, "st@", a_stget, f_type, 0
a_stget:
mv tos, st
call dpush
next
wdef spget, "sp@", a_spget, f_stget, 0
a_spget:
mv tos, sp
call dpush
next
wdef doconst, "doconst", a_doconst, f_spget, 0
a_doconst:
lw xp, -addrsize(wp)
li yp, nlen_mask
and xp, xp, yp
srli xp, xp, nlen_shift
addi xp, xp, ((-1) + addrsize + addrsize)
andi xp, xp, -addrsize
add wp, wp, xp
lw tos, 0(wp)
call dpush
next
wdef cell, "cell", a_doconst, f_doconst, 0
.word addrsize
wdef dzchk, "dzchk", a_dzchk, f_cell, 0
a_dzchk:
bne sp, st, a_fail
andi ss, ss, ssdund
bnez ss, a_fail
next
wdef rshift, "rshift", a_rshift, f_dzchk, 0
a_rshift:
call dpop
mv wp, tos
call dpop
srl tos, tos, wp
call dpush
next
wdef 2div, "2/", a_call, f_rshift, 0
.word f_lit
.word 1
.word f_rshift
.word f_exit
wdef celldiv, "cell/", a_call, f_2div, 0
.word f_lit
.word 2
.word f_rshift
.word f_exit
wdef depth, "depth", a_call, f_celldiv, 0
.word f_spget
.word f_stget
.word f_swap
.word f_sub
.word f_celldiv
.word f_exit
wdef and, "and", a_and, f_depth, 0
a_and:
call dpop
mv wp, tos
call dpop
and tos, tos, wp
call dpush
next
xdigits:
.ascii "0123456789ABCDEF"
.p2align 2, 0
wdef num2hex, "num2hex", a_call, f_and, 0
.word f_lit
.word 0xF
.word f_and
.word f_lit
.word xdigits
.word f_add
.word f_cload
.word f_exit
wdef hex4, "hex4", a_call, f_num2hex, 0
.word f_num2hex
.word f_emit
.word f_exit
wdef hex8, "hex8", a_call, f_hex4, 0
.word f_dup
.word f_lit
.word 4
.word f_rshift
.word f_hex4
.word f_hex4
.word f_exit
wdef hex16, "hex16", a_call, f_hex8, 0
.word f_dup
.word f_lit
.word 8
.word f_rshift
.word f_hex8
.word f_hex8
.word f_exit
wdef hex32, "hex32", a_call, f_hex16, 0
.word f_dup
.word f_lit
.word 16
.word f_rshift
.word f_hex16
.word f_hex16
.word f_exit
wdef load, "@", a_load, f_hex32, 0
a_load:
call dpop
lw tos, 0(tos)
call dpush
next
wdef dsdump, ".s", a_call, f_load, 0
.word f_depth
.word f_lit
.word '('
.word f_emit
.word f_hex8
.word f_lit
.word ')'
.word f_emit
.word f_depth
.word f_stget
.word f_swap
2:
.word f_dup
.word f_branch0
.word 1f
.word f_dec
.word f_swap
.word f_dup
.word f_load
.word f_hex32
.word f_lit
.word ' '
.word f_emit
.word f_cell
.word f_sub
.word f_swap
.word f_branch
.word 2b
1:
.word f_2drop
.word f_exit
wdef rxava, "rx?", a_rxava, f_dsdump, 0
a_rxava:
.equ UART_RXNE, (1 << 5)
li wp, UART1_BASE
lw xp, UART_STATR(wp)
andi xp, xp, UART_RXNE
bnez xp, 1f
mv tos, zero
call dpush
next
1:
li tos, -1
call dpush
next
wdef rxwait, "rxwait", a_call, f_rxava, 0
1:
.word f_yield
.word f_rxava
.word f_branch0
.word 1b
.word f_exit
wdef rxread, "rxread", a_rxread, f_rxwait, 0
a_rxread:
li wp, UART1_BASE
lw tos, UART_DATAR(wp)
call dpush
next
wdef rxc, "rxc", a_call, f_rxread, 0
.word f_rxwait
.word f_rxread
.word f_exit
wdef key, "key", a_call, f_rxc, 0
.word f_rxc
.word f_exit
wdef or, "or", a_or, f_key, 0
a_or:
call dpop
mv wp, tos
call dpop
or tos, tos, wp
call dpush
next
wdef isnl, "isnl", a_call, f_or, 0
.word f_dup
.word f_lit
.word '\n'
.word f_equ
.word f_swap
.word f_lit
.word '\r'
.word f_equ
.word f_or
.word f_exit
wdef isdel, "isdel", a_call, f_isnl, 0
.word f_dup
.word f_lit
.word '\b'
.word f_equ
.word f_swap
.word f_lit
.word 0x7F
.word f_equ
.word f_or
.word f_exit
wdef tib, "tib", a_doconst, f_isdel, 0
.word tib
wdef toin, ">in", a_doconst, f_tib, 0
.word toin
.equ ROM_BASE, 0x00000000
.equ ROM_END, ROM_BASE + (16 * 1024)
wdef inrom, "inrom", a_call, f_toin, 0
.word f_2lit
.word ROM_BASE
.word ROM_END
.word f_within
.word f_exit
wdef store, "!", a_call, f_inrom, 0
.word f_dup
.word f_inrom
.word f_branch0
.word 1f
.word f_rom32store
.word f_exit
1:
.word f_mem32store
.word f_exit
wdef mem32store, "mem32!", a_mem32store, f_store, 0
a_mem32store:
call dpop
mv wp, tos
call dpop
sw tos, 0(wp)
next
wdef toinchk, ">inchk", a_toinchk, f_store, 0
a_toinchk:
la wp, tib
la xp, tib_top
sub wp, xp, wp
la xp, toin
lw xp, 0(xp)
bltz xp, 1f
bge xp, wp, 1f
li tos, -1
call dpush
next
1:
mv tos, zero
call dpush
next
wdef toinrst, ">inrst", a_call, f_toinchk, 0
.word f_lit
.word 0
.word f_toin
.word f_store
.word f_exit
wdef toinload, ">in@", a_call, f_toinrst, 0
.word f_toin
.word f_load
.word f_exit
wdef cstore, "c!", a_cstore, f_toinload, 0
a_cstore:
call dpop
mv wp, tos
call dpop
sb tos, 0(wp)
next
wdef tipush, "tipush", a_call, f_cstore, 0
.word f_toinchk
.word f_branch0
.word 1f
.word f_tib
.word f_toinload
.word f_add
.word f_cstore
.word f_toinload
.word f_inc
.word f_toin
.word f_store
.word f_exit
1:
.word f_drop
.word f_exit
wdef tidrop, "tidrop", a_call, f_tipush, 0
.word f_toinchk
.word f_branch0
.word 1f
.word f_toinload
.word f_branch0
.word 1f
.word f_toinload
.word f_dec
.word f_toin
.word f_store
1:
.word f_exit
wdef cr, "cr", a_call, f_tidrop, 0
.word f_2lit
.word '\r'
.word '\n'
.word f_emit
.word f_emit
.word f_exit
wdef token, "token", a_call, f_cr, 0
2:
.word f_2lit
.word n_key
.word 3
.word f_find
.word f_execute
.word f_dup
.word f_isdel
.word f_branch0
.word 1f
.word f_drop
.word f_tidrop
.word f_branch
.word 2b