From 173268d9b214eec325fbb088442f1c4b5dc59d00 Mon Sep 17 00:00:00 2001
From: XBagon <xbagon@outlook.de>
Date: Thu, 2 Jan 2025 22:06:42 +0100
Subject: [PATCH] ffizer: init at 2.13.0

---
 pkgs/by-name/ff/ffizer/package.nix | 57 ++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 pkgs/by-name/ff/ffizer/package.nix

diff --git a/pkgs/by-name/ff/ffizer/package.nix b/pkgs/by-name/ff/ffizer/package.nix
new file mode 100644
index 00000000000000..02e40077a2c939
--- /dev/null
+++ b/pkgs/by-name/ff/ffizer/package.nix
@@ -0,0 +1,57 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+  libgit2,
+  openssl,
+  zlib,
+  stdenv,
+  darwin,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "ffizer";
+  version = "2.13.0";
+
+  buildFeatures = [ "cli" ];
+
+  src = fetchFromGitHub {
+    owner = "ffizer";
+    repo = "ffizer";
+    rev = version;
+    hash = "sha256-Kgd27X9t/AkNCkVWCHdNO6MJBLchxrPQkkmqEJVTrPo=";
+  };
+
+  cargoHash = "sha256-NTwhx0glxIrgTfx8K6tPXokL1ps5PsQ8rjEXThqHkzY=";
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  buildInputs =
+    [
+      libgit2
+      openssl
+      zlib
+    ]
+    ++ lib.optionals stdenv.isDarwin [
+      darwin.apple_sdk.frameworks.Security
+    ];
+
+  env.OPENSSL_NO_VENDOR = true;
+
+  checkFlags = [
+    # requires internet access
+    "--skip=run_test_samples_tests_data_template_2"
+  ];
+
+  meta = {
+    description = "Ffizer is a files and folders initializer / generator. Create any kind (or part) of project from template";
+    homepage = "https://github.com/ffizer/ffizer";
+    changelog = "https://github.com/ffizer/ffizer/blob/${src.rev}/CHANGELOG.md";
+    license = lib.licenses.cc0;
+    maintainers = with lib.maintainers; [ XBagon ];
+    mainProgram = "ffizer";
+  };
+}