build.gradle

plugins {
	id "scala"
	id "nova.gradle" version "0.2.5"
}

allprojects {
	apply plugin: "scala"
	apply plugin: "nova.gradle"
	apply plugin: 'jacoco'

	dependencies {
		compile nova(novaVersion)
		compile "org.scala-lang:scala-library:2.11.7"
		compile "org.jgrapht:jgrapht-core:0.9.1"
		compile "org.jgrapht:jgrapht-ext:0.9.1"
		compile "nova.minecraft:NOVA-Minecraft:0.0.1-SNAPSHOT"
		compile "nova.scala:NOVA-Scala:0.0.1-SNAPSHOT"
		compile "nova.microblock:NOVA-Microblock:0.0.1-SNAPSHOT"

		testCompile "org.assertj:assertj-core:3.0.0"
		testCompile "junit:junit:4.12"
		testCompile group: "nova.core", name: "NOVA-Core", version: novaVersion
		testCompile group: "nova.core", name: "NOVA-Core", version: novaVersion, classifier: "wrappertests", changing: true
	}

	nova {
		wrappers {
			"17" {
				wrapper "nova.core:NOVA-Core-Wrapper-MC1.7:$novaVersion"
				runtime "nova.minecraft:NOVA-Minecraft-Wrapper-MC1.7:0.0.1-SNAPSHOT"
			}

			"18" {
				wrapper "nova.core:NOVA-Core-Wrapper-MC1.8:$novaVersion"
				runtime "nova.minecraft:NOVA-Minecraft-Wrapper-MC1.8:0.0.1-SNAPSHOT"
			}
		}
	}

	jacocoTestReport {
		reports {
			xml.enabled = true // coveralls plugin depends on xml format report
			html.enabled = true
		}
	}

	artifacts {
		archives jar
	}
}

subprojects {
	dependencies {
		compile project(":")
	}
}

project(":optics") {
	dependencies {
		compile project(":electric")
	}
}

//Add subprojects as runtime dependencies
subprojects.each {Project p ->
	rootProject.nova.wrappers*.runtime p
}