build.gradle

plugins {
    id "architectury-plugin" version "3.4-SNAPSHOT"
    // Uses Architectury plugin https://github.com/architectury/architectury-plugin
    id "dev.architectury.loom" version "1.7-SNAPSHOT" apply false // Uses Architectury Loom
    id "me.shedaniel.unified-publishing" version "0.1.+" apply false // Uses Unified Publishing plugin
    id "org.cadixdev.licenser" version "0.6.1" apply false // Uses Licensing plugin
}

architectury {
    minecraft = rootProject.minecraft_version // Sets Minecraft version from gradle.properties
}

allprojects {
    def runNumber = (System.getenv("GITHUB_RUN_NUMBER") == null ? "9999" : System.getenv("GITHUB_RUN_NUMBER"))

    version = rootProject.mod_version + "-" + runNumber
    group = rootProject.maven_group

    gradle.projectsEvaluated {
        tasks.withType(JavaCompile).tap {
            configureEach {
                options.compilerArgs << "-Xlint:unchecked" //<< "-Xlint:deprecation"
            }
        }
    }

    // Set mod relations
    ec_mod_compat_enabled = minecraft_version == "1.20.1" || minecraft_version == "1.21" || minecraft_version == "1.21.1"
    lunar_mod_compat_enabled = minecraft_version == "1.20.1" || minecraft_version == "1.21" || minecraft_version == "1.21.1"
    cm_mod_compat_enabled = minecraft_version == "1.19" || minecraft_version == "1.19.1"
}

subprojects {
    apply plugin: "dev.architectury.loom" // Applies Architectury Loom to subprojects
    apply plugin: "architectury-plugin" // Applies architectury plugin to all projects
    apply plugin: "me.shedaniel.unified-publishing" // Applies Unified Publishing to subprojects
    apply plugin: 'org.cadixdev.licenser' // Applies licenser plugin to all projects
    apply plugin: "maven-publish"

    base {
        // Set up a suffixed format for the mod jar names, e.g. `example-fabric`.
        archivesName = "$rootProject.archives_base_name-$project.name"
    }

    repositories {
        maven {
            url "https://cursemaven.com"
            content {
                includeGroup "curse.maven"
            }
        }
        maven { url "https://maven.shedaniel.me/" }
        maven { url "https://maven.terraformersmc.com/releases/" }
        maven { url "https://maven.draylar.dev/releases" }
        maven { url "https://api.modrinth.com/maven" }
        maven { url "https://maven.nucleoid.xyz/" }
    }

    loom {
        silentMojangMappingsLicense() // Silences the annoying Mojang License text
    }

    dependencies {
        minecraft "net.minecraft:minecraft:$rootProject.minecraft_version"
        mappings loom.officialMojangMappings()
    }


    java {
        // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
        // if it is present.
        // If you remove this line, sources will not be generated.
        withSourcesJar()

        sourceCompatibility = JavaVersion.VERSION_21
        targetCompatibility = JavaVersion.VERSION_21
    }

    tasks.withType(JavaCompile).configureEach {
        it.options.release = 21
    }

    jar {
        from(rootProject.file("LICENSE")) {
            rename { "${it}_${mod_id}" }
        }
        manifest {
            attributes([
                    'Specification-Title'     : mod_name,
                    'Specification-Vendor'    : mod_author,
                    'Specification-Version'   : project.jar.archiveVersion,
                    'Implementation-Title'    : project.name,
                    'Implementation-Version'  : project.jar.archiveVersion,
                    'Implementation-Vendor'   : mod_author,
                    'Implementation-Timestamp': new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
                    'Timestamp'               : System.currentTimeMillis(),
                    'Built-On-Java'           : "${System.getProperty('java.vm.version')} (${System.getProperty('java.vm.vendor')})",
                    'Build-On-Minecraft'      : minecraft_version
            ])
        }
    }

    license {
        setHeader(rootProject.file("LICENSE_HEADER"))

        ext {
            name = "Urkaz - Fran Sánchez"
            year = "2025"
            modname = rootProject.mod_name
        }

        include "**/*.java"

        ignoreFailures = true
    }

    publishing {
        // See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
        repositories {
            if (System.getenv("urkaz_maven_pass") != null) {
                maven {
                    name "${archives_base_name}"
                    url "https://maven.franserver.mywire.org/releases"
                    credentials {
                        username = "autodeploy"
                        password = System.getenv("urkaz_maven_pass")
                    }
                }
            }
        }
    }
}

tasks.register('modPublish')