diff --git a/pkgs/development/python-modules/python-openstackclient/default.nix b/pkgs/development/python-modules/python-openstackclient/default.nix
index ffa0017a6e2fa..890fc02a1a88c 100644
--- a/pkgs/development/python-modules/python-openstackclient/default.nix
+++ b/pkgs/development/python-modules/python-openstackclient/default.nix
@@ -17,6 +17,7 @@
   python-mistralclient,
   python-neutronclient,
   python-openstackclient,
+  python-watcherclient,
   python-zaqarclient,
   python-zunclient,
   requests-mock,
@@ -81,6 +82,7 @@ buildPythonPackage rec {
         python-manilaclient
         python-mistralclient
         python-neutronclient
+        python-watcherclient
         python-zaqarclient
         python-zunclient
       ];
diff --git a/pkgs/development/python-modules/python-watcherclient/default.nix b/pkgs/development/python-modules/python-watcherclient/default.nix
new file mode 100644
index 0000000000000..b3cc4267f30c4
--- /dev/null
+++ b/pkgs/development/python-modules/python-watcherclient/default.nix
@@ -0,0 +1,75 @@
+{
+  lib,
+  buildPythonPackage,
+  cliff,
+  fetchFromGitHub,
+  keystoneauth1,
+  openstackdocstheme,
+  osc-lib,
+  oslo-i18n,
+  oslo-serialization,
+  oslo-utils,
+  pbr,
+  pythonOlder,
+  setuptools,
+  sphinxcontrib-apidoc,
+  sphinxHook,
+  stestr,
+}:
+
+buildPythonPackage rec {
+  pname = "python-watcherclient";
+  version = "4.4.0";
+  pyproject = true;
+
+  disabled = pythonOlder "3.8";
+
+  src = fetchFromGitHub {
+    owner = "openstack";
+    repo = "python-watcherclient";
+    rev = "refs/tags/${version}";
+    hash = "sha256-lDdiZKaeteKZEyfjpBx8KY+0FLFOYAnQXl0pTbqq0Ss=";
+  };
+
+  env.PBR_VERSION = version;
+
+  build-system = [
+    pbr
+    setuptools
+  ];
+
+  nativeBuildInputs = [
+    openstackdocstheme
+    sphinxcontrib-apidoc
+    sphinxHook
+  ];
+
+  sphinxBuilders = [ "man" ];
+
+  dependencies = [
+    cliff
+    keystoneauth1
+    osc-lib
+    oslo-i18n
+    oslo-serialization
+    oslo-utils
+  ];
+
+  nativeCheckInputs = [ stestr ];
+
+  checkPhase = ''
+    runHook preCheck
+    stestr run
+    runHook postCheck
+  '';
+
+  pythonImportsCheck = [ "watcherclient" ];
+
+  meta = {
+    homepage = "https://opendev.org/openstack/python-watcherclient";
+    description = "Client library for OpenStack Watcher API";
+    license = lib.licenses.asl20;
+    mainProgram = "watcher";
+    maintainers = lib.teams.openstack.members;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 90e1360cdd141..d6e64c83076e1 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -22915,6 +22915,7 @@ with pkgs;
   mistralclient = with python311Packages; toPythonApplication python-mistralclient;
   swiftclient = with python311Packages; toPythonApplication python-swiftclient;
   troveclient = with python311Packages; toPythonApplication python-troveclient;
+  watcherclient = with python311Packages; toPythonApplication python-watcherclient;
   zunclient = with python311Packages; toPythonApplication python-zunclient;
 
   openvdb = callPackage ../development/libraries/openvdb { };
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index acac2234ca169..42929bc9020fb 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -12846,6 +12846,8 @@ self: super: with self; {
 
   python-vlc = callPackage ../development/python-modules/python-vlc { };
 
+  python-watcherclient = callPackage ../development/python-modules/python-watcherclient { };
+
   python-whois = callPackage ../development/python-modules/python-whois { };
 
   python-wifi = callPackage ../development/python-modules/python-wifi { };