link.ld

/* The bootloader will look at this image and start execution at the symbol
    designated as the entry point. */
ENTRY(loader)

/* Tell where the various sections of the object files will be put in the final
    kernel image. */
SECTIONS
{
    /* Begin putting sections at 1 MiB, a conventional place for kernels to be
        loaded at by the bootloader. */
    . = 1M;

    ld_kernel_start = .;

    /* First put the multiboot header, as it is required to be put very early
       early in the image or the bootloader won't recognize the file format. */
    .__mbHeader :
    {
        *(.__mbHeader)
    }

    /* Next we'll put the .text section. */
    .text BLOCK(4K) : ALIGN(4K)
    {
        *(.text)
        *(.rodata*)
    }

    /* Read-write data (initialized) */
    .data BLOCK(4K) : ALIGN(4K)
    {
        *(.data)
    }

    /* Read-write data (uninitialized) and stack */
    .bss BLOCK(4K) : ALIGN(4K)
    {
        _sbss = .;
        *(COMMON)
        *(.bss)
        _ebss = .;
    }

    ld_kernel_end = .;

    /* The compiler may produce other sections, by default it will put them in
        a segment with the same name. Simply add stuff here as needed. */
}