build.gradle

println """
******************************************
        Building Thaumic Skies! 

 Output files will be in basePath/build/
******************************************
"""

import org.apache.tools.ant.filters.ReplaceTokens

version = packVersion
description = packDescription
def forgeCompatibility = packForgeCompatibility

ext {
    buildSources = "$buildDir/sources"
}

task buildAll(dependsOn: ['buildServer', 'buildClient'])

task compileServer(type: Copy) {
    doFirst {
        delete("$buildSources/server")
    }
    from('src') {
        exclude '**/_CLIENT/**'
    }
    from('src') {
        include '**/*.properties'
        include '**/*.txt'
        include '**/*.json'
        include '**/*.cfg'
        include '**/*.conf'
        include '**/*.config'
        include '**/*.xml'
        include '**/*.recipes'
        exclude '**/_CLIENT/**'
        filter(ReplaceTokens, tokens: project.properties.collectEntries { k, v -> [k, v ?: ''] })
    }
    into "$buildSources/server"

    eachFile { details ->
        details.path = details.path.replaceAll('_SERVER', '');
    }
    includeEmptyDirs = false
}

task compileClient(type: Copy) {
    doFirst {
        delete("$buildSources/client")
    }
    from('src') {
        exclude '**/_SERVER/**'
    }
    from('src') {
        include '**/*.properties'
        include '**/*.txt'
        include '**/*.json'
        include '**/*.cfg'
        include '**/*.conf'
        include '**/*.config'
        include '**/*.xml'
        include '**/*.recipes'
        exclude '**/_SERVER/**'
        filter(ReplaceTokens, tokens: project.properties.collectEntries { k, v -> [k, v ?: ''] })
    }
    into "$buildSources/client"

    eachFile { details ->
        details.path = details.path.replaceAll('_CLIENT', '');
    }
    includeEmptyDirs = false
}

task buildServer(type: Zip, dependsOn: ['compileServer']) {
    from "$buildSources/server"
    baseName = "$buildDir/${project.name}_${project.version}_Server"
}

task buildClient(type: Zip, dependsOn: ['compileClient']) {
    from "$buildSources/client"
    baseName = "$buildDir/${project.name}_${project.version}_Client"
}