Declaring tag to inject a value for a tool command?

[deepbrook]

Ahoi!

I want to load a yaml file given via -t fname=$file in a cue cmd. It essentialls reads that config and generates a few import strings for terraform and subsequently dumps them as JSON to stdout.

I've got this so far:

import (
    "tool/file",
    "tool/cli",
    "encoding/yaml",
    "encoding/json",
    "team-config/schema",
)

#args: {
    fname: string @tag(fname)
}

command: "member-imports": {
    raw: file.Read & { filename: #args.fname, contents: string }
    config: schema.#Config & yaml.Unmarshal(raw.contents)
    result: imports: [for i, member in config.members {to: "module.team.github_team_membership.this[\"\(member.user)\"]", id: "\(config.slug):\(member.user)" }]
    cli.Print & {text: json.Marshal(result)}
}

The problem is, I'm not able to inject fname:

🐟 ❯ cue cmd -t fname=swae-devops-test.yaml member-imports
no tag for "fname"

I've tried declaring it outside of a struct like so:

fname: string @tag(fname)

And inside of the command like this:

command: "member-imports": {
    fname: string @tag(fname)
    raw: file.Read & { filename: fname, contents: string }
    config: schema.#Config & yaml.Unmarshal(raw.contents)
    result: imports: [for i, member in config.members {to: "module.team.github_team_membership.this[\"\(member.user)\"]", id: "\(config.slug):\(member.user)" }]
    cli.Print & {text: json.Marshal(result)}
}

But the error stays the same. Quite confident this is something utterly simple, but I don't see it, afterall you appear to using injection without any issues in the repositories.

I've seen various issues dealing with this, and I believe i've tried all their suggested fixes?

#437
#2478

I've tried this on 0.6.0 and 0.7.0.

[verdverm]

The following works for me, ran: cue cmd -t fname=tony member-imports foo_tool.cue

import (
	"tool/file"
	"tool/cli"
	"encoding/yaml"
	"encoding/json"
	"team-config/schema"
)

#args: {
	fname: string @tag(fname)
}

command: "member-imports": {
	cli.Print & {text: #args.fname}
}

Can you get this working as well? (by putting it in an isolated environment / directory / module)

Best if we can reduce until it works and then add back to see what is the cause

[deepbrook]

No luck. I've moved it to an empty directory and dropped everything except the cli import. Won't print that tag :<

~/devel/qm w 🐍 v3.10.12 (swae-management) ☁️ GHE-Prod
🐟 ❯ cat import_tool.cue
import (
        "tool/cli"
)

#args: {
        fname: string @tag(fname)
}

command: "member-imports": {
        cli.Print & {text: #args.fname}
}⏎

~/devel/qm w 🐍 v3.10.12 (swae-management) ☁️ GHE-Prod
🐟 ❯ ls -l
-rw-r--r-- 1 deepbrook deepbrook  173 Dec 11 21:04 import_tool.cue

~/devel/qm w 🐍 v3.10.12 (swae-management) ☁️ GHE-Prod
🐟 ❯ cue cmd -t fname=swae-devops-test.yaml member-imports
no tag for "fname"

~/devel/qm w 🐍 v3.10.12 (swae-management) ☁️ GHE-Prod
[🔴 ERROR] 🐟 ❯ cue version
cue version v0.7.0

go version go1.21.5
      -buildmode exe
       -compiler gc
       -trimpath true
     CGO_ENABLED 0
          GOARCH amd64
            GOOS linux
         GOAMD64 v1

[deepbrook]

Oh dear me. Oh god. I figured it out.

For some reason I did not think to include the tool file in the invocation. Works just fine now. Oh god that's dumb.

So, the _tool.cue prefix is purely a convention? I thought cue magically reads only those files when running cue cmd and selects the relevant command to run from them (member-imports in my case).

Thanks for helping me out, appreciate it 😄

[eonpatapon]

That's because the file isn't part of a package. So you need to pass it explicitly.

Add package main for example at the top of the file. In this case cue will automatically evaluate all files that are in the same package. And you won't need to pass the list of files explicitly.

Note that all files in a directory should belong to the same package.