build.gradle

plugins {
	id 'fabric-loom' version '1.6-SNAPSHOT'
	id 'maven-publish'
	id "me.modmuss50.mod-publish-plugin" version "0.5.1"
	id "com.sidneysimmons.gradle-plugin-external-properties" version "2.0.1"
}

version = project.mod_version
group = project.maven_group

base {
	archivesName = project.archives_base_name
}

repositories {
	maven { url 'https://maven.nucleoid.xyz' }
}

dependencies {
	// To change the versions see the gradle.properties file
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

	// Fabric API. This is technically optional, but you probably want it anyway.
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"
	
	// Uncomment the following line to enable the deprecated Fabric API modules. 
	// These are included in the Fabric API production distribution and allow you to update your mod to the latest modules at a later more convenient time.

	// modImplementation "net.fabricmc.fabric-api:fabric-api-deprecated:${project.fabric_version}"

	include modImplementation("eu.pb4:polymer-core:${project.polymer_version}")
	include modImplementation("xyz.nucleoid:server-translations-api:${project.server_translations_version}")
}

final String minecraft_version = stonecutter.current.version

processResources {
	inputs.property "version", project.version
	inputs.property "minecraft_version", minecraft_version
	inputs.property "polymer_version", project.property("polymer_version")
	inputs.property "server_translations_version", project.property("server_translations_version")



	filesMatching("fabric.mod.json") {
		expand ([
				"version": project.version,
				"minecraft_version": minecraft_version,
				"polymer_version": project.property("polymer_version"),
				"server_translations_version": project.property("server_translations_version")
		])
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.release = 17
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()

	sourceCompatibility = JavaVersion.VERSION_17
	targetCompatibility = JavaVersion.VERSION_17
}

jar {
	from("LICENSE") {
		rename { "${it}_${project.base.archivesName.get()}"}
	}
}

loom {
	runConfigs.all {
		ideConfigGenerated true // Run configurations are not created for subprojects by default
		runDir "../../run" // Use a shared run folder and just create separate worlds
	}
}

// configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			from components.java
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	repositories {
		// Add repositories to publish to here.
		// Notice: This block does NOT have the same function as the block in the top level.
		// The repositories here will be used for publishing your artifact, not for
		// retrieving dependencies.
	}
}

publishMods {
	file = remapJar.archiveFile

	type = STABLE
	modLoaders.add("fabric")
	additionalFiles.from(remapSourcesJar.archiveFile)

	displayName = "Random Fishing " + project.version + "-" + minecraft_version

	modrinth {
		accessToken = props.get("MODRINTH_KEY")
		projectId = "vEyyiUWA"
		minecraftVersions.add(minecraft_version)
	}

	github {
		accessToken = props.get("GITHUB_TOKEN")
		repository = "Overcontrol1/RandomFishing"
		commitish = "master"
		tagName = project.version + "-" + minecraft_version
	}

	changelog = "- Added data files for blacklisting individual items through tags and namespaces (mods) through a JSON. \n" +
				"- View [this wiki page](https://minecraft.wiki/w/Tag) for information on tags. The tag is an item tag with the identifier `randomfishing:blacklist`."
}