RFIDListUpdaterTest.apxc

@isTest
private class RFIDListUpdaterTest {
    static testMethod void onlyReturnCurrentRfidTags() {
        RestContext.response = new RestResponse();
        
		addContact('validTag', 'Yes');
        addContact('expiredTag', 'No');
        
        String result = RFIDListUpdater.getTagList();
        
        System.assertEquals('validTag|', result);
    }
    
    static testMethod void returnPipeDelimitedTags() {
        RestContext.response = new RestResponse();
        
		addContact('validTag1', 'Yes');
        addContact('validTag2', 'Yes');
        
        String result = RFIDListUpdater.getTagList();
        
        System.assertEquals('validTag1|validTag2|', result);
    }
    
    static testMethod void addTextPlainContentTypeToResponse() {
        RestContext.response = new RestResponse();
        
        addContact('', 'Yes');
        RFIDListUpdater.getTagList();
        
        String contentType = RestContext.response.headers.get('Content-Type');
        
        System.assertEquals('text/plain', contentType);
    }
    
    static testmethod void emptyResponseWhenNoValidTags() {
        RestContext.response = new RestResponse();
        
        String response = RFIDListUpdater.getTagList();
        
        System.assertEquals('', response);
    }
    
    static testmethod void shouldStripEmptyRfidTagValues() {
        RestContext.response = new RestResponse();
        
        addContact('validTag1', 'Yes');
        addContact('', 'Yes');
        addContact('validTag2', 'Yes');
        String response = RFIDListUpdater.getTagList();
        
        System.assertEquals('validTag1|validTag2|', response);
    }
    
    private static void addContact(String tag, String isCurrentMember) {
        Contact currentMember = new Contact(Tag_ID__c=tag, Current_Member__c=isCurrentMember,
                                           LastName='RequiredField');
        insert currentMember;
    }
}