settings.gradle

plugins {
    id "com.gradle.enterprise" version "3.15"
}

if (!JavaVersion.current().isJava11Compatible()) {
    throw new GradleScriptException("Building OmniJ requires JDK 11 or later", null)
}

rootProject.name = 'OmniJ'

include 'omnij-core',
        'omnij-dsl',
        'omnij-jsonrpc',    // Omni JSON-RPC pure Java
        'omnij-net-api',
        'omnij-rest-client-retrofit',
        'omnij-money'

include 'omnij-rest-client-jdk'        // JDK Omni REST client (using java.net.http)
include 'omnij-rpc'                    // Omni JSON-RPC + Groovy + Integration tests

if (JavaVersion.current().compareTo(JavaVersion.VERSION_17) >= 0) {
    System.err.println "Including JDK 17 modules because Java is ${JavaVersion.current()}"
    include 'omnij-tx-records'
} else {
    System.err.println "Skipping JDK 17 subprojects, requires Java 17+, currently running Java ${JavaVersion.current()}"
}

if (JavaVersion.current().compareTo(JavaVersion.VERSION_21) >= 0) {
    System.err.println "Including JDK 21 modules because Java is ${JavaVersion.current()}"
    include 'omnij-cli'
} else {
    System.err.println "Skipping JDK 21 modules, currently running Java ${JavaVersion.current()}"
}