feat(modules): helix config and node env

modules/darwin/home-manager/users/bddvlpr.nix

@@ -1,5 +1,6 @@
 {outputs, ...}: {
   imports = with outputs.homeManagerModules; [
+    dev
     fish
     git
     gpg

modules/home/default.nix

@@ -1,4 +1,5 @@
 {
+  dev = import ./dev;
   firefox = import ./firefox;
   fish = import ./fish;
   git = import ./git;

modules/home/dev/default.nix

@@ -0,0 +1,3 @@
+{pkgs, ...}: {
+    home.packages = with pkgs; [nodejs] ++ (with nodePackages; [yarn pnpm]);
+}

modules/home/helix/default.nix

@@ -1,7 +1,34 @@
-{
+{pkgs, ...} @ args: {
   programs.helix = {
     enable = true;
 
+    languages = import ./languages.nix args;
+
     defaultEditor = true;
+    extraPackages = with pkgs;
+      [
+        buf-language-server
+        docker-compose-language-service
+        gleam
+        gopls
+        haskell-language-server
+        helm-ls
+        kotlin-language-server
+        lldb
+        marksman
+        netcoredbg
+        nil
+        omnisharp-roslyn
+        rust-analyzer
+        taplo
+        terraform-ls
+        texlab
+        yaml-language-server
+        zls
+      ]
+      ++ (with nodePackages; [
+        svelte-language-server
+        vscode-langservers-extracted
+      ]);
   };
 }

modules/home/helix/languages.nix

@@ -0,0 +1,58 @@
+{
+  lib,
+  pkgs,
+  ...
+}: let
+  inherit (lib) getExe;
+  inherit (pkgs) alejandra;
+  inherit (pkgs.nodePackages) prettier;
+
+  mkPrettier = {
+    name,
+    parser ? name,
+    plugin ? null,
+  }: {
+    inherit name;
+    auto-format = true;
+    formatter = {
+      command = getExe prettier;
+      args =
+        [
+          "--parser"
+          parser
+        ]
+        ++ (
+          if plugin != null
+          then ["--plugin" plugin]
+          else []
+        );
+    };
+  };
+in {
+  language = [
+    (mkPrettier {name = "html";})
+    (mkPrettier {name = "json";})
+    (mkPrettier {name = "css";})
+    (mkPrettier {name = "typescript";})
+    (mkPrettier {
+      name = "javascript";
+      parser = "typescript";
+    })
+    (mkPrettier {
+      name = "tsx";
+      parser = "typescript";
+    })
+    (mkPrettier {
+      name = "svelte";
+      parser = "typescript";
+      plugin = "prettier-plugin-svelte";
+    })
+    {
+      name = "nix";
+      auto-format = true;
+      formatter = {
+        command = getExe alejandra;
+      };
+    }
+  ];
+}