Counter for Vectors

[gergoerdi]

How about something like this?

data Endian = BigEndian | LittleEndian

newtype Counters (endianness :: Endian) n a = Counters{ getCounters :: Vec n a }
    deriving (Generic, NFDataX, Eq, Show)

ripple :: ((Bool -> a -> (Bool, a)) -> Bool -> Vec n a -> (Bool, Vec n a)) -> (a -> (Bool, a)) -> Vec n a -> (Bool, Vec n a)
ripple mapAccum f = mapAccum step True
  where
    step carry x = if carry then f x else (False, x)

instance (Counter a, KnownNat n, 1 <= n) => Counter (Counters BigEndian n a) where
    countMin = Counters $ repeat countMin
    countMax = Counters $ repeat countMax

    countSuccOverflow = fmap Counters . ripple mapAccumR countSuccOverflow . getCounters
    countPredOverflow = fmap Counters . ripple mapAccumR countPredOverflow . getCounters

instance (Counter a, KnownNat n, 1 <= n) => Counter (Counters LittleEndian n a) where
    countMin = Counters $ repeat countMin
    countMax = Counters $ repeat countMax

    countSuccOverflow = fmap Counters . ripple mapAccumL countSuccOverflow . getCounters
    countPredOverflow = fmap Counters . ripple mapAccumL countPredOverflow . getCounters

Mostly I just want to be able to use a Counter BigEndian n (Index 10) as the world's least-effort BCD counter...

[martijnbastiaan]

Is there a reason we can't build Counter a => Counter (Vec n a)? Or do you want to introduce Counters as a means to introduce endianness?

[gergoerdi]

Just neither direction seemed more natural to me than the other, so I went with both.

[martijnbastiaan]

Yeah, I've had similar thoughts when writing instances for tuples. I see you made #2788 marking this issue as fixed; feel free to open an additional issue proposing to extend Counter with endianness if that's important to you.