build.gradle

// --- COMMON BUILD SCRIPT START ---
buildscript {
    repositories {
        maven { url = 'https://maven.minecraftforge.net' }
        maven { url = 'https://maven.sinytra.org/' } // Wiki
        maven { url = 'https://maven.parchmentmc.org' } // Mappings
        maven { url = 'https://repo.spongepowered.org/repository/maven-public/' }
        mavenCentral()
    }
    dependencies {
        classpath group: 'net.minecraftforge.gradle', name: 'ForgeGradle', version: '6+', changing: true
        classpath 'org.parchmentmc:librarian:1.+'
        classpath group: 'org.spongepowered', name: 'mixingradle', version: '+'
    }
}

plugins {
    id 'java'
    id 'idea'
    id 'maven-publish'
    id "me.modmuss50.mod-publish-plugin" version "${publish_plugin_version}"
    id "org.moddedmc.wiki.toolkit" version "${wiki_toolkit_version}"
}

apply plugin: 'net.minecraftforge.gradle'
apply plugin: 'org.parchmentmc.librarian.forgegradle'
apply plugin: 'org.spongepowered.mixin'

apply from: 'https://raw.githubusercontent.com/RobertSkalko/ModResources/refs/heads/main/1.20.1/common.gradle'
apply from: 'https://raw.githubusercontent.com/RobertSkalko/ModResources/refs/heads/main/1.20.1/exile_lib_dep.gradle'
apply from: 'https://raw.githubusercontent.com/RobertSkalko/ModResources/refs/heads/main/1.20.1/ide_runs.gradle'
apply from: 'https://raw.githubusercontent.com/RobertSkalko/ModResources/refs/heads/main/1.20.1/meta.gradle'
apply from: 'https://raw.githubusercontent.com/RobertSkalko/ModResources/refs/heads/main/1.20.1/publishing.gradle'
apply from: 'https://raw.githubusercontent.com/RobertSkalko/ModResources/refs/heads/main/1.20.1/mixin.gradle'

// --- COMMON BUILD SCRIPT END ---


// --- MOD SPECIFIC ---

repositories {

    maven { url = "https://maven.theillusivec4.top/" } // curios
    maven { url = "https://maven.kosmx.dev/" } // player animations
    maven {
        // location of a maven mirror for JEI files, as a fallback
        name = "ModMaven"
        url = "https://modmaven.dev/"
        content {
            includeGroup "mezz.jei"
        }
    }
}

minecraft {
    accessTransformer = file('src/main/resources/META-INF/accesstransformer.cfg')
}

dependencies {

    implementation fg.deobf("top.theillusivec4.curios:curios-forge:${curios_version}")

    compileOnly fg.deobf("mezz.jei:jei-1.20.1-common-api:${project.jei_version}") //API for compile
    compileOnly fg.deobf("mezz.jei:jei-1.20.1-forge-api:${project.jei_version}") //API for compile
    runtimeOnly fg.deobf("mezz.jei:jei-1.20.1-forge:${project.jei_version}") //Full for runtime

    implementation fg.deobf("dev.kosmx.player-anim:player-animation-lib-forge:${player_animator_version}")

}


publishMods {

    curseforge {
        requires { slug = "library-of-exile" }
        requires { slug = "curios" }
        requires { slug = "playeranimator" }
    }
    modrinth {
        requires { slug = "library-of-exile" }
        requires { slug = "curios" }
        requires { slug = "playeranimator" }
    }
}

wiki {
    docs {
        mutils {
            root = file("docs")
        }
    }
}

// --- MOD SPECIFIC ---