domain as argument

[klipus]

Hi, I have a question regarding passing domain from service class to different domain. currently my code is:
OpportunitiesTriggerHandler:

    public override void onBeforeInsert() {
        updateOpportunityApprovers();
    }
    private void updateOpportunityApprovers(){
        OpportunitiesService.updateOpportunityApprovers(getRecords());
    }

OpportunitiesService:

	public static void updateOpportunityApprovers(List<Opportunity> records){
		service().updateOpportunityApprovers(records);
	}

OpportunitiesServiceImpl:

    public void updateOpportunityApprovers(List<Opportunity> records){
        updateOpportunityApprovers(Opportunities.newInstance(records));
    }

    public void updateOpportunityApprovers(IOpportunities domain){      
        IInvoiceLocationSectors invLocSectors = InvoiceLocationSectors.newInstance(
                InvoiceLocationSectorsSelector.newInstance().selectByInvLocId(invoiceIds)
        );

        domain.updateApproversFromInvLocSector(invLocSectors);
    }

Opportunities:

    public void updateApproversFromInvLocSector(IInvoiceLocationSectors invLocSectors){
        for (Opportunity record : (List<Opportunity>) getRecords()){
            List<Invoice_Location_Sector__c> filteredSectors = 
                invLocSectors.filterByInvLocAndSector(
                    record.Invoice_Location__c,
                    record.Sector__c
            );

            if(filteredSectors.isEmpty()){ continue; }
            ..... update opportunity fields ...
        }
    }

I think this is working fine, but currently I'm struggling with related service test class:

...
        List<Invoice_Location_Sector__c> invLocSectors = new List<Invoice_Location_Sector__c>{
            new Invoice_Location_Sector__c(Id = fflib_IDGenerator.generate(Schema.Invoice_Location_Sector__c.SObjectType))
        };
        InvoiceLocationSectors invLocDomain = (InvoiceLocationSectors) InvoiceLocationSectors.newInstance(invLocSectors);
       ((IOpportunities) mocks.verify(oppDomainMock)).updateApproversFromInvLocSector(invLocDomain);

fflib_ApexMocks.ApexMocksException: EXPECTED COUNT: 1
ACTUAL COUNT: 0

So, my question is if it is a good approach to pass InvoiceLocationSectors domain to Opportunities domain to do the filtering or it would be better to update the record in implementation class?

[wimvelzeboer]

Hi @klipus
I would avoid passing a domain to another domain, in my definition a domain should not be aware of anything outside itself.

Would I typically would do, is that you use a getter method to extract the data from the domain into a map with primitive data types and pass that into a setter method of the other domain. Then you have the highest possibility of re-use for both methods.

Something like this:

IOpportunities opportunities = Opportunities.newInstance(records);

IInvoiceLocationSectors filteredSectors = InvoiceLocationSectors.newInstance(
                InvoiceLocationSectorsSelector.newInstance().selectByInvLocId(invoiceIds)
        )
             .selectByInvoiceLocation( opportunities.getInvoiceLocations() )
             .selectBySector( opportinities.getSectors() );

if (filteredSectors.isEmpty(){ return; }

opportunities.selectById( filteredSectors.getOpportunityId() )    
   .setStatus('Something');

Note: try to avoid methods like filterByInvLocAndSector which basically do two things, that will reduce the chance of re-use significantly

[wimvelzeboer]

Ok, then I would write something like:

IOpportunitities opportunitites = Opportunities.newInstance(records);
// get the Invoice Locations from Opportunities
Set<Id> invoiceLocationIds = opportunitites.getInvoiceLocationIds();
// get the sector by Invoice Locations
Map<Id, Id> SectorIdByinvoiceLocationId = InvoiceLocations.newInstance(invoiceLocationIds);
// set the Sector__c field on Opportunities by the Invoice Locations
opportunitites.setSectorIdByInvoiceLocationsId(SectorIdByinvoiceLocationId);

In the domain classes it will look something like:
Opportuntities

public Set<Id> getInvoiceLocationIds()
{
   return getIdFieldValues(Opportunity.Invoice_Location__c);
}

// SectorIdByinvoiceLocationId key = locationId, value = sector Id
public IOpportunities setSectorIdByInvoiceLocationsId(Map<Id, Id> SectorIdByinvoiceLocationId)
{
   setFieldValueByMap(Opportunity.Invoice_Location__c, Opportunity.Sector__c, SectorIdByinvoiceLocationId);
   return this;
}

[klipus]

let me try to explain the situation on this example:

new Opportunity( Name = 'test', Invoice_Location__c = 'invLoc1Id', Sector__c = 'sectorName1', Approver__c = null );
Invoice_Location__c( Id = 'invLoc1Id' );
Invoice_Location__c( Id = 'invLoc2Id' );
Invoice_Location_Sector__c( Id = 'invLocSect0Id', Sector__c = 'sectorName0', Invoice_Location__c = 'invLoc1Id', User__c = 'user1Id' );
Invoice_Location_Sector__c( Id = 'invLocSect1Id', Sector__c = 'sectorName1', Invoice_Location__c = 'invLoc1Id', User__c = 'user2Id'  );
Invoice_Location_Sector__c( Id = 'invLocSect2Id', Sector__c = 'sectorName2', Invoice_Location__c = 'invLoc1Id', User__c = 'user1Id'  );

so when creating the Opportunity, I want to grab Invoice_Location__c with Id = 'invLoc1Id', get all related Invoice_Location_Sector__c records (in this case all 3 records ) and filter them to get one with Sector__c ( String ) = 'sectorName1' ( from Opportunity ). So in this case I would like to copy 'user2Id' to the newly created Opportunity ( field Approver__c )

[wimvelzeboer]

Ah I understand the complexity you are facing.
It is still possible in the way I was explaining earlier but the map with primitive data is slightly more complex.

Your handler/service should look something like this:

IOpportunities opportunities = Opportunities.newInstance(records);
Set<Id> invoiceLocations = opportunities.getInvoiceLocations();
Set<String> sectorNames = opportunities.getSectorNames();

IInvoiceLocations invoiceLocations = 
    InvoiceLocations.newInstance(
        InvoiceLocationsSelector.newInstance()
            .selectByInvoiceLocationIdAndSectorName(invoiceLocations, sectorNames)
				);
Map<Id, Map<String, Id>> userIdBySectorNameByInvoiceLocationId = 
    invoiceLocations.getUserIdBySectorNameByInvoiceLocationId();
		
opportunities.setApproverByInvoiceLocationIdBySectorName(
    userIdBySectorNameByInvoiceLocationId);	

and your Opportunities domain should have this method:

public IOpportunities setApproverByInvoiceLocationIdBySectorName(
	Map<Id, Map<String, Id>> values)
{
    for (Opportunity record : getOpportunities())
    {
        if (record.Invoice_Location__c == null || String.isBlank(record.Sector__c)
                || values.containsKey(record.Invoice_Location__c) == false
                || values.get(record.Invoice_Location__c).containsKey(record.Sector__c) == false)
                         continue;

            record.Approver__c = values.get(record.Invoice_Location__c).get(record.Sector__c);
    }
    return this;
}

[klipus]

I think, that's it! Thank you for your help..

I can see two more possible challenges here:

1. you mentioned map with primitive data types. Currently we copy one Approver field, but in reality there are like 10 fields we need to copy. It would make Map<Id, Map<String, Map<String, Id>>>?
2. If I needed to add another filter (eg. Sub_Sector__c), it would be Map<Id, Map<String, Map<String, Id>>>
   ... and the combination of both of them would be very complex.

But I guess there is no way around..

[klipus]

I was thinking about scenario 1 and I found these possible solutions:

• create Map<Id, Map<String, Map<String, Id>>>
• create getFieldBySectorNameByInvoiceLocationId(String fieldName) => I would need to create 10 Maps in implementation class anyway
• break the rule of primitive data type and create getInvoiceLocationSectorBySectorNameByInvoiceLocationId(), which still looks like the best approach

and regarding scenario 2, I did not find any better solution (except maybe using concatenated Sector__c and Sub_Sector__c as a Map key)

[ImJohnMDaniel]

@klipus -- going back to your original question and issue about the problem that you are having with the unit test, I am assuming that you are using the ApplicationFactory pattern and thus are utilizing an Application.cls in your codebase. You mentioned in you exert that your test method was the following:

    List<Invoice_Location_Sector__c> invLocSectors = new List<Invoice_Location_Sector__c>{
        new Invoice_Location_Sector__c(Id = fflib_IDGenerator.generate(Schema.Invoice_Location_Sector__c.SObjectType))
    };
    InvoiceLocationSectors invLocDomain = (InvoiceLocationSectors) InvoiceLocationSectors.newInstance(invLocSectors);
    ((IOpportunities) mocks.verify(oppDomainMock)).updateApproversFromInvLocSector(invLocDomain);

When you defined oppDomainMock did you also tell the Application.Domain factory about the mock via Application.Domain.setMock() method (ref)??

Would you also please provide the full unit test method?

In general, I am not seeing anything obviously wrong with the original implementation that you have setup. It is acceptable to pass one domain interface to another domain and generally is a simpler approach.

[klipus]

Hi @ImJohnMDaniel, I reverted back all my recent changes and noticed that you're right. I had setMock for Opportunity domain, but not for the Invoice Location Sector. After adding that, it is working fine.
So, thank you both, it was a great lesson

[ImJohnMDaniel]

Good to hear @klipus. All the best.