build.gradle

plugins {
    id 'java'

    id 'com.github.johnrengelman.shadow' version '7.1.2'
    id 'net.minecrell.plugin-yml.bukkit' version '0.5.1'

}

group 'com.nextplugins'
version '1.0.7'

repositories {
    mavenCentral()
    mavenLocal()

    // spigot

    maven { url = 'https://hub.spigotmc.org/nexus/content/repositories/snapshots/' }
    maven { url = 'https://oss.sonatype.org/content/groups/public/' }

    // libs

    maven { url = 'https://repo.codemc.org/repository/maven-public' }
    maven { url = 'https://jitpack.io/' }
}

dependencies {

    compileOnly 'org.spigotmc:spigot-api:1.18.2-R0.1-SNAPSHOT'

    implementation 'com.github.HenryFabio:configuration-injector:main-SNAPSHOT'
    implementation 'org.bstats:bstats-bukkit:1.8'

    def lombok = 'org.projectlombok:lombok:1.18.24'
    compileOnly lombok
    annotationProcessor lombok

}

bukkit {
    main = 'com.nextplugins.sorteios.NextSorteios'
    authors = ['Henry_Fabio', 'Eike', 'Gabriel Santos', 'Yuhtin']
    website = 'https://github.com/NextPlugins'
    apiVersion = '1.18'
    version = "${project.version}"
    commands {
        sortear {
            description = 'Sortear algum prêmio aleatório'
            aliases = ['sorteio']
            permission = 'nextsorteios.sort'
        }
    }
}

tasks {
    build {
        dependsOn 'shadowJar'
    }
}

shadowJar {
    archiveName("${project.name}-${project.version}.jar")
    relocate 'com.henryfabio.minecraft.configinjector', 'com.nextplugins.sorteios.libs.configinjector'
    relocate 'org.bstats', 'com.nextplugins.sorteios.libs.bstats'
}

compileJava {
    options.encoding('UTF-8')

    sourceCompatibility('1.8')
    targetCompatibility('1.8')
}