base-module.gradle

apply plugin: 'com.android.library' // alias libs.plugins.com.android.library
apply plugin: 'kotlin-android' // alias libs.plugins.org.jetbrains.kotlin.android
apply plugin: 'kotlin-kapt'
apply plugin: 'kotlin-parcelize'

android {
    namespace 'com.gumu.calorietracker'
    compileSdk ProjectConfig.compileSdk

    defaultConfig {
        minSdk ProjectConfig.minSdk
        targetSdk ProjectConfig.targetSdk
        versionCode ProjectConfig.versionCode
        versionName ProjectConfig.versionName

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        consumerProguardFiles "consumer-rules.pro"
    }
    buildTypes {
        release {
            minifyEnabled true
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    compileOptions {
        coreLibraryDesugaringEnabled true

        sourceCompatibility JavaVersion.VERSION_17
        targetCompatibility JavaVersion.VERSION_17
    }
    kotlinOptions {
        jvmTarget = '17'
    }
}

dependencies {
    // Dagger-Hilt
    implementation libs.hilt.android
    kapt libs.hilt.compiler

    // Testing
    testImplementation libs.junit
    testImplementation libs.androidx.test.ext.junit
    testImplementation libs.coroutines.test
    testRuntimeOnly("net.bytebuddy:byte-buddy:1.10.21") // fix mockk warning/issue with java 17
    testImplementation libs.mockk
    testImplementation libs.turbine
    testImplementation libs.truth
    testImplementation libs.mockwebserver

    androidTestImplementation libs.androidx.test.ext.junit
    androidTestImplementation libs.espresso.core
    androidTestImplementation libs.coroutines.test
    androidTestImplementation platform(libs.compose.bom)
    androidTestImplementation libs.ui.test.junit4
    androidTestImplementation libs.mockk
    androidTestImplementation libs.turbine
    androidTestImplementation libs.truth
    androidTestImplementation libs.mockwebserver
    androidTestImplementation libs.hilt.testing
}