build.gradle

plugins {
    id "base"
    id "com.github.spotbugs" version "${githubSpotbugsVersion}"
    id "de.undercouch.download" version "${downloadVersion}"
    id 'net.researchgate.release' version "${researchgateReleaseVersion}"
}

description = 'Ballerinax - DataMapper Extension'

ext.puppycrawlCheckstyleVersion = project.puppycrawlCheckstyleVersion
ext.ballerinaLangVersion = project.ballerinaLangVersion
ext.dataMapperVersion = project.version

allprojects {
    repositories {
        mavenLocal()
        maven {
            url = 'https://maven.wso2.org/nexus/content/repositories/releases/'
        }

        maven {
            url = 'https://maven.wso2.org/nexus/content/groups/wso2-public/'
        }

        maven {
            url = 'https://repo.maven.apache.org/maven2'
        }

        maven {
            url = 'https://maven.pkg.github.com/ballerina-platform/*'
            credentials {
                username System.getenv("packageUser")
                password System.getenv("packagePAT")
            }
        }
    }
}

allprojects {
    apply plugin: 'java'
    apply plugin: 'maven-publish'

    configurations {
        ballerinaStdLibs
    }

    dependencies {
        /* Standard libraries */
        ballerinaStdLibs "io.ballerina.stdlib:io-ballerina:${stdlibIoVersion}"
        ballerinaStdLibs "io.ballerina.stdlib:observe-ballerina:${observeVersion}"
        ballerinaStdLibs "io.ballerina:observe-ballerina:${observeInternalVersion}"
    }

    publishing {
        repositories {
            maven {
                name = "GitHubPackages"
                url = uri("https://maven.pkg.github.com/ballerina-platform/module-ballerinax-datamapper")
                credentials {
                    username System.getenv("packageUser")
                    password System.getenv("packagePAT")
                }
            }
        }
    }

    release {
        // Disable check snapshots temporarily
        buildTasks = []
        failOnSnapshotDependencies = false
        failOnCommitNeeded = false
        versionPropertyFile = 'gradle.properties'
        tagTemplate = 'v${version}'
        git {
            // To release from any branch
            requireBranch = null
        }
    }
}

apply from: "gradle/javaProject.gradle"