build.gradle

buildscript {
  repositories {
    mavenCentral()
    maven {
      name = "forge"
      url = "http://files.minecraftforge.net/maven"
    }
    maven {
      name = "sonatype"
      url = "https://oss.sonatype.org/content/repositories/snapshots/"
    }
  }

  dependencies {
    classpath "net.minecraftforge.gradle:ForgeGradle:1.2-SNAPSHOT"
  }
}

repositories {
  maven {
    name "Mobius"
    url "http://mobiusstrip.eu/maven"
  }
  maven { // NEI/CCC
    name "Chickenbones"
    url "http://chickenbones.net/maven/"
  }
}

apply plugin: "idea"
apply plugin: "forge"

tasks.withType(JavaCompile) {
  sourceCompatibility = "1.7"
  targetCompatibility = "1.7"
}

version = "0.1.${System.getenv("DRONE_BUILD_NUMBER")}"
group = "net.soartex.modlistbuilder"
archivesBaseName = "modlistbuilder"

minecraft {
  version = "1.7.10-10.13.4.1448-1.7.10"
  runDir = "run"

  replaceIn "src/main/java/net/soartex/modlist/ModInfo.java"
  replace "@VERSION@", project.version
}

dependencies {
  // Not actual dependencies, just for dev environment
  compile "codechicken:CodeChickenLib:1.7.10-1.1.3.138:dev"
  compile "codechicken:CodeChickenCore:1.7.10-1.0.7.46:dev"
  compile "codechicken:NotEnoughItems:1.7.10-1.0.5.110:dev"
  compile 'mcp.mobius.waila:Waila:1.5.11-RC1_1.7.10:dev'
}

processResources {
  inputs.property "version", project.version
  inputs.property "mcversion", project.minecraft.version

  from(sourceSets.main.resources.srcDirs) {
    include "mcmod.info"

    expand "version": project.version, "mcversion": project.minecraft.version
  }

  from(sourceSets.main.resources.srcDirs) {
    exclude "mcmod.info"
  }
}