build.gradle

import org.gradle.api.publish.maven.internal.publication.MavenPomInternal;
import org.gradle.api.publish.maven.internal.publisher.MavenProjectIdentity;
import static org.gradle.api.publish.plugins.PublishingPlugin.PUBLISH_TASK_GROUP;

plugins {
    // This adds tasks to auto close or release nexus staging repos
    // see https://github.com/gradle-nexus/publish-plugin/
    id "io.github.gradle-nexus.publish-plugin"
}


allprojects {
    group 'org.quartz-scheduler'
    version quartzVersion
}

subprojects {
    repositories {
        mavenCentral()
    }
}

allprojects {
    plugins.withType(JavaBasePlugin) {
        java {
            toolchain {
                languageVersion = JavaLanguageVersion.of(11)
            }
        }
    }

    plugins.withType(MavenPublishPlugin) {

        publishing {
            configurations {
                provided
                runtimeClasspath.extendsFrom(provided)
            }
            publications {
                maven(MavenPublication) {
                    pom {
                        name = "$project.name"
                        url = 'https://www.quartz-scheduler.org/'
                        licenses {
                            license {
                                name = 'The Apache License, Version 2.0'
                                url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                            }
                        }
                        scm {
                            connection = 'scm:git:git://github.com:electric-cloud/quartz.git'
                            developerConnection = 'scm:git:ssh:git@github.com:electric-cloud/quartz.git'
                            url = 'https://github.com/electric-cloud/quartz'
                        }
                        developers {
                            developer {
                                name = "Terracotta Engineers"
                                email = "tc-oss@softwareag.com"
                                organization = "Terracotta Inc., a wholly-owned subsidiary of Software AG USA, Inc."
                                organizationUrl = "http://www.quartz-scheduler.org/"
                            }
                        }
                    }

                    from components.java
                    pom.withXml {
                        asNode()
                                .dependencies
                                .dependency
                                .findAll { dependency ->
                                    // Patch up dependency scopes per expectations of maven users
                                    (dependency.groupId.text() == 'com.mchange' ||
                                            dependency.groupId.text() == 'com.zaxxer' ||
                                            dependency.artifactId.text() == 'slf4j-log4j12' ||
                                            dependency.groupId.text() == 'jakarta.xml' )
                                }
                                .each { dependency ->
                                    // Set scope value to compile.
                                    dependency.scope*.value = 'provided'
                                }
                    }
                }
            }
        }

        // for MANIFEST.MF
        jar {
            manifest {
                attributes(
                        "Implementation-Title": project.name,
                        "Implementation-Vendor-Id": project.group,
                        "Implementation-Version": project.version,
                        "Built-By": System.getProperty("user.name"),
                        "Built-JDK": System.getProperty("java.version")
                )
            }
        }

    }

    // Put pom.xml and pom.properties in the jar:
    project.afterEvaluate{p ->
        // module.json publishing confuses sonatype and it doesn't process the jar.
        tasks.withType(GenerateModuleMetadata) {
            enabled = false
        }
        tasks.withType(GenerateMavenPom) {pomTask ->
            MavenProjectIdentity identity = ((MavenPomInternal) pomTask.getPom()).getProjectIdentity();
            TaskProvider<WriteProperties> pomPropertiesTask = project.getTasks().register(pomTask.getName().replace("PomFile", "PomProperties"), WriteProperties.class, task -> {
                task.dependsOn(pomTask);
                task.setGroup(PUBLISH_TASK_GROUP);
                task.setOutputFile(new File(pomTask.getDestination().getParentFile(), "pom.properties"));
                task.property("groupId", identity.getGroupId());
                task.property("artifactId", identity.getArtifactId());
                task.property("version", identity.getVersion());
            });

            project.tasks.withType(Jar).configureEach{jar ->
                jar.into("META-INF/maven/" + identity.getGroupId().get() + "/" + identity.getArtifactId().get(), spec -> {
                    spec.from(pomTask, pom -> pom.rename(".*", "pom.xml"));
                    spec.from(pomPropertiesTask);
                });
            }
        }
    }

}

nexusPublishing {
    repositories {
        sonatype {
            // To get the values for username and password, please refer to the following link:
            // https://nexus-internal.cloudbees.com/#profile (Select the "User Token" tab and button "Access Token"
            username = 'OVERRIDE_ME'
            password = 'OVERRIDE_ME'
            stagingProfileId = '7a7e874f6c38' // Staging profile ID
            nexusUrl = uri('https://nexus-internal.cloudbees.com/service/local/') // CloudBees Internal Nexus URI
        }
    }
}