hyuga: init at 1.0.0

pkgs/by-name/hy/hyuga/package.nix

@@ -0,0 +1,49 @@
+{
+  lib,
+  fetchFromGitHub,
+  python3Packages,
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "hyuga";
+  version = "1.0.0";
+  pyproject = true;
+
+  build-system = with python3Packages; [
+    setuptools
+    poetry-core
+  ];
+
+  src = fetchFromGitHub {
+    owner = "sakuraiyuta";
+    repo = "hyuga";
+    rev = "refs/tags/${version}";
+    hash = "sha256-7TLWx+t9VE1LcjH3z0XGHSeR1kcYy2EjPmvI1fUoilM=";
+  };
+
+  postPatch = ''
+    substituteInPlace hyuga/uri/helper.hy \
+       --replace-fail "{root-path}/.venv/lib" "$out/lib"
+  '';
+
+  dependencies = with python3Packages; [
+    hy
+    hyrule
+    toolz
+    pygls
+  ];
+
+  pythonRemoveDeps = [ "setuptools" ];
+
+  nativeCheckInputs = [ python3Packages.pytestCheckHook ];
+
+  doCheck = true;
+
+  meta = {
+    description = "Yet Another Hy Language Server";
+    mainProgram = "hyuga";
+    license = lib.licenses.mit;
+    homepage = "https://github.com/sakuraiyuta/hyuga";
+    maintainers = with lib.maintainers; [ sigmanificient ];
+  };
+}