forked from Fr0sT-Brutal/Delphi_MemoryModule
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathMemoryModule.pas
3737 lines (3426 loc) · 122 KB
/
MemoryModule.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
unit MemoryModule;
{ * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
* Memory DLL loading code
* ------------------------
*
* Original C Code
* Memory DLL loading code
* Version 0.0.4
*
* Copyright ( c ) 2004-2015 by Joachim Bauch / [email protected]
* http://www.joachim-bauch.de
*
* The contents of this file are subject to the Mozilla Public License Version
* 2.0 ( the "License" ); you may not use this file except in compliance with
* the License. You may obtain a copy of the License at
* http://www.mozilla.org/MPL/
*
* Software distributed under the License is distributed on an "AS IS" basis,
* WITHOUT WARRANTY OF ANY KIND, either express or implied. See the License
* for the specific language governing rights and limitations under the
* License.
*
* The Original Code is MemoryModule.c
*
* The Initial Developer of the Original Code is Joachim Bauch.
*
* Portions created by Joachim Bauch are Copyright ( C ) 2004-2015
* Joachim Bauch. All Rights Reserved.
*
* ================== MemoryModule "Conversion to Delphi" ==================
*
* Copyright ( c ) 2015 by Fr0sT / https://github.com/Fr0sT-Brutal
*
* Initially based on the code by:
* Copyright ( c ) 2005 - 2006 by Martin Offenwanger / [email protected] / http://www.dsplayer.de
* Carlo Pasolini / [email protected] / http://pasotech.altervista.org
*
* NOTE
* This code is Delphi translation of original C code taken from https://github.com/fancycode/MemoryModule
* ( commit dc173ca from Mar 1, 2015 ).
* Resource loading and exe loading, custom functions, user data not implemented yet.
* Tested under RAD Studio XE2 and XE6 32/64-bit, Lazarus 32-bit
* }
interface
{.$DEFINE FastMM4} // FastMM4 Version
{.$DEFINE FastMM5} // FastMM5 Version
{.$DEFINE LZMA}
{$DEFINE MANIFEST} // WinSxS Support
{$DEFINE ALLOW_LOAD_FILES}
{$DEFINE LOAD_FROM_RESOURCE}
{$IF Defined( LOAD_FROM_RESOURCE ) AND ( NOT Defined( FastMM4 ) AND NOT Defined( FastMM5 ) )}
{$DEFINE USE_STREAMS}
{$IFEND}
{$DEFINE GetModuleHandle_BuildImportTable} // Try GetModuleHandle for BuildImportTable
{$DEFINE GetModuleHandle}
{$IF Defined( GetModuleHandle ) AND ( NOT Defined( FastMM4 ) AND NOT Defined( FastMM5 ) )}
{$DEFINE UnloadAllOnFinalize} // Unload all Modules during Finalization of this Unit
{$DEFINE GetModuleHandleCriticalSection} // Thread-Safe
{$IFEND GetModuleHandle}
{$IFDEF MANIFEST}
{$OPTIMIZATION OFF}
{$ENDIF}
{$WARN UNSAFE_TYPE OFF}
{$WARN UNSAFE_CODE OFF}
{$WARN UNSAFE_CAST OFF}
{$WARN COMBINING_SIGNED_UNSIGNED OFF}
// To compile under FPC, Delphi mode must be used
// Also define CPUX64 for simplicity
{$IFDEF FPC}
{$mode delphi}
{$IFDEF CPU64}
{$DEFINE CPUX64}
{$ENDIF}
{$ENDIF}
{$IFNDEF FPC}
{$IF CompilerVersion >= 23}
{$LEGACYIFEND ON}
{$WARN IMPLICIT_STRING_CAST OFF}
{$ELSE}
{$RANGECHECKS OFF} // RangeCheck might cause Internal-Error C1118
{$IFEND}
{$ENDIF}
uses
Windows;
type
{$IF NOT DECLARED( IMAGE_NT_HEADERS32 )}
PIMAGE_NT_HEADERS32 = ^IMAGE_NT_HEADERS;
{$ELSE}
PIMAGE_NT_HEADERS32 = ^IMAGE_NT_HEADERS32;
{$IFEND}
{$IF NOT DECLARED( IMAGE_NT_HEADERS64 )}
_IMAGE_OPTIONAL_HEADER64 = record
{ Standard fields. }
Magic: Word;
MajorLinkerVersion: Byte;
MinorLinkerVersion: Byte;
SizeOfCode: DWORD;
SizeOfInitializedData: DWORD;
SizeOfUninitializedData: DWORD;
AddressOfEntryPoint: DWORD;
BaseOfCode: DWORD;
{ NT additional fields. }
ImageBase: ULONGLONG;
SectionAlignment: DWORD;
FileAlignment: DWORD;
MajorOperatingSystemVersion: Word;
MinorOperatingSystemVersion: Word;
MajorImageVersion: Word;
MinorImageVersion: Word;
MajorSubsystemVersion: Word;
MinorSubsystemVersion: Word;
Win32VersionValue: DWORD;
SizeOfImage: DWORD;
SizeOfHeaders: DWORD;
CheckSum: DWORD;
Subsystem: Word;
DllCharacteristics: Word;
SizeOfStackReserve: ULONGLONG;
SizeOfStackCommit: ULONGLONG;
SizeOfHeapReserve: ULONGLONG;
SizeOfHeapCommit: ULONGLONG;
LoaderFlags: DWORD;
NumberOfRvaAndSizes: DWORD;
DataDirectory: packed array[0..IMAGE_NUMBEROF_DIRECTORY_ENTRIES-1] of TImageDataDirectory;
end;
IMAGE_OPTIONAL_HEADER64 = _IMAGE_OPTIONAL_HEADER64;
PIMAGE_OPTIONAL_HEADER64 = ^IMAGE_OPTIONAL_HEADER64;
_IMAGE_NT_HEADERS64 = record
Signature: DWORD;
FileHeader: TImageFileHeader;
OptionalHeader: IMAGE_OPTIONAL_HEADER64;
end;
IMAGE_NT_HEADERS64 = _IMAGE_NT_HEADERS64;
PIMAGE_NT_HEADERS64 = ^IMAGE_NT_HEADERS64;
{$ELSE}
PIMAGE_NT_HEADERS64 = ^IMAGE_NT_HEADERS64;
{$IFEND}
TMemoryModuleModules = record
Handle : HMODULE;
{$IFDEF GetModuleHandle_BuildImportTable}
Free : boolean;
{$ENDIF GetModuleHandle_BuildImportTable}
end;
TIMAGE_NT_HEADERS3264 = packed record
X64 : Boolean;
case Boolean of
False : ( headers32 : PIMAGE_NT_HEADERS32 );
True : ( headers64 : PIMAGE_NT_HEADERS64 );
end;
PIMAGE_NT_HEADERS3264 = TIMAGE_NT_HEADERS3264;
TMemoryModule = record
headers : PIMAGE_NT_HEADERS3264;
codeBase : Pointer; // ModuleHandle
modules : array of TMemoryModuleModules;
initialized : Boolean;
isRelocated : Boolean;
pageSize : Cardinal;
end;
PMemoryModule = ^TMemoryModule;
{$IF NOT DECLARED( LOAD_LIBRARY_AS_IMAGE_RESOURCE )}
const
LOAD_LIBRARY_AS_IMAGE_RESOURCE = $00000020;
{$IFEND}
{$IF NOT DECLARED( LOAD_LIBRARY_AS_DATAFILE_EXCLUSIVE )}
const
LOAD_LIBRARY_AS_DATAFILE_EXCLUSIVE = $00000040;
{$IFEND}
{$IF NOT DECLARED( IMAGE_FILE_MACHINE_AMD64 )}
const
IMAGE_FILE_MACHINE_AMD64 = $8664; { AMD64 (K8) }
{$IFEND}
{ ++++++++++++++++++++++++++++++++++++++++++++++++++
*** Memory DLL loading functions Declaration ***
-------------------------------------------------- }
// return value is nil if function fails
function MemoryLoadLibrary( data: Pointer; var Module : PMemoryModule; Flags : Cardinal = 0 ): ShortInt; stdcall; {$IF Defined( ALLOW_LOAD_FILES ) OR Defined( LOAD_FROM_RESOURCE )}overload;{$IFEND}
{$IFDEF ALLOW_LOAD_FILES}
function MemoryLoadLibraryFile( FileName : string; var Module : PMemoryModule; Flags : Cardinal = 0 ): ShortInt; stdcall;
{$ENDIF ALLOW_LOAD_FILES}
{$IFDEF LOAD_FROM_RESOURCE}
function MemoryLoadLibrary( ResourceName : string; var Module : PMemoryModule; {$IFDEF USE_STREAMS}Password : string = '';{$ENDIF} Flags : Cardinal = 0 ): ShortInt; stdcall; overload;
function MemoryResourceExists( var ResourceName : string ) : HRSRC;
{$ENDIF LOAD_FROM_RESOURCE}
{$IFDEF GetModuleHandle}
function MemoryGetModuleHandle( data: Pointer ): PMemoryModule; stdcall; {$IF Defined( ALLOW_LOAD_FILES ) OR Defined( LOAD_FROM_RESOURCE )}overload;{$IFEND}
{$IF Defined( ALLOW_LOAD_FILES ) OR Defined( LOAD_FROM_RESOURCE )}
function MemoryGetModuleHandle( FileName : string{$IFDEF LOAD_FROM_RESOURCE}; IsResource : boolean = False{$ENDIF} ): PMemoryModule; stdcall; overload;
{$IFEND}
{$ENDIF GetModuleHandle}
// return value is nil if function fails
function MemoryGetProcAddress( module: PMemoryModule; const name: PAnsiChar ): Pointer; stdcall;
// free module
procedure MemoryFreeLibrary( var module: PMemoryModule ); stdcall;
function CheckSumMappedFile( Module : PMemoryModule; HeaderSum : PCardinal; CheckSum : PCardinal ) : PIMAGE_NT_HEADERS32;
function MemoryEnumerateImports( data: Pointer; var Modules : string; DelimiterString : String = ';'; FullPath : Boolean = False ): ShortInt; overload;
function MemoryEnumerateImports( ModuleData : Pointer; FileName : String; var Modules : String; DelimiterString : String = ';'; FullPath : Boolean = False; const MaxRecurseDepth : Word = 255 ) : Int64; overload;
{$IFDEF ALLOW_LOAD_FILES}
function MemoryEnumerateImportsFile( FileName : String; var Modules : String; DelimiterString : String = ';'; FullPath : Boolean = False; const MaxRecurseDepth : Word = 255{$IFDEF USE_STREAMS}; Password : string = ''{$ENDIF} ) : Int64; overload;
{$ENDIF}
{$IFDEF LOAD_FROM_RESOURCE}
function MemoryEnumerateImports( ResourceName : string; FileName : String; var Modules : String; DelimiterString : String = ';'; FullPath : Boolean = False; const MaxRecurseDepth : Word = 255{$IFDEF USE_STREAMS}; Password : string = ''{$ENDIF} ) : Int64; overload;
{$ENDIF}
function MemoryEnumerateExports( ModuleData : Pointer; var AExports : String; DelimiterString : String = ';' ) : ShortInt; overload;
{$IFDEF ALLOW_LOAD_FILES}
function MemoryEnumerateExportsFile( FileName : String; var AExports : String; DelimiterString : String = ';'{$IFDEF USE_STREAMS}; Password : string = ''{$ENDIF} ) : ShortInt; overload;
{$ENDIF}
{$IFDEF LOAD_FROM_RESOURCE}
function MemoryEnumerateExports( ResourceName : string; var AExports : String; DelimiterString : String = ';'{$IFDEF USE_STREAMS}; Password : string = ''{$ENDIF} ) : ShortInt; overload;
{$ENDIF}
function ListMissingModules( ModuleData : Pointer; FileName : String; var Modules : String; DelimiterString : String = #13#10; FullPath : Boolean = False; const MaxRecurseDepth : Word = 255 ) : Int64; overload;
{$IFDEF ALLOW_LOAD_FILES}
function ListMissingModules( FileName : String; var Modules : String; DelimiterString : String = #13#10; FullPath : Boolean = False; const MaxRecurseDepth : Word = 255{$IFDEF USE_STREAMS}; Password : string = ''{$ENDIF} ) : Int64; overload;
{$ENDIF}
{$IFDEF LOAD_FROM_RESOURCE}
function ListMissingModules( ResourceName : string; FileName : String; var Modules : String; DelimiterString : String = #13#10; FullPath : Boolean = False; const MaxRecurseDepth : Word = 255{$IFDEF USE_STREAMS}; Password : string = ''{$ENDIF} ) : Int64; overload;
{$ENDIF}
implementation
uses
{$IF Defined( FastMM4 ) OR Defined( FastMM5 )}
ZLibMinimal,
{$IFDEF FastMM5}FastMM5{$ELSE}FastMM4{$ENDIF}
{$ELSE}
ZLib
{$IFEND}
{$IFDEF lzma},LZMA, LZMA2{$ENDIF}
{$IF ( Defined( GetModuleHandle ) AND Defined( GetModuleHandleCriticalSection ) )},SyncObjs{$IFEND}
{$IFDEF USE_STREAMS},Classes, JclCompression{$ENDIF}
;
{ ++++++++++++++++++++++++++++++++++++++++
*** Missing Windows API Definitions ***
---------------------------------------- }
type
{$IF CompilerVersion < 21}
NativeUInt = Cardinal;
NativeInt = Integer;
IntPtr = NativeInt;
{$IFEND}
{$IF NOT DECLARED(PULONGLONG)}
PULONGLONG = ^UINT64;
{$IFEND}
{$IFDEF FastMM4}
PByte = System.PByte;
{$ENDIF FastMM4}
{$IF NOT DECLARED( IMAGE_BASE_RELOCATION )}
{$ALIGN 4}
IMAGE_BASE_RELOCATION = record
VirtualAddress : Cardinal;
SizeOfBlock : Cardinal;
end;
{$ALIGN ON}
PIMAGE_BASE_RELOCATION = ^IMAGE_BASE_RELOCATION;
{$IFEND}
// Types that are declared in Pascal-style ( ex.: PImageOptionalHeader ); redeclaring them in C-style
{$IF NOT DECLARED( PIMAGE_DATA_DIRECTORY )}
PIMAGE_DATA_DIRECTORY = ^IMAGE_DATA_DIRECTORY;
{$IFEND}
{$IF NOT DECLARED( PIMAGE_SECTION_HEADER )}
PIMAGE_SECTION_HEADER = ^IMAGE_SECTION_HEADER;
{$IFEND}
{$IF NOT DECLARED( PIMAGE_EXPORT_DIRECTORY )}
PIMAGE_EXPORT_DIRECTORY = ^IMAGE_EXPORT_DIRECTORY;
{$IFEND}
{$IF NOT DECLARED( PIMAGE_DOS_HEADER )}
PIMAGE_DOS_HEADER = ^IMAGE_DOS_HEADER;
{$IFEND}
{$IF NOT DECLARED( PUINT_PTR )}
PUINT_PTR = ^UINT_PTR;
{$IFEND}
{$IF NOT DECLARED( _IMAGE_TLS_DIRECTORY32 )}
_IMAGE_TLS_DIRECTORY32 = record
StartAddressOfRawData: Cardinal;
EndAddressOfRawData: Cardinal;
AddressOfIndex: Cardinal; // PDWORD
AddressOfCallBacks: Cardinal; // PIMAGE_TLS_CALLBACK *
SizeOfZeroFill: Cardinal;
Characteristics: Cardinal;
end;
{$IFEND}
{$IF NOT DECLARED( PIMAGE_TLS_DIRECTORY32 )}
PIMAGE_TLS_DIRECTORY32 = ^_IMAGE_TLS_DIRECTORY32;
{$IFEND}
{$IF NOT DECLARED( _IMAGE_TLS_DIRECTORY64 )}
_IMAGE_TLS_DIRECTORY64 = record
StartAddressOfRawData: ULONGLONG;
EndAddressOfRawData: ULONGLONG;
AddressOfIndex: ULONGLONG; // PDWORD
AddressOfCallBacks: ULONGLONG; // PIMAGE_TLS_CALLBACK *;
SizeOfZeroFill: DWORD;
Characteristics: DWORD;
end;
{$IFEND}
{$IF NOT DECLARED( PIMAGE_TLS_DIRECTORY64 )}
PIMAGE_TLS_DIRECTORY64 = ^_IMAGE_TLS_DIRECTORY64;
{$IFEND}
// Things that are incorrectly defined at least up to XE6 (miss x64 mapping)
{$IFDEF CPUX64}
type
PIMAGE_TLS_DIRECTORY = PIMAGE_TLS_DIRECTORY64;
const
IMAGE_ORDINAL_FLAG = IMAGE_ORDINAL_FLAG64;
type
{$ENDIF}
{$IF NOT DECLARED( PIMAGE_TLS_CALLBACK )}
PIMAGE_TLS_CALLBACK = procedure ( DllHandle: Pointer; Reason: Cardinal; Reserved: Pointer ) stdcall;
{$IFEND}
{$IF NOT DECLARED( _IMAGE_IMPORT_DESCRIPTOR )}
_IMAGE_IMPORT_DESCRIPTOR = record
case Byte of
0: ( Characteristics: Cardinal ); // 0 for terminating null import descriptor
1: ( OriginalFirstThunk: Cardinal; // RVA to original unbound IAT ( PIMAGE_THUNK_DATA )
TimeDateStamp: Cardinal; // 0 if not bound,
// -1 if bound, and real date\time stamp
// in IMAGE_DIRECTORY_ENTRY_BOUND_IMPORT ( new BIND )
// O.W. date/time stamp of DLL bound to ( Old BIND )
ForwarderChain: Cardinal; // -1 if no forwarders
Name: Cardinal;
FirstThunk: Cardinal ); // RVA to IAT ( if bound this IAT has actual addresses )
end;
{$IFEND}
{$IF NOT DECLARED( PIMAGE_IMPORT_DESCRIPTOR )}
PIMAGE_IMPORT_DESCRIPTOR = ^_IMAGE_IMPORT_DESCRIPTOR;
{$IFEND}
{$IF NOT DECLARED( _IMAGE_IMPORT_BY_NAME )}
_IMAGE_IMPORT_BY_NAME = record
Hint: Word;
Name: array[ 0..0 ] of Byte;
end;
{$IFEND}
{$IF NOT DECLARED( PIMAGE_IMPORT_BY_NAME )}
PIMAGE_IMPORT_BY_NAME = ^_IMAGE_IMPORT_BY_NAME;
{$IFEND}
{$IF NOT DECLARED( _IMAGE_IMPORT_DESCRIPTOR )}
_IMAGE_IMPORT_DESCRIPTOR = record
case Byte of
0: ( Characteristics: Cardinal ); // 0 for terminating null import descriptor
1: ( OriginalFirstThunk: Cardinal; // RVA to original unbound IAT ( PIMAGE_THUNK_DATA )
TimeDateStamp: Cardinal; // 0 if not bound,
// -1 if bound, and real date\time stamp
// in IMAGE_DIRECTORY_ENTRY_BOUND_IMPORT ( new BIND )
// O.W. date/time stamp of DLL bound to ( Old BIND )
ForwarderChain: Cardinal; // -1 if no forwarders
Name: Cardinal;
FirstThunk: Cardinal ); // RVA to IAT ( if bound this IAT has actual addresses )
end;
{$IFEND}
{$IF NOT DECLARED( IMAGE_IMPORT_DESCRIPTOR )}
IMAGE_IMPORT_DESCRIPTOR = _IMAGE_IMPORT_DESCRIPTOR;
{$IFEND}
{$IF NOT DECLARED( LPSYSTEM_INFO )}
LPSYSTEM_INFO = ^SYSTEM_INFO;
{$IFEND}
// Missing constants
const
IMAGE_SIZEOF_BASE_RELOCATION = 8;
IMAGE_REL_BASED_ABSOLUTE = 0;
IMAGE_REL_BASED_HIGHLOW = 3;
IMAGE_REL_BASED_DIR64 = 10;
{$IF NOT Defined( FPC ) AND ( CompilerVersion < 23 )}
IMAGE_ORDINAL_FLAG64 = UInt64( $8000000000000000 );
IMAGE_ORDINAL_FLAG32 = LongWord( $80000000 );
IMAGE_ORDINAL_FLAG = IMAGE_ORDINAL_FLAG32;
HEAP_ZERO_MEMORY = $00000008;
{$IFEND}
type
TDllEntryProc = function( hinstDLL: HINST; fdwReason: Cardinal; lpReserved: Pointer ): BOOL; stdcall;
TSectionFinalizeData = record
address: Pointer;
alignedAddress: Pointer;
size: Cardinal;
characteristics: Cardinal;
last: Boolean;
end;
// Explicitly export these functions to allow hooking of their origins
function GetProcAddress_Internal( hModule: HMODULE; lpProcName: LPCSTR ): FARPROC; stdcall; external kernel32 name 'GetProcAddress';
function LoadLibraryA_Internal( lpLibFileName: LPCSTR ): HMODULE; stdcall; external kernel32 name 'LoadLibraryA';
function FreeLibrary_Internal( hLibModule: HMODULE ): BOOL; stdcall; external kernel32 name 'FreeLibrary';
{$IF NOT Defined( FPC ) AND ( CompilerVersion < 23 )}
procedure GetNativeSystemInfo( lpSystemInfo: LPSYSTEM_INFO ); stdcall; external kernel32 name 'GetNativeSystemInfo';
{$IFEND}
// Copy from SysUtils to get rid of this unit
function StrComp( const Str1, Str2: PAnsiChar ): Integer;
var
P1, P2: PAnsiChar;
begin
P1 := Str1;
P2 := Str2;
while True do
begin
if ( P1^ <> P2^ ) or ( P1^ = #0 ) then
{$IF Defined( FPC ) OR ( CompilerVersion >= 20 )}
Exit( Ord( P1^ ) - Ord( P2^ ) );
{$ELSE}
begin
result := Ord( P1^ ) - Ord( P2^ );
Exit;
end;
{$IFEND}
Inc( P1 );
Inc( P2 );
end;
end;
{$IF NOT Declared( FileExists )}
function FileExists(const FileName: string): Boolean;
//function FileAge(const FileName: string): Integer;
type
LongRec = packed record
case Integer of
0: (Lo, Hi: Word);
1: (Words: array [0..1] of Word);
2: (Bytes: array [0..3] of Byte);
end;
var
Handle: THandle;
FindData: TWin32FindData;
LocalFileTime: TFileTime;
tmp : Integer;
begin
Result := False;
Handle := FindFirstFile(PChar(FileName), FindData);
if Handle <> INVALID_HANDLE_VALUE then
begin
Windows.FindClose(Handle);
if (FindData.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY) = 0 then
begin
FileTimeToLocalFileTime(FindData.ftLastWriteTime, LocalFileTime);
if FileTimeToDosDateTime(LocalFileTime, LongRec(tmp).Hi, LongRec(tmp).Lo) then
begin
result := True;
Exit;
end;
end;
end;
// Result := -1;
//end;
//begin
// Result := FileAge(FileName) <> -1;
end;
{$IFEND}
{$IF NOT Declared( ExceptionErrorMessage )}
type
Exception = class(TObject)
private
Message: string;
end;
function ExceptionErrorMessage(ExceptObject: TObject; ExceptAddr: Pointer; Buffer: PChar; Size: Integer): Integer;
{$IFDEF MSWINDOWS}
function StrLCopy(Dest: PChar; const Source: PChar; MaxLen: Cardinal): PChar; overload;
var
Len: Cardinal;
begin
Result := Dest;
Len := Length(Source);
if Len > MaxLen then
Len := MaxLen;
Move(Source^, Dest^, Len * SizeOf(Char));
Dest[Len] := #0;
end;
function StrScan(const Str: PChar; Chr: Char): PChar;
begin
Result := Str;
while Result^ <> #0 do
begin
if Result^ = Chr then
Exit;
Inc(Result);
end;
if Chr <> #0 then
Result := nil;
end;
function AnsiStrScan(Str: PChar; Chr: Char): PChar;
begin
Result := StrScan(Str, Chr);
(* Needs SysLocale // MS
{$IFNDEF UNICODE}
while Result <> nil do
begin
{$IFDEF MSWINDOWS}
case StrByteType(Str, Integer(Result-Str)) of
mbSingleByte: Exit;
mbLeadByte: Inc(Result);
end;
{$ENDIF MSWINDOWS}
{$IFDEF POSIX}
if StrByteType(Str, Integer(Result-Str)) = mbSingleByte then
Exit;
{$ENDIF POSIX}
Inc(Result);
Result := StrScan(Result, Chr);
end;
{$ENDIF}
*)
end;
{$IFDEF UNICODE}
function StrRScan(const Str: PWideChar; Chr: WideChar): PWideChar;
function StrEnd(const Str: PWideChar): PWideChar;
begin
Result := Str;
while Result^ <> #0 do
Inc(Result);
end;
var
MostRecentFound: PWideChar;
begin
if Chr = #0 then
Result := StrEnd(Str)
else
begin
Result := nil;
MostRecentFound := Str;
while True do
begin
while MostRecentFound^ <> Chr do
begin
if MostRecentFound^ = #0 then
Exit;
Inc(MostRecentFound);
end;
Result := MostRecentFound;
Inc(MostRecentFound);
end;
end;
end;
{$ENDIF}
function AnsiStrRScan(Str: PChar; Chr: Char): PChar;
begin
{$IFDEF UNICODE}
result := StrRScan(Str, Chr);
{$ELSE}
Str := AnsiStrScan(Str, Chr);
Result := Str;
if Chr <> AnsiChar(#$0) then
begin
while Str <> nil do
begin
Result := Str;
Inc(Str);
Str := AnsiStrScan(Str, Chr);
end;
end
{$ENDIF}
end;
function PointerToHex( P : Pointer; TypeSize : Byte; BigEndian : boolean = false ): string;
function ByteToHex( B : Byte ) : String;
const
HexTable : Array[ 0..15 ] of Char = ( '0', '1', '2', '3', '4', '5', '6', '7', '8', '9', 'A', 'B', 'C', 'D', 'E', 'F' );
begin
result := HexTable[ b div 16 ] + HexTable[ b mod 16 ];
end;
type
TBytes = Array [ 0..15 ] of Byte;
PBytes = ^TBytes;
var
Bytes : PBytes absolute P;
i : Integer;
begin
result := '';
if ( P = nil ) then
Exit;
if ( TypeSize > SizeOf( TBytes ) ) then
Exit;
if BigEndian then
begin
for i := Low( Bytes^ ) To TypeSize-1 do
result := result + ByteToHex( Bytes^[ i ] );
end
else
begin
for i := TypeSize-1 downTo Low( Bytes^ ) do
result := result + ByteToHex( Bytes^[ i ] );
end;
i := Pos( ' ', Result );
while ( i <> 0 ) do
begin
Result[ I ] := '0';
i := Pos( ' ', Result );
end;
end;
function ConvertAddr(Address: Pointer): Pointer;
{$IFDEF Win64}
begin
Result := Address;
if Result <> nil then
Dec(PByte(Result), $1000);
end;
{$ELSE}
asm //StackAlignSafe
TEST EAX,EAX { Always convert nil to nil }
JE @@1
SUB EAX, $1000 { offset from code start; code start set by linker to $1000 }
@@1:
end;
{$ENDIF Win64}
var
MsgPtr: PChar;
MsgEnd: PChar;
MsgLen: Integer;
ModuleName: array[0..MAX_PATH] of Char;
Temp: array[0..MAX_PATH] of Char;
// Format: array[0..255] of Char;
Info: TMemoryBasicInformation;
ConvertedAddress: Pointer;
S : String;
begin
VirtualQuery(ExceptAddr, Info, sizeof(Info));
if (Info.State <> MEM_COMMIT) or
(GetModuleFilename(THandle(Info.AllocationBase), Temp, SizeOf(Temp)) = 0) then
begin
GetModuleFileName(HInstance, Temp, SizeOf(Temp));
ConvertedAddress := ConvertAddr(ExceptAddr);
end
else
IntPtr(ConvertedAddress) := IntPtr(ExceptAddr) - IntPtr(Info.AllocationBase);
StrLCopy( ModuleName, AnsiStrRScan(Temp, '\') + 1, SizeOf(ModuleName) - 1 );
MsgPtr := '';
MsgEnd := '';
if Assigned( ExceptObject ) then // ExceptObject.ClassNameIs( 'Exception' ) then
begin
MsgPtr := PChar(Exception(ExceptObject).Message);
MsgLen := Length(MsgPtr);
if (MsgLen <> 0) and (MsgPtr[MsgLen - 1] <> '.') then
MsgEnd := '.';
end;
// LoadString(FindResourceHInstance(HInstance),
// PResStringRec(@SException).Identifier, Format, SizeOf(Format));
S := 'Exception' + ' ' + ExceptObject.ClassName +' in Modul ' + ModuleName + ' bei ' + PointerToHex( @ConvertedAddress, SizeOf( ConvertedAddress ) ) + '.'+#13#10 + ' ' + MsgPtr + MsgEnd + #13#10;
FillChar( Buffer[ 0 ], Size, 0 );
Result := Length( S );
Move( S[ 1 ], Buffer[ 0 ], Result );
end;
{$ENDIF}
{$IF defined(LINUX) or defined(MACOS) or defined(ANDROID)}
const
UnknownModuleName = '<unknown>';
var
MsgPtr: PChar;
MsgEnd: PChar;
MsgLen: Integer;
Modulename: string;
Info: dl_info;
begin
MsgPtr := '';
MsgEnd := '';
if ExceptObject is Exception then
begin
MsgPtr := PChar(Exception(ExceptObject).Message);
MsgLen := StrLen(MsgPtr);
if (MsgLen <> 0) and (MsgPtr[MsgLen - 1] <> '.') then MsgEnd := '.';
end;
if (dladdr(IntPtr(ExceptAddr), Info) <> 0) and (Info.dli_fname <> nil) then
begin
ModuleName := string(Info.dli_fname);
ModuleName := Modulename.SubString(Modulename.LastIndexOf( PathDelim) + 1)
end
else
begin
ModuleName := UnknownModuleName;
end;
StrLFmt(Buffer, Size, PChar(SException), [ExceptObject.ClassName, ModuleName,
ExceptAddr, MsgPtr, MsgEnd]);
Result := StrLen(Buffer);
end;
{$IFEND LINUX or MACOS or ANDROID}
{$IFEND}
{ +++++++++++++++++++++++++++++++++++++++++++++++++++++
*** Missing WinAPI macros ***
----------------------------------------------------- }
{$IF NOT DECLARED( IMAGE_ORDINAL )}
// #define IMAGE_ORDINAL64( Ordinal ) ( Ordinal & 0xffff )
// #define IMAGE_ORDINAL32( Ordinal ) ( Ordinal & 0xffff )
function IMAGE_ORDINAL( Ordinal: NativeUInt ): Word; {$IF Defined( FPC ) OR ( CompilerVersion >= 22 )}inline;{$IFEND}
begin
Result := Ordinal and $FFFF;
end;
{$IFEND}
{$IF NOT DECLARED( IMAGE_SNAP_BY_ORDINAL )}
// IMAGE_SNAP_BY_ORDINAL64( Ordinal ) ( ( Ordinal & IMAGE_ORDINAL_FLAG64 ) != 0 )
// IMAGE_SNAP_BY_ORDINAL32( Ordinal ) ( ( Ordinal & IMAGE_ORDINAL_FLAG32 ) != 0 )
function IMAGE_SNAP_BY_ORDINAL32( Ordinal: NativeUInt ): Boolean; {$IF Defined( FPC ) OR ( CompilerVersion >= 22 )}inline;{$IFEND}
begin
Result := ( ( Ordinal and IMAGE_ORDINAL_FLAG32 ) <> 0 );
end;
function IMAGE_SNAP_BY_ORDINAL64( Ordinal: NativeUInt ): Boolean; {$IF Defined( FPC ) OR ( CompilerVersion >= 22 )}inline;{$IFEND}
begin
Result := ( ( Ordinal and IMAGE_ORDINAL_FLAG64 ) <> 0 );
end;
{$IFEND}
function GET_HEADER_DICTIONARY( module: PMemoryModule; idx: Integer ): PIMAGE_DATA_DIRECTORY;
begin
if module^.headers.X64 then
Result := PIMAGE_DATA_DIRECTORY( @( module.headers.headers64.OptionalHeader.DataDirectory[ idx ] ) )
else
Result := PIMAGE_DATA_DIRECTORY( @( module.headers.headers32.OptionalHeader.DataDirectory[ idx ] ) );
end;
function IMAGE_FIRST_SECTION( NtHeader: PIMAGE_NT_HEADERS32 ): PImageSectionHeader;
var
OptionalHeaderAddr: PByte;
begin
OptionalHeaderAddr := PByte( @NtHeader^.OptionalHeader );
Inc( OptionalHeaderAddr, NtHeader^.FileHeader.SizeOfOptionalHeader );
Result := PImageSectionHeader( OptionalHeaderAddr );
end;
function CopySections( data: Pointer; old_headers: PIMAGE_NT_HEADERS32; module: PMemoryModule ): Boolean;
var
i, size: Integer;
codebase: Pointer;
dest: Pointer;
section: PIMAGE_SECTION_HEADER;
begin
codebase := module.codeBase;
section := PIMAGE_SECTION_HEADER( IMAGE_FIRST_SECTION( module.headers.headers32 ) );
for i := 0 to module.headers.headers32.FileHeader.NumberOfSections - 1 do
begin
// section doesn't contain data in the dll itself, but may define
// uninitialized data
if section.SizeOfRawData = 0 then
begin
if module.headers.X64 then
size := PIMAGE_NT_HEADERS64( old_headers ).OptionalHeader.SectionAlignment
else
size := old_headers.OptionalHeader.SectionAlignment;
if size > 0 then
begin
dest := VirtualAlloc(
{$IF Defined( FPC ) OR ( CompilerVersion >= 20 )}
PByte( codebase ) + section.VirtualAddress,
{$ELSE}
PAnsiChar( codebase ) + section.VirtualAddress,
{$IFEND}
size, MEM_COMMIT, PAGE_EXECUTE_READWRITE );
if dest = nil then
{$IF Defined( FPC ) OR ( CompilerVersion >= 20 )}
Exit( false );
{$ELSE}
begin
result := false;
Exit;
end;
{$IFEND}
// Always use position from file to support alignments smaller
// than page size.
{$IF Defined( FPC ) OR ( CompilerVersion >= 20 )}
dest := PByte( codebase ) + section.VirtualAddress;
{$ELSE}
dest := PAnsiChar( codebase ) + section.VirtualAddress;
{$IFEND}
section.Misc.PhysicalAddress := Cardinal( dest );
ZeroMemory( dest, size );
end;
// section is empty
Inc( section );
Continue;
end;
// commit memory block and copy data from dll
dest := VirtualAlloc(
{$IF Defined( FPC ) OR ( CompilerVersion >= 20 )}
PByte( codebase ) + section.VirtualAddress,
{$ELSE}
PAnsiChar( codebase ) + section.VirtualAddress,
{$IFEND}
section.SizeOfRawData,
MEM_COMMIT,
PAGE_EXECUTE_READWRITE );
if dest = nil then
{$IF Defined( FPC ) OR ( CompilerVersion >= 20 )}
Exit( false );
{$ELSE}
begin
result := false;
Exit;
end;
{$IFEND}
// Always use position from file to support alignments smaller
// than page size.
{$IF Defined( FPC ) OR ( CompilerVersion >= 20 )}
dest := PByte( codebase ) + section.VirtualAddress;
CopyMemory( dest, PByte( data ) + section.PointerToRawData, section.SizeOfRawData );
{$ELSE}
dest := PAnsiChar( codebase ) + section.VirtualAddress;
CopyMemory( dest, PAnsiChar( data ) + section.PointerToRawData, section.SizeOfRawData );
{$IFEND}
section.Misc.PhysicalAddress := Cardinal( dest );
Inc(section);
end; // for
Result := True;
end;
// Protection flags for memory pages ( Executable, Readable, Writeable )
const
ProtectionFlags: array[ Boolean, Boolean, Boolean ] of Cardinal =
(
(
// not executable
( PAGE_NOACCESS, PAGE_WRITECOPY ),
( PAGE_READONLY, PAGE_READWRITE )
),
(
// executable
( PAGE_EXECUTE, PAGE_EXECUTE_WRITECOPY ),
( PAGE_EXECUTE_READ, PAGE_EXECUTE_READWRITE )
)
);
function FinalizeSection( module: PMemoryModule; const sectionData: TSectionFinalizeData ): Boolean;
var
protect, oldProtect: Cardinal;
executable, readable, writeable: Boolean;
begin
if sectionData.size = 0 then
{$IF Defined( FPC ) OR ( CompilerVersion >= 20 )}
Exit( True );
{$ELSE}
begin
result := True;
Exit;
end;
{$IFEND}
if ( sectionData.characteristics and IMAGE_SCN_MEM_DISCARDABLE ) <> 0 then
begin
// section is not needed any more and can safely be freed
if ( sectionData.address = sectionData.alignedAddress ) and
( sectionData.last or
( NOT module.headers.X64 AND ( module.headers.headers32.OptionalHeader.SectionAlignment = module.pageSize ) ) or
( module.headers.X64 AND ( module.headers.headers64.OptionalHeader.SectionAlignment = module.pageSize ) ) or
( sectionData.size mod module.pageSize = 0 ) ) then
// Only allowed to decommit whole pages
VirtualFree( sectionData.address, sectionData.size, MEM_DECOMMIT );
{$IF Defined( FPC ) OR ( CompilerVersion >= 20 )}
Exit( True );
{$ELSE}
result := True;
Exit;
{$IFEND}
end;
// determine protection flags based on characteristics
executable := ( sectionData.characteristics and IMAGE_SCN_MEM_EXECUTE ) <> 0;
readable := ( sectionData.characteristics and IMAGE_SCN_MEM_READ ) <> 0;
writeable := ( sectionData.characteristics and IMAGE_SCN_MEM_WRITE ) <> 0;
protect := ProtectionFlags[ executable ][ readable ][ writeable ];
if ( sectionData.characteristics and IMAGE_SCN_MEM_NOT_CACHED ) <> 0 then
protect := protect or PAGE_NOCACHE;
// change memory access flags
Result := VirtualProtect( sectionData.address, sectionData.size, protect, oldProtect );
end;
function FinalizeSections( module: PMemoryModule ): Boolean;
function GetRealSectionSize( module: PMemoryModule; section: PIMAGE_SECTION_HEADER ): Cardinal;
begin
Result := section.SizeOfRawData;
if Result = 0 then
if ( section.Characteristics and IMAGE_SCN_CNT_INITIALIZED_DATA ) <> 0 then
begin
if module.headers.X64 then
Result := module.headers.headers64.OptionalHeader.SizeOfInitializedData
else
Result := module.headers.headers32.OptionalHeader.SizeOfInitializedData;
end
else if ( section.Characteristics and IMAGE_SCN_CNT_UNINITIALIZED_DATA ) <> 0 then
begin
if module.headers.X64 then
Result := module.headers.headers64.OptionalHeader.SizeOfUninitializedData
else
Result := module.headers.headers32.OptionalHeader.SizeOfUninitializedData;
end;
end;
function ALIGN_DOWN( address: Pointer; alignment: Cardinal ): Pointer;
begin
Result := Pointer( UINT_PTR( address ) and not ( alignment - 1 ) );
end;
var
i: Integer;
section: PIMAGE_SECTION_HEADER;
imageOffset: UINT_PTR;
sectionData: TSectionFinalizeData;
sectionAddress, alignedAddress: Pointer;
sectionSize: Cardinal;
begin
section := PIMAGE_SECTION_HEADER( IMAGE_FIRST_SECTION( module.headers.headers32 ) );
if module.headers.X64 then
imageOffset := ( NativeUInt( module.codeBase ) and $ffffffff00000000 )
else
imageOffset := 0;
// {$IFDEF CPUX64}
// imageOffset := ( NativeUInt( module.codeBase ) and $ffffffff00000000 );
// {$ELSE}
// imageOffset := 0;
// {$ENDIF}
sectionData.address := Pointer( UINT_PTR( section.Misc.PhysicalAddress ) or imageOffset );
sectionData.alignedAddress := ALIGN_DOWN( sectionData.address, module.pageSize );
sectionData.size := GetRealSectionSize( module, section );
sectionData.characteristics := section.Characteristics;
sectionData.last := False;
Inc( section );
// loop through all sections and change access flags
for i := 1 to module.headers.headers32.FileHeader.NumberOfSections - 1 do
begin
sectionAddress := Pointer( UINT_PTR( section.Misc.PhysicalAddress ) or imageOffset );
alignedAddress := ALIGN_DOWN( sectionData.address, module.pageSize );
sectionSize := GetRealSectionSize( module, section );
// Combine access flags of all sections that share a page
// TODO( fancycode ): We currently share flags of a trailing large section
// with the page of a first small section. This should be optimized.
if ( sectionData.alignedAddress = alignedAddress ) or
{$IF Defined( FPC ) OR ( CompilerVersion >= 20 )}
( PByte( sectionData.address ) + sectionData.size > PByte( alignedAddress ) ) then
{$ELSE}
( PAnsiChar( sectionData.address ) + sectionData.size > PAnsiChar( alignedAddress ) ) then
{$IFEND}
begin