build.gradle

plugins {
    id "org.springframework.boot" version "2.2.8.RELEASE"
    id "io.spring.dependency-management" version "1.0.9.RELEASE"
    id 'eclipse'
    id 'idea'
    id 'maven'
}


allprojects {
  repositories {
    maven {
        url "http://maven.aliyun.com/nexus/content/groups/public/"
    }
    maven { url "https://oss.sonatype.org/content/repositories/snapshots" }
    maven { url "https://dl.bintray.com/ethereum/maven/" }
    mavenLocal()  
    jcenter() 
  }
}

subprojects {
  version = "1.3.1"
  apply plugin: "java"
  apply plugin: "org.springframework.boot"
  apply plugin: "io.spring.dependency-management"

  sourceCompatibility = '1.8'
  targetCompatibility = '1.8'

  def defaultEncoding = 'UTF-8'
  tasks.withType(AbstractCompile).each { it.options.encoding = defaultEncoding }

  javadoc {
    options.encoding = defaultEncoding
    options.addBooleanOption('Xdoclint:none', true)
  }

  compileJava.dependsOn(processResources)


  springBoot {
    buildInfo()
  }

  dependencyManagement {
    imports {
      mavenBom org.springframework.boot.gradle.plugin.SpringBootPlugin.BOM_COORDINATES
    }
  }

  test {
    useJUnitPlatform()
  }

  dependencies {
    annotationProcessor "org.springframework.boot:spring-boot-configuration-processor"
    compileOnly "org.springframework.boot:spring-boot-configuration-processor"
    implementation "org.springframework.boot:spring-boot-starter-web" 
    implementation "org.springframework.boot:spring-boot-starter-aop" 
    compile 'cn.hutool:hutool-all:5.3.7'
     // web3j依赖
    implementation ('org.fisco-bcos:web3sdk:2.4.2')
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'   

    testImplementation('org.springframework.boot:spring-boot-starter-test') {
        exclude group: 'org.junit.vintage', module: 'junit-vintage-engine'
    }
  }
}

project(':WeBASE-Collect-Bee-core') {
  dependencies {
    implementation project(':WeBASE-Collect-Bee-parser')
    implementation project(':WeBASE-Collect-Bee-common')
    implementation project(':WeBASE-Collect-Bee-db')
    implementation project(':WeBASE-Collect-Bee-extractor')   
    implementation "io.springfox:springfox-swagger2:2.9.2"
    implementation "io.springfox:springfox-swagger-ui:2.9.2"
    implementation('com.ibeetl:beetl:2.9.3')
    implementation "org.springframework.boot:spring-boot-starter-data-jpa"
    implementation 'mysql:mysql-connector-java'
    implementation('org.apache.shardingsphere:sharding-jdbc-spring-boot-starter:4.0.1')
    
    // elastic-job
    implementation('com.dangdang:elastic-job-lite-core:2.1.5')
    {
        exclude group: 'log4j'
    }
    implementation('com.dangdang:elastic-job-lite-spring:2.1.5')
    {
        exclude group: 'log4j'
    }
   
  }
}

project(':WeBASE-Collect-Bee-extractor') {
  dependencies {
    implementation project(':WeBASE-Collect-Bee-common')
  }
}

project(':WeBASE-Collect-Bee-parser') {
  dependencies {
    implementation project(':WeBASE-Collect-Bee-extractor')   
    implementation project(':WeBASE-Collect-Bee-common')
  }
}

project(':WeBASE-Collect-Bee-db') {
  dependencies {
    implementation project(':WeBASE-Collect-Bee-extractor')   
    implementation project(':WeBASE-Collect-Bee-common')
    implementation project(':WeBASE-Collect-Bee-parser')   
    implementation "org.springframework.boot:spring-boot-starter-data-jpa"
    implementation 'mysql:mysql-connector-java'
    implementation('org.apache.shardingsphere:sharding-jdbc-spring-boot-starter:4.0.1')

  }
}

configurations {
    all {
        exclude group: 'org.slf4j', module: 'slf4j-log4j12'
        resolutionStrategy.cacheChangingModulesFor 0, 'seconds'
    }
}

wrapper {
  gradleVersion = "5.4.1"
}