diff --git a/pkgs/composer/1.x.nix b/pkgs/composer/1.x.nix
new file mode 100644
index 00000000..5d561f86
--- /dev/null
+++ b/pkgs/composer/1.x.nix
@@ -0,0 +1,35 @@
+{ mkDerivation, fetchurl, makeWrapper, unzip, lib, php }:
+let
+  pname = "composer";
+  version = "1.10.26";
+in
+mkDerivation {
+  inherit pname version;
+
+  src = fetchurl {
+    url = "https://getcomposer.org/download/${version}/composer.phar";
+    sha256 = "sha256-y/4fhSdsV6vkZNk0UD2TWqITSUrChidcjfq/qR49vcQ=";
+  };
+
+  dontUnpack = true;
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/bin
+    install -D $src $out/libexec/composer/composer.phar
+    makeWrapper ${php}/bin/php $out/bin/composer \
+      --add-flags "$out/libexec/composer/composer.phar" \
+      --prefix PATH : ${lib.makeBinPath [ unzip ]}
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Dependency Manager for PHP";
+    license = licenses.mit;
+    homepage = "https://getcomposer.org/";
+    changelog = "https://github.com/composer/composer/releases/tag/${version}";
+    maintainers = with maintainers; [ offline ] ++ teams.php.members;
+  };
+}
diff --git a/pkgs/package-overrides.nix b/pkgs/package-overrides.nix
index ea0b3830..55b1bf68 100644
--- a/pkgs/package-overrides.nix
+++ b/pkgs/package-overrides.nix
@@ -35,6 +35,7 @@ in
 
   tools = prev.tools // {
     php-cs-fixer-2 = final.callPackage ./php-cs-fixer/2.x.nix { };
+    composer-1 = final.callPackage ./composer/1.x.nix { };
   } // lib.optionalAttrs (lib.versionOlder prev.php.version "7.2.5") {
     composer = final.callPackage ./composer/2.2.nix { };
   };