-
Notifications
You must be signed in to change notification settings - Fork 4
/
remaken_arch_define.pri
258 lines (245 loc) · 9.28 KB
/
remaken_arch_define.pri
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
# Author(s) : Loic Touraine
REMAKEN_BUILD_RULES_FOLDER = .build-rules
REMAKEN_INFO_SUFFIX=remakeninfo.txt
!win32 {
include(builddefs_info.pri)
}
android {
# unix path
USERHOMEFOLDER = $$clean_path($$(HOME))
isEmpty(USERHOMEFOLDER) {
# windows path
USERHOMEFOLDER = $$clean_path($$(USERPROFILE))
isEmpty(USERHOMEFOLDER) {
USERHOMEFOLDER = $$clean_path($$(HOMEDRIVE)$$(HOMEPATH))
}
}
}
unix:!android {
USERHOMEFOLDER = $$clean_path($$(HOME))
}
win32 {
USERHOMEFOLDER = $$clean_path($$(USERPROFILE))
isEmpty(USERHOMEFOLDER) {
USERHOMEFOLDER = $$clean_path($$(HOMEDRIVE)$$(HOMEPATH))
}
}
# For backward compatibility
isEmpty(REMAKENDEPSFOLDER) {
REMAKENDEPSROOTFOLDER = $$clean_path($$(REMAKEN_PKG_ROOT))
isEmpty(REMAKENDEPSROOTFOLDER) {
exists($${USERHOMEFOLDER}/.remaken/.packagespath) {
REMAKENDEPSROOTFOLDER = $$clean_path($$cat($${USERHOMEFOLDER}/.remaken/.packagespath))
}
}
!isEmpty(REMAKENDEPSROOTFOLDER) {
REMAKENDEPSFOLDER = $$clean_path($${REMAKENDEPSROOTFOLDER})
}
else { #new remaken behavior
isEmpty(USERHOMEFOLDER) {
error("[ERROR] REMAKENDEPSROOTFOLDER dependencies folder is empty. Please check your system environment path (HOME for unix, USERPROFILE for windows)")
}
# Read REMAKENDEVPROP qmake property
REMAKENDEPSFOLDER = $$clean_path($$[REMAKENDEPSFOLDERPROP])
isEmpty(REMAKENDEPSFOLDER) { # REMAKENDEVPROP not defined in qmake's properties
message("NO REMAKENDEPSFOLDERPROP defined in qmake : setting REMAKENDEPSFOLDER to " $${REMAKENDEPSROOTFOLDER}/.remaken/packages)
REMAKENDEPSFOLDER = $${USERHOMEFOLDER}/.remaken/packages
}
}
message("REMAKENDEPSFOLDER Dependencies folder is set to " $${REMAKENDEPSFOLDER})
}
# Define target architecture path depending on the build kit used if not overloaded in user's project file
isEmpty(REMAKEN_TARGET_ARCH) {
# Defaults to x86_64
REMAKEN_TARGET_ARCH = x86_64
conanArch = "arch=x86_64"
win32:!android {
# Deduce for windows as it depends on the build kit used (each kit handles either 32 or 64 bits build, but not both)
vcpkgtriplet = x64-windows
contains(QMAKE_TARGET.arch, x86) {
REMAKEN_TARGET_ARCH = i386
conanArch = "arch=x86"
vcpkgtriplet = x86-windows
}
}
unix:!android {
# To build for i386, duplicate the 64 bits build kit and change the compilers used : Qmake specs are adapted for 32 bits build
contains(CONFIG, x86) {
REMAKEN_TARGET_ARCH = i386
conanArch = "arch=x86"
}
}
macx:!android {
# To build for i386, duplicate the 64 bits build kit and change the compilers used : Qmake specs are adapted for 32 bits build
vcpkgtriplet = x64-osx
contains(CONFIG, x86) {
REMAKEN_TARGET_ARCH = i386
conanArch = "arch=x86"
vcpkgtriplet = x86-osx
}
contains(CONFIG, arm64) {
REMAKEN_TARGET_ARCH = arm64
conanArch = "arch=armv8"
vcpkgtriplet = arm64-osx
}
}
linux:!android {
# To build for i386, duplicate the 64 bits build kit and change the compilers used : Qmake specs are adapted for 32 bits build
vcpkgtriplet = x64-linux
contains(CONFIG, x86) {
REMAKEN_TARGET_ARCH = i386
conanArch = "arch=x86"
vcpkgtriplet = x86-linux
}
}
android {
REMAKEN_TARGET_ARCH = $${ANDROID_TARGET_ARCH}
vcpkgtriplet = x64-android
contains(ANDROID_TARGET_ARCH, armeabi-v7a) {
conanArch = "arch=armv7"
vcpkgtriplet = arm-android
}
contains(ANDROID_TARGET_ARCH, arm64-v8a) {
conanArch = "arch=armv8"
vcpkgtriplet = arm64-android
}
contains(ANDROID_TARGET_ARCH, x86) {
conanArch = "arch=x86"
vcpkgtriplet = x86-android
}
}
}
win32:!android {
REMAKEN_OS = win
}
unix:!android {
REMAKEN_OS = unix
}
macx:!android {
REMAKEN_OS = mac
}
linux:!android {
REMAKEN_OS = linux
}
android {
REMAKEN_OS = android
}
ios {
REMAKEN_OS = ios
}
isEmpty(CONAN_MAJOR_VERSION) {
CONAN_VERSION_CMD_RESULT += $$system(conan --version)
CONAN_MAJOR_VERSION=1
!isEmpty(CONAN_VERSION_CMD_RESULT) {
CONAN_VERSION_INFO_LIST = $$split(CONAN_VERSION_CMD_RESULT, ' ')
CONAN_VERSION_INFO_LIST_SIZE = $$size(CONAN_VERSION_INFO_LIST)
equals(CONAN_VERSION_INFO_LIST_SIZE,3) {
CONAN_VERSION = $$member(CONAN_VERSION_INFO_LIST,2)
CONAN_VERSION_LIST = $$split(CONAN_VERSION, .)
CONAN_VERSION_LIST_SIZE = $$size(CONAN_VERSION_LIST)
equals(CONAN_VERSION_LIST_SIZE,3) {
CONAN_MAJOR_VERSION=$$member(CONAN_VERSION_LIST,0)
}
}
}
message("Conan version detected : $${CONAN_VERSION} - (major version = $${CONAN_MAJOR_VERSION})")
}
isEmpty(REMAKEN_TARGET_PLATFORM) {
REMAKEN_BUILD_TOOLCHAIN = $$basename(QMAKE_CC)
win32-msvc {
!defined(QMAKE_MSC_VER,var) {
!defined (MSVC_VER, var) {
error("Unable to find msvc version : Use minimum Qt 5.6 version.")
} else {
REMAKEN_COMPILER_VER = $$MSVC_VER
}
} else {
# msvc version : https://stackoverflow.com/questions/70013/how-to-detect-if-im-compiling-code-with-visual-studio-2008
greaterThan(QMAKE_MSC_VER, 1499) {
# Visual Studio 2008 (9.0) / Visual C++ 15.0 and up
REMAKEN_COMPILER_VER = 9.0
}
greaterThan(QMAKE_MSC_VER, 1599) {
# Visual Studio 2010 (10.0) / Visual C++ 16.0 and up
REMAKEN_COMPILER_VER = 10.0
}
greaterThan(QMAKE_MSC_VER, 1699) {
# Visual Studio 2012 (11.0) / Visual C++ 17.0 and up
REMAKEN_COMPILER_VER = 11.0
}
greaterThan(QMAKE_MSC_VER, 1799) {
# Visual Studio 2013 (12.0) / Visual C++ 18.0 and up
REMAKEN_COMPILER_VER = 12.0
}
greaterThan(QMAKE_MSC_VER, 1899) {
# Visual Studio 2015 (14.0) / Visual C++ 19.0 and up
REMAKEN_COMPILER_VER = 14.0
}
greaterThan(QMAKE_MSC_VER, 1909) {
# Visual Studio 2017 (14.x with x >= 1 and < 2 ) / Visual C++ 19.10 and up to 19.16
# Note : msvc version set to 14.1 for Visual Studio 2017 in order to separate version from msvc 2015!
REMAKEN_COMPILER_VER = 14.1
equals(CONAN_MAJOR_VERSION,1) {
CONAN_WIN_COMPILER_VERSION = 15 # visual studio version removed with conan 2.x
}
else {
CONAN_WIN_COMPILER_VERSION = 191 # msvc version
}
}
greaterThan(QMAKE_MSC_VER, 1920) {
# Visual Studio 2019 (14.x with x >= 2 and < 30) / Visual C++ 19.20 and up to 19.29
# Note : msvc version set to 14.1 - TODO change to 14.2??
REMAKEN_COMPILER_VER = 14.1
equals(CONAN_MAJOR_VERSION,1) {
CONAN_WIN_COMPILER_VERSION = 16
}
else {
CONAN_WIN_COMPILER_VERSION = 192
}
}
greaterThan(QMAKE_MSC_VER, 1930) {
# Visual Studio 2022 (14.x with x >= 30) / Visual C++ 19.30 and up
# Note : msvc version set to 14.3
REMAKEN_COMPILER_VER = 14.3
equals(CONAN_MAJOR_VERSION,1) {
CONAN_WIN_COMPILER_VERSION = 17
}
else {
CONAN_WIN_COMPILER_VERSION = 193
}
}
greaterThan(QMAKE_MSC_VER, 1939) {
# Visual Studio 2022 (14.x with x >= 40) / Visual C++ 19.40 and up
# Note : msvc version set to 14.3
REMAKEN_COMPILER_VER = 14.3
equals(CONAN_MAJOR_VERSION,1) {
CONAN_WIN_COMPILER_VERSION = 17
}
else {
CONAN_WIN_COMPILER_VERSION = 194
}
}
}
contains(CONFIG,c++14)|contains(CONFIG,c++1z)|contains(CONFIG,c++17)|contains(CONFIG,c++2a)|contains(CONFIG,c++20) {
contains(CONFIG,c++11) {
CONFIG -= c++11
}
}
# note : when icl is used with msvc, the most important is the msvc compiler version!
REMAKEN_BUILD_TOOLCHAIN=$$basename(QMAKE_CC)-$$REMAKEN_COMPILER_VER
}
REMAKEN_TARGET_PLATFORM = $${REMAKEN_OS}-$${REMAKEN_BUILD_TOOLCHAIN}
REMAKEN_FULL_PLATFORM = $${REMAKEN_TARGET_PLATFORM}-$${REMAKEN_TARGET_ARCH}
}
macx {
exists(/usr/local/opt/llvm):contains(CONFIG, use_brew_llvm) {
exists(/usr/local/opt/llvm/bin/clang):exists(/usr/local/opt/llvm/bin/clang++) {
QMAKE_CC=/usr/local/opt/llvm/bin/clang
QMAKE_CXX=/usr/local/opt/llvm/bin/clang++
QMAKE_CFLAGS += -I/usr/local/opt/llvm/include
QMAKE_CXXFLAGS += -I/usr/local/opt/llvm/include -I/usr/local/opt/llvm/include/c++/v1/
QMAKE_LINK=/usr/local/opt/llvm/bin/clang++
QMAKE_LFLAGS += -L/usr/local/opt/llvm/lib -Wl,-rpath,/usr/local/opt/llvm/lib
}
}
}