From 4b5d91f0ec9b79483fb30b01c99a67b47028fa95 Mon Sep 17 00:00:00 2001
From: Frank Steimke <fsteimke.hb@gmail.com>
Date: Tue, 5 Nov 2024 07:53:08 +0100
Subject: [PATCH] Support managing or performing copy instructions for media
 files

---
 src/guide/xml/ch03.xml                     |   6 +-
 src/guide/xml/ch04.xml                     |   8 +-
 src/guide/xml/ref-params.xml               |  38 ++++
 src/guide/xml/ref-templates.xml            |  46 +++++
 src/guide/xml/references.xml               |   6 +
 src/main/xslt/docbook.xsl                  |  24 +++
 src/main/xslt/main.xsl                     |   1 +
 src/main/xslt/modules/copyinstructions.xsl | 209 +++++++++++++++++++++
 src/main/xslt/modules/objects.xsl          |   6 +-
 9 files changed, 340 insertions(+), 4 deletions(-)
 create mode 100644 src/main/xslt/modules/copyinstructions.xsl

diff --git a/src/guide/xml/ch03.xml b/src/guide/xml/ch03.xml
index 7e2dc1d171..841a961684 100644
--- a/src/guide/xml/ch03.xml
+++ b/src/guide/xml/ch03.xml
@@ -516,11 +516,13 @@ subdirectory.
 the desired results for each combination of input and output arrangements.</para>
 
 <note>
-<para>Remember that in each case, the questions are: can the
+<para>Remember that in each case, the question is: can the
 stylesheets find the media files to query them and are the correct
 HTML references produced? Actually copying the media files from where
 they are in the source system to where they need to be in the HTML is
-“not our problem.”</para>
+“not our problem.”
+But the stylesheets can help to manage or even perform the task
+of copying on demand. See <parameter>copyinstructions-uri</parameter>.</para>
 </note>
 
 <variablelist>
diff --git a/src/guide/xml/ch04.xml b/src/guide/xml/ch04.xml
index 3487d95765..f990225ab4 100644
--- a/src/guide/xml/ch04.xml
+++ b/src/guide/xml/ch04.xml
@@ -406,7 +406,13 @@ will be to <uri>media/image.png</uri>.
 <para>The stylesheets are not responsible for actually copying the media files
 into the correct locations in the output. The stylesheets only generate the HTML
 files and the references. You must copy the images and other media with some
-other process.</para>
+other process,
+unless you expressly request further assistance. 
+If the parameter <parameter>copyinstructions-uri</parameter> is set accordingly,
+a file with copy instructions is created at the specified location.
+If the function <code>file:copy</code> from <citation>EXPATH File</citation> is available
+(which is the case when you are using Saxon PE or EE),
+the stylesheets will actually perform these instructions and copy the files.</para>
 </important>
 </section>
 </section>
diff --git a/src/guide/xml/ref-params.xml b/src/guide/xml/ref-params.xml
index 57031b4e50..9af67ac19d 100644
--- a/src/guide/xml/ref-params.xml
+++ b/src/guide/xml/ref-params.xml
@@ -904,6 +904,44 @@ this script will be added to the document. This script must contain the JavaScri
 necessary to support the theme controls.</para>
 </refsection>
 </refentry>
+  
+<refentry>
+  <refmeta>
+    <fieldsynopsis>
+      <type>xs:string?</type>
+      <varname>copyinstructions-uri</varname>
+    </fieldsynopsis>
+  </refmeta>
+  <refnamediv>
+    <refpurpose>URI for a file with copy instructions for image files</refpurpose>
+  </refnamediv>
+  <refsection>
+    <title>Description</title>
+    <para>This parameter is empty by default. If this parameter contains a valid file path, this
+      means that support for copying image files is requested (should be media files in general,
+      but only image files are implemented yet). The level of support depends on whether the
+        <code>file:copy</code> function from <citation>EXPATH File</citation> is available during
+      the transformation:</para>
+    <orderedlist numeration="loweralpha">
+      <listitem>
+        <para>When <code>file:copy</code> is available, the stylesheets will copy the files to the
+          place where the generated HTML files expects them. In this case, the file at
+            <code>copyinstructions-uri</code> is a logfile with one entry for each copy
+          operation.</para>
+      </listitem>
+      <listitem>
+        <para>When <code>file:copy</code> is not available, the file at
+              <code>copyinstructions-uri</code> contains instructions which  should be executed in
+            some way independently of the stylesheets. The template
+              <template>t:write-copyinstructions</template> is responsible for writing the file, it
+            determines the format of the "instructions". You may want to override it to generate a
+            batch file in UNIX® or Windows style.</para>
+      </listitem>
+    </orderedlist>
+      <para>When it is given as a relative path, it will be resolved against the current working
+        directory (see <function>ext:cwd</function>).</para>
+  </refsection>
+</refentry> 
 
 <refentry>
   <refmeta>
diff --git a/src/guide/xml/ref-templates.xml b/src/guide/xml/ref-templates.xml
index da040b117d..9665421e92 100644
--- a/src/guide/xml/ref-templates.xml
+++ b/src/guide/xml/ref-templates.xml
@@ -624,6 +624,52 @@ to process footnotes at the bottom of a table.</para>
 chunking is performed, this should provide links between pages.</para>
 </refsection>
 </refentry>
+  
+<refentry xml:id="t_write-copyinstructions">
+  <?db filenamme='t_write-copyinstructions'?>
+  <refmeta>
+    <refentrytitle>t:write-copyinstructions</refentrytitle>
+    <refmiscinfo>{http://docbook.org/ns/docbook/templates}write-copyinstructions</refmiscinfo>
+  </refmeta>
+  <refnamediv>
+    <refname>t:write-copyinstructions</refname>
+    <refpurpose>Writes copy instructions for media files</refpurpose>
+    <refclass>template</refclass>
+  </refnamediv>
+  <refsection>
+    <title>Description</title>
+    <para>This template is responsible for writing copy instructions for media files.
+    It is called when the parameter <parameter>copyinstructions-uri</parameter> is set.
+    The default implementation simply writes an XML filewith an <code>copy</code> element for each media file.
+    You may want to overwrite this template to produce a batch file for UNIX or Microsoft Windows environment.</para>
+    
+    <para>It is called with three parameters:</para>
+    <variablelist>
+      <varlistentry>
+        <term>instructions: map(xs:anyURI, xs:anyURI)</term>
+        <listitem>
+          <para>A  map with one entry for every copy destination of some media file. 
+            <emphasis>key </emphasis>is destination, <emphasis>value</emphasis> is source of media file.
+          This ensures that we have only on copy instruction, even if the media file is references many times in the document.</para>
+        </listitem>
+      </varlistentry>
+      <varlistentry>
+        <term>href: xs:anyURI</term>
+        <listitem>
+          <para>the absolute path for the file that is generated by this template.
+          Calculated from <parameter>copyinstructions-uri</parameter>.</para>
+        </listitem>
+      </varlistentry>
+      <varlistentry>
+        <term>mediaobject-basedirectory: xs:anyURI?</term>
+        <listitem>
+          <para>The base directory for every media file.
+          Not required, only for documentation.</para>
+        </listitem>
+      </varlistentry>
+    </variablelist>
+  </refsection>
+</refentry>
 
 <refentry xml:id="t_video-fallback">
 <?db filename="t_video-fallback"?>
diff --git a/src/guide/xml/references.xml b/src/guide/xml/references.xml
index 1456d77e43..b72e66188a 100644
--- a/src/guide/xml/references.xml
+++ b/src/guide/xml/references.xml
@@ -118,6 +118,12 @@ W3C Recommendation. 8 June 2017.</bibliomixed>
 xlink:href="https://www.w3.org/TR/xsl/">Extensible Stylesheet
 Language (XSL) Version 1.1</citetitle>. Anders Berglund, Editor.
 W3C Recommendation. 5 December 2006.</bibliomixed>
+              
+<bibliomixed>
+  <abbrev>EXPATH File</abbrev>
+  <citetitle xlink:href="http://expath.org/spec/file">File Module 1.0</citetitle>,
+  <pubdate>20 February 2015</pubdate>. Christian Grün, Editor.
+</bibliomixed>              
 
 </bibliography>
 
diff --git a/src/main/xslt/docbook.xsl b/src/main/xslt/docbook.xsl
index 82f9d7341e..13c50a9a20 100644
--- a/src/main/xslt/docbook.xsl
+++ b/src/main/xslt/docbook.xsl
@@ -5,6 +5,7 @@
                 xmlns:err='http://www.w3.org/2005/xqt-errors'
                 xmlns:ext="http://docbook.org/extensions/xslt"
                 xmlns:f="http://docbook.org/ns/docbook/functions"
+                xmlns:ghost="http://docbook.org/ns/docbook/ephemeral"
                 xmlns:fp="http://docbook.org/ns/docbook/functions/private"
                 xmlns:h="http://www.w3.org/1999/xhtml"
                 xmlns:m="http://docbook.org/ns/docbook/modes"
@@ -275,6 +276,24 @@
   <xsl:variable name="result" as="document-node()">
     <xsl:sequence select="fp:run-transforms($result, $post-processing)"/>
   </xsl:variable>
+  
+  <!-- Try to create or perform copy instructions for media files marked by @ghost:sourcefile -->
+  <xsl:if test="$copyinstructions-uri and exists($result//*[@ghost:sourcefile])">
+    <xsl:variable name="current-output-directory" as="xs:string?" select="
+        if (current-output-uri()) then
+          tokenize(current-output-uri(), '/')[position() lt last()] => string-join('/') => concat('/')
+        else
+          ()"/>
+    <xsl:call-template name="tp:mediaobjects-copyinstructions">
+      <xsl:with-param name="mediaobjects" select="$result//*[@ghost:sourcefile]"/>
+      <xsl:with-param name="current-output-directory" as="xs:string?" select="$current-output-directory"/>
+    </xsl:call-template>
+  </xsl:if>
+  
+  <!-- Get rid of @ghost attributes -->
+  <xsl:variable name="result" as="document-node()">
+    <xsl:apply-templates select="$result" mode="mp:final-cleanup"/>
+  </xsl:variable>
 
   <xsl:choose>
     <xsl:when test="$return = 'raw-results'">
@@ -448,5 +467,10 @@
     </xsl:otherwise>
   </xsl:choose>
 </xsl:function>
+  
+<!-- mp:final-cleanup removes attributes in the ghost namespace -->
+<xsl:mode name="mp:final-cleanup" on-no-match="shallow-copy"/>
+
+<xsl:template mode="mp:final-cleanup" match="@ghost:*"/>
 
 </xsl:stylesheet>
diff --git a/src/main/xslt/main.xsl b/src/main/xslt/main.xsl
index 2f30f8b5fd..ef725fe73f 100644
--- a/src/main/xslt/main.xsl
+++ b/src/main/xslt/main.xsl
@@ -59,6 +59,7 @@
 <xsl:include href="modules/attributes.xsl"/>
 <xsl:include href="modules/publishers.xsl"/>
 <xsl:include href="modules/annotations.xsl"/>
+<xsl:include href="modules/copyinstructions.xsl"/>  
 
 <xsl:import href="modules/chunk.xsl"/>
 <xsl:import href="modules/chunk-cleanup.xsl"/>
diff --git a/src/main/xslt/modules/copyinstructions.xsl b/src/main/xslt/modules/copyinstructions.xsl
new file mode 100644
index 0000000000..4683cf3d01
--- /dev/null
+++ b/src/main/xslt/modules/copyinstructions.xsl
@@ -0,0 +1,209 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<xsl:stylesheet xmlns:err="http://www.w3.org/2005/xqt-errors" xmlns:file="http://expath.org/ns/file"
+  xmlns:ext="http://docbook.org/extensions/xslt"
+  xmlns:ghost="http://docbook.org/ns/docbook/ephemeral" xmlns:h="http://www.w3.org/1999/xhtml"
+  xmlns:mp="http://docbook.org/ns/docbook/modes/private"
+  xmlns:t="http://docbook.org/ns/docbook/templates"
+  xmlns:tp="http://docbook.org/ns/docbook/templates/private"
+  xmlns:fp="http://docbook.org/ns/docbook/functions/private"
+  xmlns:v="http://docbook.org/ns/docbook/variables"
+  xmlns:vp="http://docbook.org/ns/docbook/variables/private"
+  xmlns:map="http://www.w3.org/2005/xpath-functions/map" xmlns:xs="http://www.w3.org/2001/XMLSchema"
+  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="#all" version="3.0">
+
+  <!-- Tries to find the absolute URI for the mediaobjects base directory, that is, the URI
+   |   where all the relative img/@src pathes have to be resolved against. -->
+  <xsl:function name="fp:mediaobject-basedirectory" as="xs:anyURI?">
+    <xsl:param name="current-output-directory" as="xs:string?"/>
+    <xsl:variable name="result" as="xs:string?">
+      <xsl:choose>
+        <xsl:when test="exists($v:mediaobject-output-base-uri)">
+          <!-- This value is calculated from the $mediaobject-output-base-uri parameter. 
+               If the parameter is the empty string, then this value is the empty sequence. 
+               Otherwise, this value is the value of the $mediaobject-output-base-uri parameter. 
+               The trailing slash is guaranteed.-->
+          <xsl:sequence select="
+              let $base := ($vp:chunk-output-base-uri, $current-output-directory)[1]
+              return
+                resolve-uri($v:mediaobject-output-base-uri, $base)"/>
+        </xsl:when>
+        <xsl:when test="$v:chunk">
+          <!-- When chunk is requested, vp:chunk-output-base-uri is what we are looking for.
+               A trailing slah is added if neccessary.-->
+          <xsl:sequence select="
+              if (ends-with($vp:chunk-output-base-uri, '/')) then
+                $vp:chunk-output-base-uri
+              else
+                concat($vp:chunk-output-base-uri, '/')"/>
+        </xsl:when>
+        <xsl:when test="$current-output-directory">
+          <!-- Chunk is not requested, and the base uri for mediaobjects is not explicitly set.
+               This might be the simple default case of translating the input into a single HTML file,
+               especially when PDF is intended. 
+               $current-output-directory is computed in docbook.xsl from fn:current-output-uri() if possible.
+               The trailing slash is guaranteed. -->
+          <xsl:sequence select="$current-output-directory"/>
+        </xsl:when>
+      </xsl:choose>
+    </xsl:variable>
+    <xsl:choose>
+      <xsl:when test="$result gt '' and $result castable as xs:anyURI">
+        <xsl:message select="'Base-URI for media files is ' || $result"
+          use-when="$v:debug = 'mediaobject-uris'"/>
+        <xsl:sequence select="xs:anyURI($result)"/>
+      </xsl:when>
+      <xsl:otherwise>
+        <xsl:message
+          select="'Warning: Can''t calculate mediaobjects basedirectory (current output directory is ' || $current-output-directory || ').'"
+        />
+      </xsl:otherwise>
+    </xsl:choose>
+  </xsl:function>
+
+  <!-- returns a map with instructions to copy $mediaobjects
+   |   from their source to to place where the generated file expects them
+   |   taken into account the mediaobject-basedirectory.
+   |   Each entry in the map has copy destination as key and copy source as value.
+   |   This guarantees only on copy for each mediaobject,
+   |   even if it is referenced many times in the generated HTML-->
+  <xsl:function name="fp:instructions" as="map(xs:anyURI, xs:anyURI)">
+    <xsl:param name="mediaobjects" as="element()*"/>
+    <xsl:param name="mediaobject-basedirectory" as="xs:anyURI?"/>
+    <xsl:if test="$mediaobject-basedirectory and $mediaobjects">
+      <xsl:variable name="entries" as="map(xs:anyURI, xs:anyURI)*">
+        <xsl:apply-templates select="$mediaobjects" mode="mp:mediaobject-copy-instruction">
+          <xsl:with-param name="mediaobject-basedirectory" select="$mediaobject-basedirectory"/>
+        </xsl:apply-templates>
+      </xsl:variable>
+      <xsl:sequence select="map:merge($entries)"/>
+    </xsl:if>
+  </xsl:function>
+
+  <!-- Calculates the URI where copyinstructions will be written 
+   |   as absolute path from the stylesheet parameter $copyinstructions-uri. 
+   |   If $copyinstructions-uri is absolute, it will be returned unchanged.
+   |   If it is relative, it will be resolved against ext:cwd() if available, 
+   |   $mediaobject-basedirectory otherwise-->
+  <xsl:function name="fp:copyinstructions-uri" as="xs:anyURI">
+    <xsl:param name="mediaobject-basedirectory" as="xs:anyURI"/>
+    <xsl:variable name="base" as="xs:anyURI">
+      <xsl:sequence select="ext:cwd()" use-when="function-available('ext:cwd')"/>
+      <xsl:sequence select="$mediaobject-basedirectory"
+        use-when="not(function-available('ext:cwd'))"/>
+    </xsl:variable>
+    <xsl:sequence select="resolve-uri($copyinstructions-uri, $base)"/>
+  </xsl:function>
+
+  <!-- Manages or supports managing of mediaobjects
+   |   - if file:copy is available, perform copy of mediaobjects and write a log file
+   |   - otherwise create a file with copy instructions giving source and destination
+   ============================================================================== -->
+  <xsl:template name="tp:mediaobjects-copyinstructions">
+    <xsl:param name="mediaobjects" as="element()*"/>
+    <xsl:param name="current-output-directory" as="xs:string?"/>
+    <xsl:variable name="mediaobject-basedirectory" as="xs:anyURI?"
+      select="fp:mediaobject-basedirectory($current-output-directory)"/>
+    <xsl:variable name="instructions" as="map(*)"
+      select="fp:instructions($mediaobjects, $mediaobject-basedirectory)"/>
+    <xsl:if test="exists(map:keys($instructions))">
+      <!-- now we can be sure that $mediaobject-basedirectory exists
+       |   because it's a prerequisite for $instructions  -->
+      <xsl:call-template name="tp:process-copyinstructions"
+        use-when="function-available('file:copy')">
+        <xsl:with-param name="instructions" as="map(*)" select="$instructions"/>
+        <xsl:with-param name="href" select="fp:copyinstructions-uri($mediaobject-basedirectory)"/>
+        <xsl:with-param name="mediaobject-basedirectory" select="$mediaobject-basedirectory"/>
+      </xsl:call-template>
+      <xsl:call-template name="t:write-copyinstructions"
+        use-when="not(function-available('file:copy'))">
+        <xsl:with-param name="instructions" as="map(*)" select="$instructions"/>
+        <xsl:with-param name="href" select="fp:copyinstructions-uri($mediaobject-basedirectory)"/>
+        <xsl:with-param name="mediaobject-basedirectory" select="$mediaobject-basedirectory"/>
+      </xsl:call-template>
+    </xsl:if>
+  </xsl:template>
+
+  <xsl:template name="tp:process-copyinstructions" use-when="function-available('file:copy')">
+    <xsl:param name="instructions" as="map(*)"/>
+    <xsl:param name="href" as="xs:anyURI"/>
+    <xsl:param name="mediaobject-basedirectory" as="xs:anyURI?" required="no"/>
+    <xsl:variable name="timestamp" as="xs:string"
+      select="current-dateTime() => format-dateTime('[Y0001]-[M01]-[D01]T[H01]:[m01]:[s02]')"/>
+    <xsl:try>
+      <xsl:result-document href="{$href}" indent="yes" method="xml" omit-xml-declaration="no">
+        <mediaobject-copyinstructions timestamp="{$timestamp}" basedirectory="{$mediaobject-basedirectory}" xmlns="''">
+          <xsl:for-each select="map:keys($instructions)">
+            <xsl:try>
+              <xsl:sequence select="file:copy($instructions(.), .)"/>
+              <copied source="{$instructions(.)}" destination="{.}"/>
+              <xsl:catch>
+                <error source="{$instructions(.)}" destination="{.}">
+                  <xsl:value-of select="$err:description"/>
+                </error>
+              </xsl:catch>
+            </xsl:try>
+          </xsl:for-each>
+        </mediaobject-copyinstructions>
+      </xsl:result-document>
+      <xsl:message select="'Wrote log of mediaobject copy processing to ' || $href"
+        use-when="$v:debug = 'mediaobject-uris'"/>
+      <xsl:catch>
+        <xsl:message
+          select="'Warning: unable to write mediaobject copy instructions to file ' || $href || ': ' || $err:description"
+        />
+      </xsl:catch>
+    </xsl:try>
+  </xsl:template>
+
+  <xsl:template name="t:write-copyinstructions">
+    <xsl:param name="instructions" as="map(*)"/>
+    <xsl:param name="href" as="xs:anyURI"/>
+    <xsl:param name="mediaobject-basedirectory" as="xs:anyURI?" required="no"/>
+    <xsl:variable name="timestamp" as="xs:string"
+      select="current-dateTime() => format-dateTime('[Y0001]-[M01]-[D01]T[H01]:[m01]:[s01]')"/>
+    <xsl:try>
+      <xsl:result-document href="{$href}" indent="yes" method="xml" omit-xml-declaration="no">
+        <mediaobject-copyinstructions timestamp="{$timestamp}" basedirectory="{$mediaobject-basedirectory}" xmlns="">
+          <xsl:for-each select="map:keys($instructions)">
+            <copy source="{$instructions(.)}" destination="{.}"/>
+          </xsl:for-each>
+        </mediaobject-copyinstructions>
+      </xsl:result-document>
+      <xsl:message select="'Wrote mediaobject copy instructions to ' || $href"
+        use-when="$v:debug = 'mediaobject-uris'"/>
+      <xsl:catch>
+        <xsl:message
+          select="'Warning: unable to write mediaobject copy instructions to file ' || $href || ': ' || $err:description"
+        />
+      </xsl:catch>
+    </xsl:try>
+  </xsl:template>
+
+  <!-- mp:mediaobject-copy-instruction ==========================================================================
+   |   calculates for some HTML Elements an map entry which can support copy instructions
+   |   each entry is a map with copy destination as key and copy source as value
+   |==========================================================================================================-->
+  <xsl:mode name="mp:mediaobject-copy-instruction"/>
+
+  <xsl:template match="h:img[@ghost:sourcefile]" mode="mp:mediaobject-copy-instruction"
+    as="map(xs:anyURI, xs:anyURI)?">
+    <xsl:param name="mediaobject-basedirectory" as="xs:anyURI"/>
+    <xsl:try>
+      <xsl:variable name="destination" as="xs:anyURI"
+        select="resolve-uri(@src, $mediaobject-basedirectory)"/>
+      <xsl:sequence select="map:entry($destination, xs:anyURI(@ghost:sourcefile))"/>
+      <xsl:catch>
+        <xsl:message
+          select="'Warning: can''t create mediaobject copy instruction for ' || @src || ': ' || $err:description"
+        />
+      </xsl:catch>
+    </xsl:try>
+  </xsl:template>
+
+  <xsl:template match="node()" mode="mp:mediaobject-copy-instruction" priority="-10">
+    <xsl:message
+      select="'Warning: mediaobject copyinstruction not yet implemented for ' || local-name() || '.'"
+    />
+  </xsl:template>
+
+</xsl:stylesheet>
diff --git a/src/main/xslt/modules/objects.xsl b/src/main/xslt/modules/objects.xsl
index 70c8b10094..07640a644d 100644
--- a/src/main/xslt/modules/objects.xsl
+++ b/src/main/xslt/modules/objects.xsl
@@ -5,6 +5,7 @@
                 xmlns:ext="http://docbook.org/extensions/xslt"
                 xmlns:f="http://docbook.org/ns/docbook/functions"
                 xmlns:fp="http://docbook.org/ns/docbook/functions/private"
+                xmlns:ghost="http://docbook.org/ns/docbook/ephemeral"
                 xmlns:h="http://www.w3.org/1999/xhtml"
                 xmlns:m="http://docbook.org/ns/docbook/modes"
                 xmlns:map="http://www.w3.org/2005/xpath-functions/map"
@@ -756,7 +757,9 @@
       </div>
     </xsl:when>
     <xsl:otherwise>
+      <!-- $info?uri is The computed absolute URI of the input data -->
       <xsl:call-template name="t:mediaobject-img">
+        <xsl:with-param name="sourcefile" select="$info?uri"/> 
         <xsl:with-param name="filename" select="$info?href"/>
         <xsl:with-param name="styles" select="$styles"/>
         <xsl:with-param name="viewport" select="$viewport"/>
@@ -767,12 +770,13 @@
 </xsl:template>
 
 <xsl:template name="t:mediaobject-img">
+  <xsl:param name="sourcefile" as="xs:string"/>
   <xsl:param name="filename" as="xs:string"/>
   <xsl:param name="styles" as="xs:string*"/>
   <xsl:param name="viewport" as="map(*)?"/>
   <xsl:param name="imageproperties" as="map(*)?"/>
 
-  <img src="{$filename}">
+  <img src="{$filename}" ghost:sourcefile="{$sourcefile}">
     <xsl:apply-templates select="." mode="m:attributes"/>
     
     <!-- Apply any alt text in the media object to the image tag. -->