build.gradle

apply plugin: "io.github.gradle-nexus.publish-plugin"
apply from: rootProject.file('gradle/gradle-mvn-config.gradle')
apply from: 'dependencies.gradle'
apply from: 'checkstyle.gradle'



buildscript {
    ext.kotlinVersion = '1.8.21'
    ext.shadowPluginVersion = '8.1.1'
    repositories {
        maven {
            url "https://plugins.gradle.org/m2/"
        }
        google()
        mavenCentral()
        gradlePluginPortal()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:8.7.1'
        classpath 'com.github.ben-manes:gradle-versions-plugin:0.21.0'
        classpath 'gradle.plugin.org.codehaus.groovy:groovy-android-gradle-plugin:3.0.0'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
        classpath "io.github.gradle-nexus:publish-plugin:1.1.0"
        classpath "com.github.johnrengelman:shadow:$shadowPluginVersion"
    }
}

allprojects {
    apply plugin: 'com.github.ben-manes.versions'

    repositories {
        google()
        maven {
            url "https://plugins.gradle.org/m2/"
        }
        maven { url 'https://jitpack.io' }
        mavenCentral()
    }

    buildscript {
        repositories {
            google()
        }
    }

    dependencyUpdates.resolutionStrategy {
        componentSelection { rules ->
            rules.all { ComponentSelection selection ->
                boolean rejected = ['alpha', 'beta', 'rc', 'cr', 'm', 'preview'].any { qualifier ->
                    selection.candidate.version ==~ /(?i).*[.-]${qualifier}[.\d-]*/
                }
                if (rejected) {
                    selection.reject('Release candidate')
                }
            }
        }
    }

    gradle.projectsEvaluated {
        tasks.withType(JavaCompile).configureEach {
            options.compilerArgs << "-Xlint:unchecked" << "-Xlint:deprecation"
        }

        tasks.withType(Test).tap {
            configureEach {
                useJUnitPlatform()
                testLogging {
                    exceptionFormat "full"
                    events "started", "skipped", "passed", "failed"
                    showStandardStreams true
                }
            }
        }
    }


}

tasks.register('clean', Delete) {
    delete rootProject.getLayout().getBuildDirectory()
}