ALU.hdl

// This file is part of www.nand2tetris.org
// and the book "The Elements of Computing Systems"
// by Nisan and Schocken, MIT Press.
// File name: projects/02/ALU.hdl

/**
 * The ALU (Arithmetic Logic Unit).
 * Computes one of the following functions:
 * x+y, x-y, y-x, 0, 1, -1, x, y, -x, -y, !x, !y,
 * x+1, y+1, x-1, y-1, x&y, x|y on two 16-bit inputs, 
 * according to 6 input bits denoted zx,nx,zy,ny,f,no.
 * In addition, the ALU computes two 1-bit outputs:
 * if the ALU output == 0, zr is set to 1; otherwise zr is set to 0;
 * if the ALU output < 0, ng is set to 1; otherwise ng is set to 0.
 */

// Implementation: the ALU logic manipulates the x and y inputs
// and operates on the resulting values, as follows:
// if (zx == 1) set x = 0        // 16-bit constant
// if (nx == 1) set x = !x       // bitwise not
// if (zy == 1) set y = 0        // 16-bit constant
// if (ny == 1) set y = !y       // bitwise not
// if (f == 1)  set out = x + y  // integer 2's complement addition
// if (f == 0)  set out = x & y  // bitwise and
// if (no == 1) set out = !out   // bitwise not
// if (out == 0) set zr = 1
// if (out < 0) set ng = 1

CHIP ALU {
    IN  
        x[16], y[16],  // 16-bit inputs        
        zx, // zero the x input?
        nx, // negate the x input?
        zy, // zero the y input?
        ny, // negate the y input?
        f,  // compute out = x + y (if 1) or x & y (if 0)
        no; // negate the out output?

    OUT 
        out[16], // 16-bit output
        zr, // 1 if (out == 0), 0 otherwise
        ng; // 1 if (out < 0),  0 otherwise

    PARTS:
    // choose if pick x/y or set them to 0
    Mux16(a=y, b=false, sel=zy, out=zyout);
    Mux16(a=x, b=false, sel=zx, out=zxout);

    // handling of nx and ny
    Not16(in=zxout, out=notzxout);
    Mux16(a=zxout, b=notzxout, sel=nx, out=nxnotnxout);
    Not16(in=zyout, out=notzyout);
    Mux16(a=zyout, b=notzyout, sel=ny, out=nynotnyout);

    // compute f
    And16(a=nxnotnxout, b=nynotnyout, out=xandy);
    Add16(a=nxnotnxout, b=nynotnyout, out=xplusy);
    Mux16(a=xandy, b=xplusy, sel=f, out=outf);
    // negate out of f
    Not16(in=outf, out=notoutf);

    // choose final output between f or !f
    // get ng by assign MSB (out[15]) to it, if the MSB is 1 then
    // the number is negative, else the MSB will be 0
    // and divide the output in two halfs to with them get if
    // the number is 0 or not
    Mux16(a=outf, b=notoutf, sel=no, out[15]=ng, out[0..7]=half1, out[8..15]=half2, out=out);

    // if all numbers in half1[8] are 0, and all numbers in half2[8] also are 0
    // then Or of them will out 0, do not of it, so with that zr will be 1 when
    // the number is 0 
    Or8Way(in=half1, out=orhalf1);
    Or8Way(in=half2, out=orhalf2);
    Or(a=orhalf1, b=orhalf2, out=orh1h2);
    Not(in=orh1h2, out=zr);
}