build.gradle

import net.darkhax.curseforgegradle.TaskPublishCurseForge

plugins {
    id 'java-library'
    id 'eclipse'
    id 'idea'
    id 'maven-publish'
    id 'net.neoforged.gradle.userdev' version '7.0.165'
    id 'net.darkhax.curseforgegradle' version '1.1.24'
    id "com.modrinth.minotaur" version "2.+"

}

version = "${minecraft_version}-${mod_version}"
group = mod_group_id

repositories {
    mavenLocal()

    maven {
        name = "Curse Maven"
        url = uri("https://cursemaven.com")
        content {
            includeGroup("curse.maven")
        }
    }
}
base {
    archivesName = mod_id
}

java.toolchain.languageVersion = JavaLanguageVersion.of(21)

runs {
    configureEach {

        systemProperty 'forge.logging.markers', 'REGISTRIES'
        systemProperty 'forge.logging.console.level', 'debug'
        modSource project.sourceSets.main
    }

    client {
        systemProperty 'forge.enabledGameTestNamespaces', project.mod_id
    }

    server {
        systemProperty 'forge.enabledGameTestNamespaces', project.mod_id
        programArgument '--nogui'
    }
    gameTestServer {
        systemProperty 'forge.enabledGameTestNamespaces', project.mod_id
    }

    data {
        programArguments.addAll '--mod', project.mod_id, '--all', '--output', file('src/generated/resources/').getAbsolutePath(), '--existing', file('src/main/resources/').getAbsolutePath()
    }
}

sourceSets.main.resources { srcDir 'src/generated/resources' }

configurations {
    runtimeClasspath.extendsFrom localRuntime
}

dependencies {

    implementation "net.neoforged:neoforge:${neo_version}"

    //JEI

    compileOnly "curse.maven:jei-238222:5606861"
    runtimeOnly "curse.maven:jei-238222:5606861"


    //Caveopolis 5.0.20
    compileOnly "curse.maven:caveopolis-mod-639186:5982032"
    runtimeOnly "curse.maven:caveopolis-mod-639186:5982032"

    //Functional Storage
    compileOnly "curse.maven:functional-storage-556861:6023174"
    runtimeOnly "curse.maven:functional-storage-556861:6023174"

    //Caveopolis 5.0.20
    compileOnly "curse.maven:titanium-287342:5897690"
    runtimeOnly "curse.maven:titanium-287342:5897690"

    //BBL Core
    compileOnly "curse.maven:bbl-core-1135181:5973478"
    runtimeOnly "curse.maven:bbl-core-1135181:5973478"

    //Mekanism
    compileOnly "curse.maven:mekanism-268560:5574951"
    runtimeOnly "curse.maven:mekanism-268560:5574951"

    //Chipped
    compileOnly "curse.maven:chipped-456956:5681013"
    runtimeOnly "curse.maven:chipped-456956:5681013"

    //Chipped
    compileOnly "curse.maven:resourceful-lib-570073:5793500"
    runtimeOnly "curse.maven:resourceful-lib-570073:5793500"

    //Chipped
    compileOnly "curse.maven:athena-841890:5629395"
    runtimeOnly "curse.maven:athena-841890:5629395"

    //Ceramic Buckets
    compileOnly "curse.maven:ceramic-bucket-363799:5676627"
    runtimeOnly "curse.maven:ceramic-bucket-363799:5676627"

    //Bucket Lib
    compileOnly "curse.maven:bucketlib-560156:5800757"
    runtimeOnly "curse.maven:bucketlib-560156:5800757"


    //EMI

    //compileOnly "curse.maven:emi-580555:5619579"
    //runtimeOnly "curse.maven:emi-580555:5619579"

}

tasks.withType(ProcessResources).configureEach {
    var replaceProperties = [
            minecraft_version      : minecraft_version,
            minecraft_version_range: minecraft_version_range,
            neo_version            : neo_version,
            neo_version_range      : neo_version_range,
            loader_version_range   : loader_version_range,
            mod_id                 : mod_id,
            mod_name               : mod_name,
            mod_license            : mod_license,
            mod_version            : mod_version,
            mod_authors            : mod_authors,
            mod_description        : mod_description
    ]
    inputs.properties replaceProperties

    filesMatching(['META-INF/neoforge.mods.toml']) {
        expand replaceProperties
    }
}

publishing {
    publications {
        register('mavenJava', MavenPublication) {
            from components.java
        }
    }
    repositories {

        maven {
            url "https://cursemaven.com"
            content {
                includeGroup "curse.maven"
            }
        }

        maven {
            url "file://${project.projectDir}/repo"
        }
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8' // Use the UTF-8 charset for Java compilation
}

idea {
    module {
        downloadSources = true
        downloadJavadoc = true
    }
}

tasks.register('publishCurseForge', TaskPublishCurseForge) {
    group "modpublishing"

    apiToken = System.getenv("curseforge_token").toString()

    def projectId = 649644
    def mainFile = upload(projectId, jar)

    mainFile.changelog = changelog
    mainFile.addOptional("jei") // JEI
    mainFile.addRequirement("bbl-core")
    mainFile.releaseType = "release"
    mainFile.gameVersions.addAll("1.21", "1.21.1")
}

tasks.getByName("modrinth").setGroup("modpublishing")

modrinth {
    token = System.getenv("modrinth_token").toString()
    projectId = "rzq32Rx3"
    versionType = "release"
    versionName = "opolisutilities-" + "$minecraft_version" + "-" + "$mod_version"
    uploadFile = jar // With Loom, this MUST be set to `remapJar` instead of `jar`!

    gameVersions.addAll("1.21", "1.21.1")

    loaders = ["neoforge"]
    changelog = project.changelog
    dependencies {
        optional.project "jei"
        required.project "bbl-core"
    }
}