settings.gradle

rootProject.name = "CommonUtils"
include ':library'
include ':sample-app'
include ':sample-app-java'

enableFeaturePreview('VERSION_CATALOGS')
dependencyResolutionManagement {
    versionCatalogs {
        dep {
            version('androidx-core', '1.7.0')
            alias('androidx-core').to('androidx.core', 'core').versionRef('androidx-core')
            alias('androidx-coreKtx').to('androidx.core', 'core-ktx').versionRef('androidx-core')

            alias('guava').to('com.google.guava:guava:27.0.1-android')
            alias('maps').to('com.google.android.gms:play-services-maps:17.0.1')
            alias('timber').to('com.jakewharton.timber:timber:5.0.1')
            alias('multidex').to('androidx.multidex:multidex:2.0.1')

            version('coroutines', '1.5.2')
            alias('coroutines-core').to('org.jetbrains.kotlinx', 'kotlinx-coroutines-core').versionRef('coroutines')
            alias('coroutines-android').to('org.jetbrains.kotlinx', 'kotlinx-coroutines-android').versionRef('coroutines')
            bundle('coroutines', ['coroutines-core', 'coroutines-android'])

            version('glide', '4.11.0')
            alias('glide-core').to('com.github.bumptech.glide', 'glide').versionRef('glide')
            alias('glide-compiler').to('com.github.bumptech.glide', 'compiler').versionRef('glide')
            bundle('glide', ['glide-core', 'glide-compiler'])

            alias('androidx-appcompat').to('androidx.appcompat:appcompat:1.4.0')
            alias('androidx-constraintlayout').to('androidx.constraintlayout:constraintlayout:2.1.2')
            alias('android-material').to('com.google.android.material:material:1.4.0')
            bundle('ui', ['androidx-appcompat', 'androidx-constraintlayout', 'android-material'])

            alias('junit-jupiter').to('org.junit.jupiter:junit-jupiter-api:5.7.1')
            alias('junit-engine').to('org.junit.jupiter:junit-jupiter-engine:5.7.1')
            alias('androidx-junit').to('androidx.test.ext:junit:1.1.3')
            alias('androidx-espresso').to('androidx.test.espresso:espresso-core:3.4.0')
            bundle('androidTest', ['androidx-junit', 'androidx-espresso'])
        }

        plugin {
            alias('android-gradle').to('com.android.tools.build:gradle:7.0.4')
            alias('jetbrains-kotlin').to('org.jetbrains.kotlin:kotlin-gradle-plugin:1.6.10')
            alias('jetbrains-dokka').to('org.jetbrains.dokka:dokka-gradle-plugin:1.5.0')
            alias('nexus-publish').to('io.github.gradle-nexus:publish-plugin:1.1.0')
        }
    }
}

dependencyResolutionManagement {
    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
    repositories {
        google()
        mavenCentral()
    }
}