PKGBUILD

pkgname=devtools-arch4edu-extra
pkgver=12.3c44e3c
pkgrel=1
pkgdesc='Extra tools for arch4edu package maintainers'
arch=('x86_64' 'armv7h' 'aarch64')
url='http://github.com/arch4edu/devtools-arch4edu-extra'
license=('GPL')
depends=('devtools')
makedepends=('git')
source=("git+${url}.git")
sha256sums=('SKIP')

pkgver() {
	cd "$srcdir/$pkgname"
	echo "$(git rev-list --count master).$(git rev-parse --short master)"
}

package() {
	cd "$srcdir/$pkgname"
	mkdir -p $pkgdir/usr/bin
	mkdir -p $pkgdir/usr/share/devtools

	if [ "$CARCH" = 'x86_64' ]
	then
		mkdir -p $pkgdir/usr/share/devtools/makepkg.conf.d
		mkdir -p $pkgdir/usr/share/devtools/pacman.conf.d
		ln -sf /usr/bin/archbuild $pkgdir/usr/bin/arch4edu-x86_64-build
		cat /usr/share/devtools/pacman.conf.d/extra.conf arch4edu.conf > $pkgdir/usr/share/devtools/pacman.conf.d/arch4edu.conf
		cat /usr/share/devtools/pacman.conf.d/multilib.conf arch4edu.conf > $pkgdir/usr/share/devtools/pacman.conf.d/multilib-arch4edu.conf
	else
		for i in armv7h aarch64
		do
			cp $srcdir/$pkgname/pacman-extra-$i.conf $pkgdir/usr/share/devtools/
			cp $srcdir/$pkgname/makepkg-$i.conf $pkgdir/usr/share/devtools/
			ln -sf /usr/bin/archbuild $pkgdir/usr/bin/extra-$i-build
		done
	fi
}