build.gradle

plugins {
    id 'java-library'
    id 'eclipse'
    id 'idea'
    id 'maven-publish'
    id 'net.neoforged.gradle.userdev' version '7.0.145'
}

def secrets = new Properties()
def secretsFile = file('secrets.properties')
if (secretsFile.exists()) {
    secretsFile.withInputStream {
        stream -> secrets.load(stream)
    }
    fileTree("secrets").matching {
        include "**/*.properties"
    }.each {
        File file ->
            file.withInputStream {
                stream -> secrets.load(stream)
            }
    }
}

version = project.artifactor_minecraft_version + "-" + project.artifactor_mod_version
group = project.mod_group

if (hasProperty("CIVersion")) {
    version += "." + CIVersion
}

repositories {
    maven {
        url 'https://maven.tamaized.com/releases/'
    }
}

base {
    archivesName = project.archive_name
}

java.toolchain.languageVersion = JavaLanguageVersion.of(21)

runs {
    configureEach {
        modSource project.sourceSets.main
    }
    client {
        systemProperty 'forge.enabledGameTestNamespaces', project.archive_name
    }

    server {
        systemProperty 'forge.enabledGameTestNamespaces', project.archive_name
    }

    data {
        workingDirectory project.file('run-data')
        programArguments.addAll '--mod', 'doiamornament', '--all', '--output', file('src/generated/resources/').getAbsolutePath(), '--existing', file('src/main/resources/').getAbsolutePath(), '--existing-mod', 'ornamental', '--existing-mod', 'twilightforest'
    }
}

// Include resources generated by data generators.
sourceSets.main.resources {
    srcDir 'src/generated/resources'
}

dependencies {
    implementation "net.neoforged:neoforge:${project.artifactor_forge_version}"

    implementation "androsa:ornamental:${ornamental_version}"
    implementation "team-twilight:twilightforest:${tf_version}:universal"
}

// Example for how to get properties into the manifest for reading by the runtime..
jar {
    manifest {
        attributes([
            "Specification-Title": "Do I am Ornament",
            "Specification-Vendor": "Androsa",
            "Specification-Version": "${version}", // We are version 1 of ourselves
            "Implementation-Title": project.name,
            "Implementation-Version": "${version}",
            "Implementation-Vendor" : "Androsa",
            "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
        ])
    }
}

def mavenUser = hasProperty("CIMUser") ? CIMUser : secrets.getProperty("maven_username")
def mavenToken = hasProperty("CIMToken") ? CIMToken : secrets.getProperty("maven_password")

publishing {
    publications {
        mavenJava(MavenPublication) {
            afterEvaluate {
                artifact project.jar
                artifact project.sourceJar
            }
            setGroupId 'team-twilight'
            setArtifactId project.archive_name
        }
    }
    repositories {
        maven {
            url "https://maven.tamaized.com/releases"
            credentials {
                username mavenUser
                password mavenToken
            }
        }
    }
}

tasks.register('sourceJar', Jar) {
    dependsOn 'classes'
    from sourceSets.main.allSource
    archiveClassifier = 'sources'
}