bintray.gradle

apply plugin: 'com.jfrog.bintray'

version = '0.9'

task sourcesJar(type: Jar) {
    from android.sourceSets.main.java.srcDirs
    classifier = 'sources'
}

task javadoc(type: Javadoc) {
    source = android.sourceSets.main.java.srcDirs
    classpath += project.files(android.getBootClasspath().join(File.pathSeparator))
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

afterEvaluate {
    javadoc.classpath += files(android.libraryVariants.collect { variant ->
        variant.javaCompile.classpath.files
    })
}

artifacts {
    archives javadocJar
    archives sourcesJar
}

// Bintray
Properties properties = new Properties()
properties.load(project.rootProject.file('local.properties').newDataInputStream())

bintray {
    user = properties.getProperty("bintray.user")
    key = properties.getProperty("bintray.apikey")

    configurations = ['archives']
    pkg {
        repo = 'Wroup'
        name = 'wroup'
        desc = 'Android WiFi P2P Library'
        websiteUrl = 'https://github.com/ble180/Wroup'
        vcsUrl = 'https://github.com/ble180/Wroup.git'
        licenses = ["MIT"]
        publish = true
        publicDownloadNumbers = true
    }
}