build.gradle

buildscript {
    repositories {
        jcenter()
        maven { url "https://plugins.gradle.org/m2/" }
        maven { url  "http://palantir.bintray.com/releases" }
    }

    dependencies {
        classpath 'com.gradle.publish:plugin-publish-plugin:0.9.1'
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.6'
        classpath 'com.netflix.nebula:nebula-dependency-recommender:4.0.2'
        classpath 'com.netflix.nebula:nebula-publishing-plugin:4.9.1'
        classpath 'com.palantir.baseline:gradle-baseline-java:0.12.0'
        classpath 'net.ltgt.gradle:gradle-errorprone-plugin:0.0.9'
    }
}

plugins {
    id 'com.palantir.git-version' version '0.5.3'
    id 'org.inferred.processors' version '1.1.3'
}

apply plugin: 'java'
apply plugin: 'com.palantir.baseline-config'
apply plugin: 'com.palantir.baseline-idea'
apply plugin: 'maven'
apply plugin: 'maven-publish'

tasks.test.dependsOn tasks.publishToMavenLocal

dependencies {
    baseline group: 'com.palantir.baseline', name: 'gradle-baseline-java-config', ext: 'zip'
}

allprojects {
    repositories {
        jcenter()
        maven { url  "http://palantir.bintray.com/releases" }
        maven { url "https://plugins.gradle.org/m2/" }
    }

    apply plugin: 'org.inferred.processors'

    apply plugin: 'nebula.dependency-recommender'
    dependencyRecommendations {
        strategy OverrideTransitives
        propertiesFile file: project.rootProject.file('versions.props')
    }

    group = 'com.palantir.baseline'
    version = gitVersion()
    description = 'A Gradle plugin for applying Baseline-recommended build and IDE settings'
}