Composing figures, or plot(plt1, plt2, plt3, ...)

[asinghvi17]

Plots.jl has plot(p1, p2, p3, ...) which take multiple "plots", basically multiple GridLayouts in Makie parlance, and places them together into a single Figure. I've also seen a number of people ask in forums about this.

Generally it is pretty easy to just change your code to "move axes" from different figures into the same figure, but I wanted to do it assuming that you needed to integrate a figure generated by some black-box function into your Figure.

Turns out that it is actually pretty easy! All I need to do is hook up interactivity, but otherwise this works pretty much perfectly.

The code is below - you basically call move!(newfig[i, j], oldfig.layout). You can also move a GridLayout from one figure to another, which is pretty neat!

"""
    get_all_blocks(layout::GridLayout)

Recursively gets all blocks in that layout, and returns a flattened Vector of blocks.
"""
function get_all_blocks(layout::GridLayout, blocks = Makie.Block[])
    contents = Makie.contents(layout)
    append!(blocks, filter(c -> c isa Makie.Block, contents))
    for sublayout in filter(c -> c isa Makie.GridLayout, contents)
        get_all_blocks(sublayout, blocks)
    end
    return blocks
end

"""
    move!(position::GridPosition, layout::GridLayout)

Moves `layout` and all its contents to `position`.
This works even with different figures, i.e., different layout roots.

Note that this function assumes that both `position` and `layout`
are associated with some `Figure` - even if those `Figure`s are different.

## Example

fig1 = Figure(resolution = (1500, 1500))
fig2 = Figure()

gl1 = GridLayout(fig1[1, 1])
gl2 = GridLayout(fig1[1, 2])

for gl in (gl1, gl2)
    lines(gl[1, 1], rand(10))
    scatter(gl[1, 2], rand(10))
    heatmap(gl[2, 1], rand(100, 100))
    surface(gl[2, 2], Makie.peaks())
end

move!(fig2[1, 1], gl1)
fig2

## TODOS
- Get screen events (mouse, keyboard) hooked up
"""
function move!(position::Makie.GridPosition, layout::GridLayout; remove_scenes_from_old_figure = true)
    # first, get figures
    new_figure = Makie.get_figure(position)
    old_figure = Makie.GridLayoutBase.top_parent(layout)
    @assert old_figure isa Figure
    @assert new_figure isa Figure

    # move the layout to the new figure
    position[] = layout
    # tell the layout that it's been moved
    layout.parent = position.layout

    # move the Blocks' blockscenes to the new figure
    for block in get_all_blocks(layout)
        # push the blockscene of each block to the new figure
        push!(new_figure.scene.children, block.blockscene)
        block.blockscene.parent = new_figure.scene
        # optionally, remove the scenes from the old figure
        if remove_scenes_from_old_figure
            deleteat!(old_figure.scene.children, findfirst(x -> x === block.blockscene, old_figure.scene.children))
        end
        # TODO: this doesn't work, we probably need to set up mouse and keyboard handlers again
        # for the new Scene.
        nodes = map(fieldnames(Makie.Events)) do field
            if !(field ∈ (:window_area, :mousebuttonstate, :keyboardstate))
                Makie.connect!(getfield(new_figure.scene.events, field), getfield(block.blockscene.events, field))
            end
        end
    end

    return position
end

move!(position::Makie.GridPosition, figure::Figure; remove_scenes_from_old_figure = true) = move!(position, figure.layout; remove_scenes_from_old_figure)

Would appreciate some advice on how to hook up interactivity (and potentially remove the previous stuff).