forked from beyondgrep/ack2
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathAck.pm
1119 lines (844 loc) · 28.6 KB
/
Ack.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
package App::Ack;
use warnings;
use strict;
use App::Ack::ConfigDefault;
use App::Ack::ConfigFinder;
use Getopt::Long 2.36 ();
use File::Next 1.10;
=head1 NAME
App::Ack - A container for functions for the ack program
=head1 VERSION
Version 2.00a01
=cut
our $VERSION;
our $GIT_REVISION;
our $COPYRIGHT;
BEGIN {
$VERSION = '2.00a01';
$COPYRIGHT = 'Copyright 2005-2012 Andy Lester.';
$GIT_REVISION = '';
}
our $fh;
BEGIN {
$fh = *STDOUT;
}
our %types;
our %type_wanted;
our %mappings;
our %ignore_dirs;
our $is_filter_mode;
our $output_to_pipe;
our $dir_sep_chars;
our $is_cygwin;
our $is_windows;
use File::Spec 1.00015 ();
use File::Glob 1.00015 ':glob';
BEGIN {
# These have to be checked before any filehandle diddling.
$output_to_pipe = not -t *STDOUT;
$is_filter_mode = -p STDIN;
$is_cygwin = ($^O eq 'cygwin');
$is_windows = ($^O =~ /MSWin32/);
$dir_sep_chars = $is_windows ? quotemeta( '\\/' ) : quotemeta( File::Spec->catfile( '', '' ) );
}
=head1 SYNOPSIS
If you want to know about the F<ack> program, see the F<ack> file itself.
No user-serviceable parts inside. F<ack> is all that should use this.
=head1 FUNCTIONS
=head2 read_ackrc
Reads the contents of the .ackrc file and returns the arguments.
=cut
sub retrieve_arg_sources {
my @arg_sources;
my $noenv;
my $ackrc;
Getopt::Long::Configure('default', 'no_auto_help', 'no_auto_version');
Getopt::Long::Configure('pass_through');
Getopt::Long::Configure('no_auto_abbrev');
Getopt::Long::GetOptions(
'noenv' => \$noenv,
'ackrc=s' => \$ackrc,
);
Getopt::Long::Configure('default', 'no_auto_help', 'no_auto_version');
my @files;
if ( !$noenv ) {
my $finder = App::Ack::ConfigFinder->new;
@files = $finder->find_config_files;
}
if ( $ackrc ) {
# we explicitly use open so we get a nice error message
# XXX this is a potential race condition!
if(open my $fh, '<', $ackrc) {
close $fh;
} else {
die "Unable to load ackrc '$ackrc': $!"
}
push( @files, $ackrc );
}
push @arg_sources, Defaults => [ App::Ack::ConfigDefault::options() ];
foreach my $file ( @files) {
my @lines = read_rcfile($file);
push ( @arg_sources, $file, \@lines ) if @lines;
}
if ( $ENV{ACK_OPTIONS} && !$noenv ) {
push( @arg_sources, 'ACK_OPTIONS' => $ENV{ACK_OPTIONS} );
}
push( @arg_sources, 'ARGV' => [ @ARGV ] );
return @arg_sources;
}
sub read_rcfile {
my $file = shift;
return unless defined $file && -e $file;
my @lines;
open( my $fh, '<', $file ) or App::Ack::die( "Unable to read $file: $!" );
while ( my $line = <$fh> ) {
chomp $line;
$line =~ s/^\s+//;
$line =~ s/\s+$//;
next if $line eq '';
next if $line =~ /^#/;
push( @lines, $line );
}
close $fh;
return @lines;
}
=head2 create_ignore_rules( $what, $where, \@opts )
Takes an array of options passed in on the command line and returns
a hashref of information about them:
*
# is: Match the filename exactly
# ext: Match the extension
# regex: Match against a Perl regular expression
=cut
sub create_ignore_rules {
my $what = shift;
my $where = shift;
my $opts = shift;
my @opts = @{$opts};
my %rules;
for my $opt ( @opts ) {
if ( $opt =~ /^(is|ext|regex),(.+)$/ ) {
my $method = $1;
my $arg = $2;
if ( $method eq 'regex' ) {
push( @{$rules{regex}}, qr/$arg/ );
}
else {
++$rules{$method}{$arg};
}
}
else {
App::Ack::die( "Invalid argument for --$what: $opt" );
}
}
return \%rules;
}
=head2 remove_dir_sep( $path )
This functions removes a trailing path separator, if there is one, from its argument
=cut
sub remove_dir_sep {
my $path = shift;
$path =~ s/[$dir_sep_chars]$//;
return $path;
}
=head2 build_regex( $str, \%opts )
Returns a regex object based on a string and command-line options.
Dies when the regex $str is undefinied (i.e. not given on command line).
=cut
sub build_regex {
my $str = shift;
my $opt = shift;
defined $str or App::Ack::die( 'No regular expression found.' );
$str = quotemeta( $str ) if $opt->{Q};
if ( $opt->{w} ) {
$str = "\\b$str" if $str =~ /^\w/;
$str = "$str\\b" if $str =~ /\w$/;
}
my $regex_is_lc = $str eq lc $str;
if ( $opt->{i} || ($opt->{smart_case} && $regex_is_lc) ) {
$str = "(?i)$str";
}
my $ok = eval {
qr/$str/
};
my $error = $@;
if ( !$ok ) {
die "Invalid regex '$str':\n $error";
}
return $str;
}
=head2 check_regex( $regex_str )
Checks that the $regex_str can be compiled into a perl regular expression.
Dies with the error message if this is not the case.
No return value.
=cut
sub check_regex {
my $regex = shift;
return unless defined $regex;
eval { qr/$regex/ };
if ($@) {
(my $error = $@) =~ s/ at \S+ line \d+.*//;
chomp($error);
App::Ack::die( "Invalid regex '$regex':\n $error" );
}
return;
}
=head2 warn( @_ )
Put out an ack-specific warning.
=cut
sub warn {
return CORE::warn( _my_program(), ': ', @_, "\n" );
}
=head2 die( @_ )
Die in an ack-specific way.
=cut
sub die {
return CORE::die( _my_program(), ': ', @_, "\n" );
}
sub _my_program {
require File::Basename;
return File::Basename::basename( $0 );
}
=head2 filetypes_supported()
Returns a list of all the types that we can detect.
=cut
sub filetypes_supported {
return keys %mappings;
}
sub _get_thpppt {
my $y = q{_ /|,\\'!.x',=(www)=, U };
$y =~ tr/,x!w/\nOo_/;
return $y;
}
sub _thpppt {
my $y = _get_thpppt();
App::Ack::print( "$y ack $_[0]!\n" );
exit 0;
}
sub _bar {
my $x;
$x = <<'_BAR';
6?!I'7!I"?%+!
3~!I#7#I"7#I!?!+!="+"="+!:!
2?#I!7!I!?#I!7!I"+"=%+"=#
1?"+!?*+!=#~"=!+#?"="+!
0?"+!?"I"?&+!="~!=!~"=!+%="+"
/I!+!?)+!?!+!=$~!=!~!="+!="+"?!="?!
.?%I"?%+%='?!=#~$="
,,!?%I"?(+$=$~!=#:"~$:!~!
,I!?!I!?"I"?!+#?"+!?!+#="~$:!~!:!~!:!,!:!,":#~!
+I!?&+!="+!?#+$=!~":!~!:!~!:!,!:#,!:!,%:"
*+!I!?!+$=!+!=!+!?$+#=!~":!~":#,$:",#:!,!:!
*I!?"+!?!+!=$+!?#+#=#~":$,!:",!:!,&:"
)I!?$=!~!=#+"?!+!=!+!=!~!="~!:!~":!,'.!,%:!~!
(=!?"+!?!=!~$?"+!?!+!=#~"=",!="~$,$.",#.!:!=!
(I"+"="~"=!+&=!~"=!~!,!~!+!=!?!+!?!=!I!?!+"=!.",!.!,":!
%I$?!+!?!=%+!~!+#~!=!~#:#=!~!+!~!=#:!,%.!,!.!:"
$I!?!=!?!I!+!?"+!=!~!=!~!?!I!?!=!+!=!~#:",!~"=!~!:"~!=!:",&:" '-/
$?!+!I!?"+"=!+"~!,!:"+#~#:#,"=!~"=!,!~!,!.",!:".!:! */! !I!t!'!s! !a! !g!r!e!p!!! !/!
$+"=!+!?!+"~!=!:!~!:"I!+!,!~!=!:!~!,!:!,$:!~".&:"~!,# (-/
%~!=!~!=!:!.!+"~!:!,!.!,!~!=!:$.!,":!,!.!:!~!,!:!=!.#="~!,!:" ./!
%=!~!?!+"?"+!=!~",!.!:!?!~!.!:!,!:!,#.!,!:","~!:!=!~!=!:",!~! ./!
%+"~":!~!=#~!:!~!,!.!~!:",!~!=!~!.!:!,!.",!:!,":!=":!.!,!:!7! -/!
%~",!:".#:!=!:!,!:"+!:!~!:!.!,!~!,!.#,!.!,$:"~!,":"~!=! */!
&=!~!=#+!=!~",!.!:",#:#,!.",+:!,!.",!=!+!?!
&~!=!~!=!~!:"~#:",!.!,#~!:!.!+!,!.",$.",$.#,!+!I!?!
&~!="~!:!~":!~",!~!=!~":!,!:!~!,!:!,&.$,#."+!?!I!?!I!
&~!=!~!=!+!,!:!~!:!=!,!:!~&:$,!.!,".!,".!,#."~!+!?$I!
&~!=!~!="~!=!:!~":!,!~%:#,!:",!.!,#.",#I!7"I!?!+!?"I"
&+!I!7!:#~"=!~!:!,!:"~$.!=!.!,!~!,$.#,!~!7!I#?!+!?"I"7!
%7#?!+!~!:!=!~!=!~":!,!:"~":#.!,)7#I"?"I!7&
%7#I!=":!=!~!:"~$:"~!:#,!:!,!:!~!:#,!7#I!?#7)
$7$+!,!~!=#~!:!~!:!~$:#,!.!~!:!=!,":!7#I"?#7+=!?!
$7#I!~!,!~#=!~!:"~!:!,!:!,#:!=!~",":!7$I!?#I!7*+!=!+"
"I!7$I!,":!,!.!=":$,!:!,$:$7$I!+!?"I!7+?"I!7!I!7!,!
!,!7%I!:",!."~":!,&.!,!:!~!I!7$I!+!?"I!7,?!I!7',!
!7(,!.#~":!,%.!,!7%I!7!?#I"7,+!?!7*
7+:!,!~#,"=!7'I!?#I"7/+!7+
77I!+!7!?!7!I"71+!7,
_BAR
$x =~ s/(.)(.)/$1x(ord($2)-32)/eg;
App::Ack::print( $x );
exit 0;
}
=head2 show_help()
Dumps the help page to the user.
=cut
sub show_help {
my $help_arg = shift || 0;
# return show_help_types() if $help_arg =~ /^types?/;
App::Ack::print( <<"END_OF_HELP" );
Usage: ack [OPTION]... PATTERN [FILES OR DIRECTORIES]
Search for PATTERN in each source file in the tree from the current
directory on down. If any files or directories are specified, then
only those files and directories are checked. ack may also search
STDIN, but only if no file or directory arguments are specified,
or if one of them is "-".
Default switches may be specified in ACK_OPTIONS environment variable or
an .ackrc file. If you want no dependency on the environment, turn it
off with --noenv.
Example: ack -i select
Searching:
-i, --ignore-case Ignore case distinctions in PATTERN
--[no]smart-case Ignore case distinctions in PATTERN,
only if PATTERN contains no upper case.
Ignored if -i is specified
-v, --invert-match Invert match: select non-matching lines
-w, --word-regexp Force PATTERN to match only whole words
-Q, --literal Quote all metacharacters; PATTERN is literal
Search output:
--line=NUM Only print line(s) NUM of each file
-l, --files-with-matches
Only print filenames containing matches
-L, --files-without-matches
Only print filenames with no matches
--output=expr Output the evaluation of expr for each line
(turns off text highlighting)
-o Show only the part of a line matching PATTERN
Same as --output='\$&'
--passthru Print all lines, whether matching or not
--match PATTERN Specify PATTERN explicitly.
-m, --max-count=NUM Stop searching in each file after NUM matches
-1 Stop searching after one match of any kind
-H, --with-filename Print the filename for each match
-h, --no-filename Suppress the prefixing filename on output
-c, --count Show number of lines matching per file
--column Show the column number of the first match
-A NUM, --after-context=NUM
Print NUM lines of trailing context after matching
lines.
-B NUM, --before-context=NUM
Print NUM lines of leading context before matching
lines.
-C [NUM], --context[=NUM]
Print NUM lines (default 2) of output context.
--print0 Print null byte as separator between filenames,
only works with -f, -g, -l, -L or -c.
-s Suppress error messages about nonexistent or
unreadable files.
File presentation:
--pager=COMMAND Pipes all ack output through COMMAND. For example,
--pager="less -R". Ignored if output is redirected.
--nopager Do not send output through a pager. Cancels any
setting in ~/.ackrc, ACK_PAGER or ACK_PAGER_COLOR.
--[no]heading Print a filename heading above each file's results.
(default: on when used interactively)
--[no]break Print a break between results from different files.
(default: on when used interactively)
--group Same as --heading --break
--nogroup Same as --noheading --nobreak
--[no]color Highlight the matching text (default: on unless
output is redirected, or on Windows)
--[no]colour Same as --[no]color
--color-filename=COLOR
--color-match=COLOR
--color-lineno=COLOR Set the color for filenames, matches, and line numbers.
--flush Flush output immediately, even when ack is used
non-interactively (when output goes to a pipe or
file).
File finding:
-f Only print the files selected, without searching.
The PATTERN must not be specified.
-g Same as -f, but only select files matching PATTERN.
--sort-files Sort the found files lexically.
--show-types Show which types each file has.
--files-from=FILE Read the list of files to search from FILE.
-x Read the list of files to search from STDIN.
File inclusion/exclusion:
--[no]ignore-dir=name Add/Remove directory from the list of ignored dirs
-r, -R, --recurse Recurse into subdirectories (ack's default behavior)
-n, --no-recurse No descending into subdirectories
--[no]follow Follow symlinks. Default is off.
-k, --known-types Include only files with types that ack recognizes.
--type=X Include only X files, where X is a recognized filetype.
--type=noX Exclude X files.
See "ack --help-types" for supported filetypes.
File type specification:
--type-set TYPE=.EXTENSION[,.EXT2[,...]]
Files with the given EXTENSION(s) are recognized as
being of type TYPE. This replaces an existing
definition for type TYPE.
--type-add TYPE=.EXTENSION[,.EXT2[,...]]
Files with the given EXTENSION(s) are recognized as
being of (the existing) type TYPE
Miscellaneous:
--noenv Ignore environment variables and global ackrc files
--ackrc=filename Specify an ackrc file to use
--ignore-ack-defaults Ignore the default definitions that ack includes.
--create-ackrc Outputs a default ackrc for your customization to standard output.
--help This help
--help-types Display all known types
--dump Dump information on which options are loaded from which RC files
--man Man page
--version Display version & copyright
--thpppt Bill the Cat
--bar The warning admiral
Exit status is 0 if match, 1 if no match.
This is version $VERSION of ack.
END_OF_HELP
return;
}
=head2 show_help_types()
Display the filetypes help subpage.
=cut
sub show_help_types {
App::Ack::print( <<'END_OF_HELP' );
Usage: ack [OPTION]... PATTERN [FILES OR DIRECTORIES]
The following is the list of filetypes supported by ack. You can
specify a file type with the --type=TYPE format, or the --TYPE
format. For example, both --type=perl and --perl work.
Note that some extensions may appear in multiple types. For example,
.pod files are both Perl and Parrot.
END_OF_HELP
my @types = filetypes_supported();
my $maxlen = 0;
for ( @types ) {
$maxlen = length if $maxlen < length;
}
for my $type ( sort @types ) {
next if $type =~ /^-/; # Stuff to not show
my $ext_list = $mappings{$type};
if ( ref $ext_list ) {
$ext_list = join( ' ', map { $_->to_string } @{$ext_list} );
}
App::Ack::print( sprintf( " --[no]%-*.*s %s\n", $maxlen, $maxlen, $type, $ext_list ) );
}
return;
}
sub show_man {
require Pod::Usage;
Pod::Usage::pod2usage({
-input => $App::Ack::orig_program_name,
-verbose => 2,
-exitval => 0,
});
}
sub _listify {
my @whats = @_;
return '' if !@whats;
my $end = pop @whats;
my $str = @whats ? join( ', ', @whats ) . " and $end" : $end;
no warnings 'once';
require Text::Wrap;
$Text::Wrap::columns = 75;
return Text::Wrap::wrap( '', ' ', $str );
}
=head2 get_version_statement
Returns the version information for ack.
=cut
sub get_version_statement {
require Config;
my $copyright = get_copyright();
my $this_perl = $Config::Config{perlpath};
if ($^O ne 'VMS') {
my $ext = $Config::Config{_exe};
$this_perl .= $ext unless $this_perl =~ m/$ext$/i;
}
my $ver = sprintf( '%vd', $^V );
my $git_revision = $GIT_REVISION ? " (git commit $GIT_REVISION)" : '';
return <<"END_OF_VERSION";
ack ${VERSION}${git_revision}
Running under Perl $ver at $this_perl
$copyright
This program is free software. You may modify or distribute it
under the terms of the Artistic License v2.0.
END_OF_VERSION
}
=head2 print_version_statement
Prints the version information for ack.
=cut
sub print_version_statement {
App::Ack::print( get_version_statement() );
return;
}
=head2 get_copyright
Return the copyright for ack.
=cut
sub get_copyright {
return $COPYRIGHT;
}
=head2 load_colors
Set default colors, load Term::ANSIColor
=cut
sub load_colors {
eval 'use Term::ANSIColor 3.01 ()';
$ENV{ACK_COLOR_MATCH} ||= 'black on_yellow';
$ENV{ACK_COLOR_FILENAME} ||= 'bold green';
$ENV{ACK_COLOR_LINENO} ||= 'bold yellow';
return;
}
# print subs added in order to make it easy for a third party
# module (such as App::Wack) to redefine the display methods
# and show the results in a different way.
sub print { print {$fh} @_; return; }
sub print_first_filename { App::Ack::print( $_[0], "\n" ); return; }
sub print_blank_line { App::Ack::print( "\n" ); return; }
sub print_separator { App::Ack::print( "--\n" ); return; }
sub print_filename { App::Ack::print( $_[0], $_[1] ); return; }
sub print_line_no { App::Ack::print( $_[0], $_[1] ); return; }
sub print_column_no { App::Ack::print( $_[0], $_[1] ); return; }
sub print_count {
my $filename = shift;
my $nmatches = shift;
my $ors = shift;
my $count = shift;
my $show_filename = shift;
if ($show_filename) {
App::Ack::print( $filename );
App::Ack::print( ':', $nmatches ) if $count;
}
else {
App::Ack::print( $nmatches ) if $count;
}
App::Ack::print( $ors );
return;
}
sub print_count0 {
my $filename = shift;
my $ors = shift;
my $show_filename = shift;
if ($show_filename) {
App::Ack::print( $filename, ':0', $ors );
}
else {
App::Ack::print( '0', $ors );
}
return;
}
sub set_up_pager {
my $command = shift;
return if App::Ack::output_to_pipe();
my $pager;
if ( not open( $pager, '|-', $command ) ) {
App::Ack::die( qq{Unable to pipe to pager "$command": $!} );
}
$fh = $pager;
return;
}
=head2 output_to_pipe()
Returns true if ack's input is coming from a pipe.
=cut
sub output_to_pipe {
return $output_to_pipe;
}
=head2 exit_from_ack
Exit from the application with the correct exit code.
Returns with 0 if a match was found, otherwise with 1. The number of matches is
handed in as the only argument.
=cut
sub exit_from_ack {
my $nmatches = shift;
my $rc = $nmatches ? 0 : 1;
exit $rc;
}
{
my @capture_indices;
my $match_column_number;
sub does_match {
my ( $opt, $line ) = @_;
my $re = $opt->{regex};
my $invert = $opt->{v};
$match_column_number = undef;
@capture_indices = ();
if ( $invert ? $line !~ /$re/ : $line =~ /$re/ ) {
if ( not $invert ) {
use English '-no_match_vars';
$match_column_number = $LAST_MATCH_START[0] + 1;
if ( @LAST_MATCH_START > 1 ) {
@capture_indices = map {
[ $LAST_MATCH_START[$_], $LAST_MATCH_END[$_] ]
} ( 1 .. $#LAST_MATCH_START );
}
}
return 1;
}
else {
return;
}
}
sub get_capture_indices {
return @capture_indices;
}
sub get_match_column {
return $match_column_number;
}
}
sub print_matches_in_resource {
my ( $resource, $opt ) = @_;
my $passthru = $opt->{passthru};
my $max_count = $opt->{m} || -1;
my $nmatches = 0;
my $filename = $resource->name;
my $break = $opt->{break};
my $heading = $opt->{heading};
my $ors = $opt->{print0} ? "\0" : "\n";
my $color = $opt->{color};
my $print_filename = $opt->{show_filename};
my $has_printed_for_this_resource = 0;
App::Ack::iterate($resource, $opt, sub {
if ( App::Ack::does_match($opt, $_) ) {
if( !$has_printed_for_this_resource ) {
if( $break && has_printed_something() ) {
App::Ack::print_blank_line();
}
if( $print_filename) {
if( $heading ) {
my $filename = $resource->name;
if($color) {
$filename = Term::ANSIColor::colored($filename,
$ENV{ACK_COLOR_FILENAME});
}
App::Ack::print_filename( $filename, $ors );
}
}
}
App::Ack::print_line_with_context($opt, $filename, $_, $.);
$has_printed_for_this_resource = 1;
$nmatches++;
$max_count--;
}
elsif ( $passthru ) {
chomp;
if( $break && !$has_printed_for_this_resource && has_printed_something() ) {
App::Ack::print_blank_line();
}
App::Ack::print_line_with_options($opt, $filename, $_, $., ':');
$has_printed_for_this_resource = 1;
}
return $max_count != 0;
});
return $nmatches;
}
sub count_matches_in_resource {
my ( $resource, $opt ) = @_;
my $nmatches = 0;
App::Ack::iterate( $resource, $opt, sub {
++$nmatches if App::Ack::does_match($opt, $_);
return 1;
} );
return $nmatches;
}
sub resource_has_match {
my ( $resource, $opt ) = @_;
my $stash_v = $opt->{v};
$opt->{v} = 0;
my $n = count_matches_in_resource($resource, $opt) > 0;
$opt->{v} = $stash_v;
return $n;
}
{
my @before_ctx_lines;
my @after_ctx_lines;
my $is_iterating;
sub get_context {
if ( not $is_iterating ) {
Carp::croak( 'get_context() called outside of iterate()' );
}
return (
scalar(@before_ctx_lines) ? \@before_ctx_lines : undef,
scalar(@after_ctx_lines) ? \@after_ctx_lines : undef,
);
}
sub iterate {
my ( $resource, $opt, $cb ) = @_;
$is_iterating = 1;
local $opt->{before_context} = $opt->{output} ? 0 : $opt->{before_context};
local $opt->{after_context} = $opt->{output} ? 0 : $opt->{after_context};
my $n_before_ctx_lines = $opt->{before_context} || 0;
my $n_after_ctx_lines = $opt->{after_context} || 0;
my $current_line;
@after_ctx_lines = @before_ctx_lines = ();
if ( $resource->next_text() ) {
$current_line = $_; # prime the first line of input
}
while ( defined $current_line ) {
while ( (@after_ctx_lines < $n_after_ctx_lines) && $resource->next_text() ) {
push @after_ctx_lines, $_;
}
local $_ = $current_line;
local $. = $. - @after_ctx_lines;
last unless $cb->();
push @before_ctx_lines, $current_line;
if($n_after_ctx_lines) {
$current_line = shift @after_ctx_lines;
}
elsif($resource->next_text()) {
$current_line = $_;
}
else {
undef $current_line;
}
shift @before_ctx_lines while @before_ctx_lines > $n_before_ctx_lines;
}
$is_iterating = 0;
return;
}
}
my $has_printed_something;
BEGIN {
$has_printed_something = 0;
}
sub has_printed_something {
return $has_printed_something;
}
sub print_line_with_options {
my ( $opt, $filename, $line, $line_no, $separator ) = @_;
$has_printed_something = 1;
my $print_filename = $opt->{show_filename};
my $print_column = $opt->{column};
my $ors = $opt->{print0} ? "\0" : "\n";
my $heading = $opt->{heading};
my $output_expr = $opt->{output};
my $re = $opt->{regex};
my @line_parts;
if($print_filename) {
if( $heading ) {
push @line_parts, $line_no;
}
else {
push @line_parts, $filename, $line_no;
}
if( $print_column ) {
push @line_parts, get_match_column();
}
}
if( $output_expr ) {
# XXX avoid re-evaluation if we can
while( $line =~ /$re/g ) {
my $output = eval qq{"$output_expr"};
App::Ack::print( join( $separator, @line_parts, $output ), $ors );
}
}
else {
push @line_parts, $line;
App::Ack::print( join( $separator, @line_parts ), $ors );
}
return;
}
{
my $is_first_match;
my $previous_file_processed;
my $previous_line_printed;
BEGIN {
$is_first_match = 1;
$previous_line_printed = -1;
}
sub print_line_with_context {
my ( $opt, $filename, $matching_line, $line_no ) = @_;
my $heading = $opt->{heading};
if( !defined($previous_file_processed) ||
$previous_file_processed ne $filename ) {
$previous_file_processed = $filename;
$previous_line_printed = -1;
if( $heading ) {
$is_first_match = 1;
}
}
my $ors = $opt->{print0} ? "\0" : "\n";
my $color = $opt->{color};
my $match_word = $opt->{w};
my $re = $opt->{regex};
my $is_tracking_context = $opt->{after_context} || $opt->{before_context};
my $output_expr = $opt->{output};
chomp $matching_line;
my ( $before_context, $after_context ) = get_context();
if($before_context) {
my $first_line = $. - @{$before_context};
if( !$is_first_match && $previous_line_printed != $first_line - 1 ) {
App::Ack::print('--', $ors);
}
$previous_line_printed = $.; # XXX unless --after-context
my $offset = @{$before_context};