settings.gradle

pluginManagement {
    repositories {
        maven {
            name = 'Fabric'
            url = 'https://maven.fabricmc.net/'
        }
        maven {
            name = "Forge"
            url = "https://files.minecraftforge.net/maven/"
        }
        maven {
            name = "NeoForged"
            url = "https://maven.neoforged.net/releases"
        }
        maven {
            name = "Kikugie"
            url = "https://maven.kikugie.dev/releases"
        }
        maven {
            name = "Architectury"
            url = "https://maven.architectury.dev/"
        }
        mavenCentral()
        gradlePluginPortal()
    }
}

plugins {
    id "dev.kikugie.stonecutter" version "0.4.2"
}

stonecutter {
    shared {
        def mc = { String version, String... loaders ->
            loaders.each { loader ->
                vers("$version-$loader", version)
            }
        }

        // The topmost version is considered the "default" and activated with "Reset active project"
        mc("1.21", "fabric", "forge")
        mc("1.20.6", "fabric", "forge")
        mc("1.20.4", "fabric", "forge")
        mc("1.20.1", "fabric")
    }

    create rootProject
}
rootProject.name = "better-clouds"