This is the configuration we’ve been building in the Emacs From Scratch series, now written as an Org Mode document. This file generates init.el which can be loaded by Emacs at startup.
NOTE: If you run into any issues while using this configuration, please file an issue or send me an email at david at systemcrafters.cc.
The following variables are used to tweak some of the configuration pieces for use in the live streams so you might need to adjust them for your local machine if you try to use this configuration directly.
;; NOTE: init.el is now generated from Emacs.org. Please edit that file
;; in Emacs and init.el will be generated automatically!
;; You will most likely need to adjust this font size for your system!
(defvar efs/default-font-size 100)
(defvar efs/default-variable-font-size 100)
;; Make frame transparency overridable
(defvar efs/frame-transparency '(90 . 90))
(defvar efs/default-font "Hack")In this document I’ve added links in many places that lead you to documentation for the various packages we use. If you’re looking at this file in Emacs, you can put your cursor on a link and press C-c C-o or run M-x org-open-at-point to open the link in your web browser.
;; The default is 800 kilobytes. Measured in bytes.
(setq gc-cons-threshold (* 50 1000 1000))
(defun efs/display-startup-time ()
(message "Emacs loaded in %s with %d garbage collections."
(format "%.2f seconds"
(float-time
(time-subtract after-init-time before-init-time)))
gcs-done))
(add-hook 'emacs-startup-hook #'efs/display-startup-time)
Emacs has a built in package manager but it doesn’t make it easy to automatically install packages on a new system the first time you pull down your configuration. use-package is a really helpful package used in this configuration to make it a lot easier to automate the installation and configuration of everything else we use.
(add-to-list 'load-path "~/projects/emacs/packages")
;; Initialize package sources
(require 'package)
(setq package-archives '(("melpa" . "https://melpa.org/packages/")
("org" . "https://orgmode.org/elpa/")
("elpa" . "https://elpa.gnu.org/packages/")))
(package-initialize)
(unless package-archive-contents
(package-refresh-contents))
;; Initialize use-package on non-Linux platforms
(unless (package-installed-p 'use-package)
(package-install 'use-package))
(require 'use-package)
(setq use-package-always-ensure t)
The auto-package-update package helps us keep our Emacs packages up to date! It will prompt you after a certain number of days either at startup or at a specific time of day to remind you to update your packages.
You can also use M-x auto-package-update-now to update right now!
(use-package auto-package-update
:custom
(auto-package-update-interval 7)
(auto-package-update-prompt-before-update t)
(auto-package-update-hide-results t)
:config
(auto-package-update-maybe)
(auto-package-update-at-time "09:00"))
We use the no-littering package to keep folders where we edit files and the Emacs configuration folder clean! It knows about a wide variety of variables for built in Emacs features as well as those from community packages so it can be much easier than finding and setting these variables yourself.
;; NOTE: If you want to move everything out of the ~/.emacs.d folder
;; reliably, set `user-emacs-directory` before loading no-littering!
;(setq user-emacs-directory "~/.cache/emacs")
(use-package no-littering)
;; no-littering doesn't set this by default so we must place
;; auto save files in the same path as it uses for sessions
(setq auto-save-file-name-transforms
`((".*" ,(no-littering-expand-var-file-name "auto-save/") t)))
This section configures basic UI settings that remove unneeded elements to make Emacs look a lot more minimal and modern. If you’re just getting started in Emacs, the menu bar might be helpful so you can remove the (menu-bar-mode -1) line if you’d like to still see that.
(setq inhibit-startup-message t)
(scroll-bar-mode -1) ; Disable visible scrollbar
(tool-bar-mode -1) ; Disable the toolbar
(tooltip-mode -1) ; Disable tooltips
(set-fringe-mode 10) ; Give some breathing room
(menu-bar-mode -1) ; Disable the menu bar
;; Set up the visible bell
(setq visible-bell t)
(column-number-mode)
(global-display-line-numbers-mode t)
;; Set frame transparency
(set-frame-parameter (selected-frame) 'alpha efs/frame-transparency)
(add-to-list 'default-frame-alist `(alpha . ,efs/frame-transparency))
(set-frame-parameter (selected-frame) 'fullscreen 'maximized)
(add-to-list 'default-frame-alist '(fullscreen . maximized))
;; Disable line numbers for some modes
(dolist (mode '(org-mode-hook
term-mode-hook
shell-mode-hook
treemacs-mode-hook
eshell-mode-hook))
(add-hook mode (lambda () (display-line-numbers-mode 0))))
I am using the Fira Code and Cantarell fonts for this configuration which will more than likely need to be installed on your machine. Both can usually be found in the various Linux distro package managers or downloaded from the links above.
(set-face-attribute 'default nil :font efs/default-font :height efs/default-font-size)
;; Set the fixed pitch face
(set-face-attribute 'fixed-pitch nil :font efs/default-font :height efs/default-font-size)
;; Set the variable pitch face
(set-face-attribute 'variable-pitch nil :font efs/default-font :height efs/default-variable-font-size :weight 'regular)
This configuration uses evil-mode for a Vi-like modal editing experience. general.el is used for easy keybinding configuration that integrates well with which-key. evil-collection is used to automatically configure various Emacs modes with Vi-like keybindings for evil-mode.
;; Make ESC quit prompts
(global-set-key (kbd "<escape>") 'keyboard-escape-quit)
(use-package general
:after evil
:config
(general-create-definer efs/leader-keys
:keymaps '(normal insert visual emacs)
:prefix "SPC"
:global-prefix "C-SPC")
(efs/leader-keys
"SPC" '(completion-at-point :which-key "auto complete code")
"n" '(:ignore t :which-key "navigation")
"nr" '(lsp-treemacs-references :which-key "find references of symbol")
"nd" '(lsp-find-definition :which-key "find definition of symbol")
"nt" '(lsp-type-definition :which-key "find definition of symbol")
"r" '(:ignore t :which-key "refactor")
"ro" '(srefactor-refactor-at-point :which-key "symantic local symbol refactor")
"rr" '(lsp-rename :which-key "clang global symbol refactor")
"m" '(magit-status :which-key "magit status")
"p" '(:ignore t :which-key "project")
"pC" '(projectile-configure-project :which-key "configure the project")
"pc" '(projectile-compile-project :which-key "compile the project")
"pr" '(projectile-run-project :which-key "run the project")
"pt" '(projectile-test-project :which-key "test the project")
"pv" '(treemacs :which-key "show the project view")
"pa" '(treemacs-projectile :which-key "add project to treemacs workspace")
"pd" '(treemacs-remove-project-from-workspace :which-key "remove project from treemacs workspace")
"f" '(:ignore t :which-key "source file")
"fs" '(lsp-treemacs-symbols :which-key "show symbols in the file")
"fr" '(lsp-treemacs-references :which-key "show reference in the file")
"ff" '(clang-format-buffer :which-key "reformats the file using clang-format")
"fd" '(lsp-treemacs-errors-list :which-key "show diagnostic information in file")
"d" '(gdb :which-key "start gdb")
"b" '(gdb-toggle-breakpoint-all :which-key "insert breakpoint on all sessions")
"8" '(gdb-next :which-key "move to next line")
"7" '(gdb-step :which-key "step into line")
"9" '(gdb-continue-all :which-key "continue execution in all sessions")
"5" '(gdb-continue :which-key "continue execution in current sessions")
"0" '(gdb-kill-all-session :which-key "stop debugging")
"k" '(kill-matching-buffers :which-key "kill matching buffers")
"w" '(gud-watch :which-key "add watch to variable")
"t" '(:ignore t :which-key "toggles")
"tf" '(other-frame :which-key "toggle frame")
"ti" '(ivy-rich-mode :which-key "toggle ivy-rich-mode")))
(use-package evil
:init
(setq evil-want-integration t)
(setq evil-want-keybinding nil)
(setq evil-want-C-u-scroll t)
(setq evil-want-C-i-jump nil)
:config
(evil-mode 1)
(setq evil-want-keybinding t)
(define-key evil-insert-state-map (kbd "C-g") 'evil-normal-state)
(define-key evil-insert-state-map (kbd "C-h") 'evil-delete-backward-char-and-join)
;; Use visual line motions even outside of visual-line-mode buffers
(evil-global-set-key 'motion "j" 'evil-next-visual-line)
(evil-global-set-key 'motion "k" 'evil-previous-visual-line)
(evil-set-initial-state 'messages-buffer-mode 'normal)
(evil-set-initial-state 'dashboard-mode 'normal))
(use-package evil-collection
:after evil
:config
(evil-collection-init))
command-log-mode is useful for displaying a panel showing each key binding you use in a panel on the right side of the frame. Great for live streams and screencasts!
(use-package command-log-mode
:commands command-log-mode)
doom-themes is a great set of themes with a lot of variety and support for many different Emacs modes. Taking a look at the screenshots might help you decide which one you like best. You can also run M-x counsel-load-theme to choose between them easily.
(use-package doom-themes
:init (load-theme 'doom-palenight t))
doom-modeline is a very attractive and rich (yet still minimal) mode line configuration for Emacs. The default configuration is quite good but you can check out the configuration options for more things you can enable or disable.
NOTE: The first time you load your configuration on a new machine, you’ll need to run `M-x all-the-icons-install-fonts` so that mode line icons display correctly.
(use-package all-the-icons)
(use-package doom-modeline
:init (doom-modeline-mode 1)
:custom ((doom-modeline-height 15)))
which-key is a useful UI panel that appears when you start pressing any key binding in Emacs to offer you all possible completions for the prefix. For example, if you press C-c (hold control and press the letter c), a panel will appear at the bottom of the frame displaying all of the bindings under that prefix and which command they run. This is very useful for learning the possible key bindings in the mode of your current buffer.
(use-package which-key
:defer 0
:diminish which-key-mode
:config
(which-key-mode)
(setq which-key-idle-delay 1))
Ivy is an excellent completion framework for Emacs. It provides a minimal yet powerful selection menu that appears when you open files, switch buffers, and for many other tasks in Emacs. Counsel is a customized set of commands to replace `find-file` with `counsel-find-file`, etc which provide useful commands for each of the default completion commands.
ivy-rich adds extra columns to a few of the Counsel commands to provide more information about each item.
(use-package ivy
:diminish
:bind (("C-s" . swiper)
:map ivy-minibuffer-map
("TAB" . ivy-alt-done)
("C-l" . ivy-alt-done)
("C-j" . ivy-next-line)
("C-k" . ivy-previous-line)
:map ivy-switch-buffer-map
("C-k" . ivy-previous-line)
("C-l" . ivy-done)
("C-d" . ivy-switch-buffer-kill)
:map ivy-reverse-i-search-map
("C-k" . ivy-previous-line)
("C-d" . ivy-reverse-i-search-kill))
:config
(ivy-mode 1))
(use-package ivy-rich
:after ivy
:init
(ivy-rich-mode t))
(use-package counsel
:bind (("C-M-j" . 'counsel-switch-buffer)
:map minibuffer-local-map
("C-r" . 'counsel-minibuffer-history))
:custom
(counsel-linux-app-format-function #'counsel-linux-app-format-function-name-only)
:config
(counsel-mode 1))
prescient.el provides some helpful behavior for sorting Ivy completion candidates based on how recently or frequently you select them. This can be especially helpful when using M-x to run commands that you don’t have bound to a key but still need to access occasionally.
This Prescient configuration is optimized for use in System Crafters videos and streams, check out the video on prescient.el for more details on how to configure it!
(use-package ivy-prescient
:after counsel
:custom
(ivy-prescient-enable-filtering nil)
:config
;; Uncomment the following line to have sorting remembered across sessions!
;(prescient-persist-mode 1)
(ivy-prescient-mode 1))
Helpful adds a lot of very helpful (get it?) information to Emacs’ describe- command buffers. For example, if you use describe-function, you will not only get the documentation about the function, you will also see the source code of the function and where it gets used in other places in the Emacs configuration. It is very useful for figuring out how things work in Emacs.
(use-package helpful
:commands (helpful-callable helpful-variable helpful-command helpful-key)
:custom
(counsel-describe-function-function #'helpful-callable)
(counsel-describe-variable-function #'helpful-variable)
:bind
([remap describe-function] . counsel-describe-function)
([remap describe-command] . helpful-command)
([remap describe-variable] . counsel-describe-variable)
([remap describe-key] . helpful-key))
This is an example of using Hydra to design a transient key binding for quickly adjusting the scale of the text on screen. We define a hydra that is bound to C-s t s and, once activated, j and k increase and decrease the text scale. You can press any other key (or f specifically) to exit the transient key map.
(use-package hydra
:defer t)
(defhydra hydra-text-scale (:timeout 4)
"scale text"
("j" text-scale-increase "in")
("k" text-scale-decrease "out")
("f" nil "finished" :exit t))
(efs/leader-keys
"ts" '(hydra-text-scale/body :which-key "scale text"))
Org Mode is one of the hallmark features of Emacs. It is a rich document editor, project planner, task and time tracker, blogging engine, and literate coding utility all wrapped up in one package.
This section contains the basic configuration for org-mode plus the configuration for Org agendas and capture templates. There’s a lot to unpack in here so I’d recommend watching the videos for Part 5 and Part 6 for a full explanation.
(defun efs/org-mode-setup ()
(org-indent-mode)
(variable-pitch-mode 1)
(visual-line-mode 1))
(use-package org
:pin org
:commands (org-capture org-agenda)
:hook (org-mode . efs/org-mode-setup)
:config
(setq org-ellipsis " ▾")
(setq org-agenda-start-with-log-mode t)
(setq org-log-done 'time)
(setq org-log-into-drawer t)
(setq org-agenda-files
'("~/projects/emacs/OrgFiles/Tasks.org"
"~/projects/emacs/OrgFiles/Habits.org"
"~/projects/emacs/OrgFiles/Birthdays.org"))
(require 'org-habit)
(add-to-list 'org-modules 'org-habit)
(setq org-habit-graph-column 60)
(setq org-todo-keywords
'((sequence "TODO(t)" "NEXT(n)" "|" "DONE(d!)")
(sequence "BACKLOG(b)" "PLAN(p)" "READY(r)" "ACTIVE(a)" "REVIEW(v)" "WAIT(w@/!)" "HOLD(h)" "|" "COMPLETED(c)" "CANC(k@)")))
(setq org-refile-targets
'(("Archive.org" :maxlevel . 1)
("Tasks.org" :maxlevel . 1)))
;; Save Org buffers after refiling!
(advice-add 'org-refile :after 'org-save-all-org-buffers)
(setq org-tag-alist
'((:startgroup)
; Put mutually exclusive tags here
(:endgroup)
("@errand" . ?E)
("@home" . ?H)
("@work" . ?W)
("agenda" . ?a)
("planning" . ?p)
("publish" . ?P)
("batch" . ?b)
("note" . ?n)
("idea" . ?i)))
;; Configure custom agenda views
(setq org-agenda-custom-commands
'(("d" "Dashboard"
((agenda "" ((org-deadline-warning-days 7)))
(todo "NEXT"
((org-agenda-overriding-header "Next Tasks")))
(tags-todo "agenda/ACTIVE" ((org-agenda-overriding-header "Active Projects")))))
("n" "Next Tasks"
((todo "NEXT"
((org-agenda-overriding-header "Next Tasks")))))
("W" "Work Tasks" tags-todo "+work-email")
;; Low-effort next actions
("e" tags-todo "+TODO=\"NEXT\"+Effort<15&+Effort>0"
((org-agenda-overriding-header "Low Effort Tasks")
(org-agenda-max-todos 20)
(org-agenda-files org-agenda-files)))
("w" "Workflow Status"
((todo "WAIT"
((org-agenda-overriding-header "Waiting on External")
(org-agenda-files org-agenda-files)))
(todo "REVIEW"
((org-agenda-overriding-header "In Review")
(org-agenda-files org-agenda-files)))
(todo "PLAN"
((org-agenda-overriding-header "In Planning")
(org-agenda-todo-list-sublevels nil)
(org-agenda-files org-agenda-files)))
(todo "BACKLOG"
((org-agenda-overriding-header "Project Backlog")
(org-agenda-todo-list-sublevels nil)
(org-agenda-files org-agenda-files)))
(todo "READY"
((org-agenda-overriding-header "Ready for Work")
(org-agenda-files org-agenda-files)))
(todo "ACTIVE"
((org-agenda-overriding-header "Active Projects")
(org-agenda-files org-agenda-files)))
(todo "COMPLETED"
((org-agenda-overriding-header "Completed Projects")
(org-agenda-files org-agenda-files)))
(todo "CANC"
((org-agenda-overriding-header "Cancelled Projects")
(org-agenda-files org-agenda-files)))))))
(setq org-capture-templates
`(("t" "Tasks / Projects")
("tt" "Task" entry (file+olp "~/projects/emacs/OrgFiles/Tasks.org" "Inbox")
"* TODO %?\n %U\n %a\n %i" :empty-lines 1)
("j" "Journal Entries")
("jj" "Journal" entry
(file+olp+datetree "~/projects/emacs/OrgFiles/Journal.org")
"\n* %<%I:%M %p> - Journal :journal:\n\n%?\n\n"
;; ,(dw/read-file-as-string "~/Notes/Templates/Daily.org")
:clock-in :clock-resume
:empty-lines 1)
("jm" "Meeting" entry
(file+olp+datetree "~/projects/emacs/OrgFiles/Journal.org")
"* %<%I:%M %p> - %a :meetings:\n\n%?\n\n"
:clock-in :clock-resume
:empty-lines 1)
("w" "Workflows")
("we" "Checking Email" entry (file+olp+datetree "~/projects/emacs/OrgFiles/Journal.org")
"* Checking Email :email:\n\n%?" :clock-in :clock-resume :empty-lines 1)
("m" "Metrics Capture")
("mw" "Weight" table-line (file+headline "~/projects/emacs/OrgFiles/Metrics.org" "Weight")
"| %U | %^{Weight} | %^{Notes} |" :kill-buffer t)))
(define-key global-map (kbd "C-c j")
(lambda () (interactive) (org-capture nil "jj")))
(efs/org-font-setup))
org-bullets replaces the heading stars in org-mode buffers with nicer looking characters that you can control. Another option for this is org-superstar-mode which we may cover in a later video.
(use-package org-bullets
:hook (org-mode . org-bullets-mode)
:custom
(org-bullets-bullet-list '("◉" "○" "●" "○" "●" "○" "●")))
We use visual-fill-column to center org-mode buffers for a more pleasing writing experience as it centers the contents of the buffer horizontally to seem more like you are editing a document. This is really a matter of personal preference so you can remove the block below if you don’t like the behavior.
(defun efs/org-mode-visual-fill ()
(setq visual-fill-column-width 100
visual-fill-column-center-text t)
(visual-fill-column-mode 1))
(use-package visual-fill-column
:hook (org-mode . efs/org-mode-visual-fill))
The efs/org-font-setup function configures various text faces to tweak the sizes of headings and use variable width fonts in most cases so that it looks more like we’re editing a document in org-mode. We switch back to fixed width (monospace) fonts for code blocks and tables so that they display correctly.
(defun efs/org-font-setup ()
;; Replace list hyphen with dot
(font-lock-add-keywords 'org-mode
'(("^ *\\([-]\\) "
(0 (prog1 () (compose-region (match-beginning 1) (match-end 1) "•"))))))
;; Set faces for heading levels
(dolist (face '((org-level-1 . 1.2)
(org-level-2 . 1.1)
(org-level-3 . 1.05)
(org-level-4 . 1.0)
(org-level-5 . 1.1)
(org-level-6 . 1.1)
(org-level-7 . 1.1)
(org-level-8 . 1.1)))
(set-face-attribute (car face) nil :font efs/default-font :weight 'regular :height (cdr face)))
;; Ensure that anything that should be fixed-pitch in Org files appears that way
(set-face-attribute 'org-block nil :foreground nil :inherit 'fixed-pitch)
(set-face-attribute 'org-table nil :inherit 'fixed-pitch)
(set-face-attribute 'org-formula nil :inherit 'fixed-pitch)
(set-face-attribute 'org-code nil :inherit '(shadow fixed-pitch))
(set-face-attribute 'org-table nil :inherit '(shadow fixed-pitch))
(set-face-attribute 'org-verbatim nil :inherit '(shadow fixed-pitch))
(set-face-attribute 'org-special-keyword nil :inherit '(font-lock-comment-face fixed-pitch))
(set-face-attribute 'org-meta-line nil :inherit '(font-lock-comment-face fixed-pitch))
(set-face-attribute 'org-checkbox nil :inherit 'fixed-pitch)
(set-face-attribute 'line-number nil :inherit 'fixed-pitch)
(set-face-attribute 'line-number-current-line nil :inherit 'fixed-pitch))
To execute or export code in org-mode code blocks, you’ll need to set up org-babel-load-languages for each language you’d like to use. This page documents all of the languages that you can use with org-babel.
(with-eval-after-load 'org
(org-babel-do-load-languages
'org-babel-load-languages
'((emacs-lisp . t)
(python . t)))
(push '("conf-unix" . conf-unix) org-src-lang-modes))
Org Mode’s structure templates feature enables you to quickly insert code blocks into your Org files in combination with org-tempo by typing < followed by the template name like el or py and then press TAB. For example, to insert an empty emacs-lisp block below, you can type <el and press TAB to expand into such a block.
You can add more src block templates below by copying one of the lines and changing the two strings at the end, the first to be the template name and the second to contain the name of the language as it is known by Org Babel.
(with-eval-after-load 'org
;; This is needed as of Org 9.2
(require 'org-tempo)
(add-to-list 'org-structure-template-alist '("sh" . "src shell"))
(add-to-list 'org-structure-template-alist '("el" . "src emacs-lisp"))
(add-to-list 'org-structure-template-alist '("py" . "src python")))
This snippet adds a hook to org-mode buffers so that efs/org-babel-tangle-config gets executed each time such a buffer gets saved. This function checks to see if the file being saved is the Emacs.org file you’re looking at right now, and if so, automatically exports the configuration here to the associated output files.
;; Automatically tangle our Emacs.org config file when we save it
(defun efs/org-babel-tangle-config ()
(when (string-equal (file-name-directory (buffer-file-name))
(expand-file-name user-emacs-directory))
;; Dynamic scoping to the rescue
(let ((org-confirm-babel-evaluate nil))
(org-babel-tangle))))
(add-hook 'org-mode-hook (lambda () (add-hook 'after-save-hook #'efs/org-babel-tangle-config)))
We use the excellent lsp-mode to enable IDE-like functionality for many different programming languages via “language servers” that speak the Language Server Protocol. Before trying to set up lsp-mode for a particular language, check out the documentation for your language so that you can learn which language servers are available and how to install them.
The lsp-keymap-prefix setting enables you to define a prefix for where lsp-mode’s default keybindings will be added. I highly recommend using the prefix to find out what you can do with lsp-mode in a buffer.
The which-key integration adds helpful descriptions of the various keys so you should be able to learn a lot just by pressing C-c l in a lsp-mode buffer and trying different things that you find there.
(defun efs/lsp-mode-setup ()
(setq lsp-headerline-breadcrumb-segments '(path-up-to-project file symbols))
(lsp-headerline-breadcrumb-mode)
(setq lsp-headerline-breadcrumb-enable t)
(setq lsp-headerline-breadcrumb-icons-enable t))
(use-package lsp-mode
:commands (lsp lsp-deferred)
:hook (lsp-mode . efs/lsp-mode-setup)
:init
(setq lsp-keymap-prefix "C-c l") ;; Or 'C-l', 's-l'
:config
(progn
(add-hook 'prog-mode-hook #'lsp)
(lsp-register-client
(make-lsp-client :new-connection (lsp-tramp-connection
"/mnt/common/hdevarajan/stage/spack/var/spack/environments/emacs/.spack-env/view/bin/clang")
:major-modes '(c-mode c++-mode)
:remote? t
:server-id 'clangd-remote)))
(lsp-enable-which-key-integration t))
lsp-ui is a set of UI enhancements built on top of lsp-mode which make Emacs feel even more like an IDE. Check out the screenshots on the lsp-ui homepage (linked at the beginning of this paragraph) to see examples of what it can do.
(use-package lsp-ui
:hook (lsp-mode . lsp-ui-mode)
:custom
(lsp-ui-doc-position 'bottom))
lsp-treemacs provides nice tree views for different aspects of your code like symbols in a file, references of a symbol, or diagnostic messages (errors and warnings) that are found in your code.
Try these commands with M-x:
lsp-treemacs-symbols- Show a tree view of the symbols in the current filelsp-treemacs-references- Show a tree view for the references of the symbol under the cursorlsp-treemacs-error-list- Show a tree view for the diagnostic messages in the project
This package is built on the treemacs package which might be of some interest to you if you like to have a file browser at the left side of your screen in your editor.
(use-package lsp-treemacs
:after lsp)
lsp-ivy integrates Ivy with lsp-mode to make it easy to search for things by name in your code. When you run these commands, a prompt will appear in the minibuffer allowing you to type part of the name of a symbol in your code. Results will be populated in the minibuffer so that you can find what you’re looking for and jump to that location in the code upon selecting the result.
Try these commands with M-x:
lsp-ivy-workspace-symbol- Search for a symbol name in the current project workspacelsp-ivy-global-workspace-symbol- Search for a symbol name in all active project workspaces
(use-package lsp-ivy
:after lsp)
(use-package aggressive-indent
:config
(global-aggressive-indent-mode 1)
(add-to-list 'aggressive-indent-excluded-modes 'html-mode)
(add-to-list 'aggressive-indent-excluded-modes 'prog-mode)
(add-hook 'emacs-lisp-mode-hook #'aggressive-indent-mode))dap-mode is an excellent package for bringing rich debugging capabilities to Emacs via the Debug Adapter Protocol. You should check out the configuration docs to learn how to configure the debugger for your language. Also make sure to check out the documentation for the debug adapter to see what configuration parameters are available to use for your debug templates!
(use-package dap-mode
;; Uncomment the config below if you want all UI panes to be hidden by default!
;; :custom
;; (lsp-enable-dap-auto-configure nil)
;; :config
;; (dap-ui-mode 1)
:commands dap-debug
:config
;; Set up Node debugging
(require 'dap-node)
(dap-node-setup) ;; Automatically installs Node debug adapter if needed
;; Bind `C-c l d` to `dap-hydra` for easy access
(general-define-key
:keymaps 'lsp-mode-map
:prefix lsp-keymap-prefix
"d" '(dap-hydra t :wk "debugger")))
;; GDB base package
(use-package quelpa)
(require 'quelpa)
(use-package quelpa-use-package)
(require 'quelpa-use-package)
(use-package gdb-mi
:quelpa (gdb-mi :fetcher git
:url "https://github.com/hariharan-devarajan/emacs-gdb.git"
:files ("*.el" "*.c" "*.h" "Makefile"))
:init
(fmakunbound 'gdb)
(fmakunbound 'gdb-enable-debug))
;; GDB functions to enhance functionality
(defun gdb-pid-internal (debuggee-pid)
"Start debugging an executable with DEBUGGEE-PID in a new current session."
(let ((session (gdb-create-session)))
(setf (gdb--session-debuggee-path session) debuggee-pid)
(with-selected-frame (gdb--session-frame session)
(gdb--command (concat "attach " debuggee-pid))
(gdb--command "-file-list-exec-source-file" 'gdb--context-initial-file)
(gdb--rename-buffers-with-debuggee debuggee-pid))
(cl-loop for frame in (frame-list)
when (eq (frame-parameter frame 'gdb--session) session)
do (gdb--rename-frame frame))))
(defun gdb-toggle-breakpoint-all (&optional arg)
"Toggle breakpoint in all active gdb sessions location.
When ARG is non-nil, prompt for additional breakpoint settings.
If ARG is `dprintf' create a dprintf breakpoint instead."
(interactive "P")
(setq gdb--session-temp gdb--session)
(cl-loop for session in gdb--sessions do
(setq gdb--session session)
(let ((breakpoint-on-point (gdb--infer-breakpoint session))
(location (gdb--point-location))
(dprintf (eq arg 'dprintf))
type thread ignore-count condition format-args)
(when (and (not location) breakpoint-on-point)
(setq location (gdb--infer-breakpoint-location breakpoint-on-point)))
(when (or arg (not location))
(unless (string= (or location "")
(setq location (read-string (concat "Location: ") location)))
(setq breakpoint-on-point nil))
(when breakpoint-on-point
(setq thread (gdb--breakpoint-thread breakpoint-on-point)
ignore-count (gdb--breakpoint-ignore-count breakpoint-on-point)
condition (gdb--breakpoint-condition breakpoint-on-point)))
(setq
type (cdr (assoc-string (completing-read (concat "Type of " (if dprintf "dprintf" "breakpoint") ":")
gdb--available-breakpoint-types nil t nil nil
(caar gdb--available-breakpoint-types))
gdb--available-breakpoint-types))
thread (gdb--ask-for-thread thread)
ignore-count (read-number "Ignore count: " (or ignore-count 0))
condition (gdb--read-line "Condition: " condition))
(when dprintf (setq format-args (gdb--read-line "Format and args: "))))
(when breakpoint-on-point
(gdb--command (format "-break-delete %d" (gdb--breakpoint-number breakpoint-on-point))
(cons 'gdb--context-breakpoint-delete breakpoint-on-point)))
(when (and location (or arg (not breakpoint-on-point)))
(gdb--command (concat "-" (if dprintf "dprintf" "break") "-insert "
(and (> (length condition) 0) (concat "-c " (gdb--escape-argument condition) " "))
(and thread (format "-p %d " (gdb--thread-id thread)))
(and ignore-count (> ignore-count 0) (format "-i %d " ignore-count))
type "-f " (gdb--escape-argument location)
(when dprintf (concat " " format-args)))
'gdb--context-breakpoint-insert nil t))))
(setq gdb--session gdb--session-temp))
(defun gdb-pid (debuggee-pid)
"Start debugging an executable with DEBUGGEE-PID in the current session."
(interactive "spid: ")
(gdb-pid-internal debuggee-pid))
(defun gdb-continue-all (&optional arg)
"Continues all GDB Sessions. If ARG is nil, try to resume threads in this order:
- Inferred thread if it is stopped
- Selected thread if it is stopped
- All threads
If ARG is non-nil, resume all threads unconditionally."
(interactive "P")
(setq gdb--session-temp gdb--session)
(cl-loop for session in gdb--sessions do
(setq gdb--session session)
(gdb--with-valid-session
(let* ((inferred-thread (gdb--infer-thread 'not-selected))
(selected-thread (gdb--session-selected-thread session))
(thread-to-resume
(unless arg
(cond
((and inferred-thread (string= (gdb--thread-state inferred-thread) "stopped")) inferred-thread)
((and selected-thread (string= (gdb--thread-state selected-thread) "stopped")) selected-thread)))))
(if (or arg (not thread-to-resume))
(gdb--command "-exec-continue --all")
(gdb--command "-exec-continue" nil thread-to-resume)))))
(setq gdb--session gdb--session-temp))
(defun gdb-kill-all-session ()
"Kill all active GDB session."
(interactive)
(setq gdb--session-temp gdb--session)
(cl-loop for session in gdb--sessions do
(setq gdb--session session)
(gdb--kill-session (gdb--infer-session)))
(setq gdb--session gdb--session-temp))
(defun executable-find (command)
"Search for COMMAND in `exec-path' and return the absolute file name.
Return nil if COMMAND is not found anywhere in `exec-path'."
;; Use 1 rather than file-executable-p to better match the behavior of
;; call-process.
(locate-file command exec-path exec-suffixes 1))
(setq mpi-executable (executable-find "mpirun"))
(defun string-trim-final-newline (string)
;; trim the final \n if exists in a string.
(let ((len (length string)))
(cond
((and (> len 0) (eql (aref string (- len 1)) ?\n))
(substring string 0 (- len 1)))
(t string))))
(defun mpi-debug (path procs)
"Executes an mpi process with executable and number of procs.
mpirun -n $procs $path.
Addionally, it spawn a debugger with each process pre-attached to the gdb on separate sessions."
(interactive
(list
(read-file-name "Enter Executable: ")
(read-string "Num of procs: ")
))
(setq mpi-command (format "%s -n %s %s" mpi-executable procs path))
(with-output-to-temp-buffer mpi-command
(async-shell-command mpi-command mpi-command "*Messages*")
(pop-to-buffer mpi-command)
(setq proc_ids (shell-command-to-string (format "ps -aef | grep %s | grep -v grep | grep -v mpirun | awk '{print $2}'" path)))
(setq proc_ids (string-trim-final-newline proc_ids))
(setq proc_id_lists (split-string proc_ids "\n"))
(cl-loop for proc_id in proc_id_lists do
(gdb-pid-internal proc_id))
))
(defun mpi-attach-debug (path)
"Executes an mpi process with executable and number of procs.
mpirun -n $procs $path.
Addionally, it spawn a debugger with each process pre-attached to the gdb on separate sessions."
(interactive
(list
(read-file-name "Enter Executable: ")
))
(setq path (file-remote-p (file-truename path) 'localname))
(setq path (file-name-nondirectory path))
(setq mpi-command (format "%s %s" mpi-executable path))
(setq pipe (format "ps -aef | grep '%s' | grep -v grep | grep -v mpirun | awk '{print $2}'" path))
(message (format "Command %s" pipe))
(setq proc_ids (shell-command-to-string pipe))
(message (format "Process Ids to attach %s..." proc_ids))
(setq proc_ids (string-trim-final-newline proc_ids))
(setq proc_id_lists (split-string proc_ids "\n"))
(cl-loop for proc_id in proc_id_lists do
(gdb-pid-internal proc_id))
)
(setq comint-prompt-read-only t)This is a basic configuration for the TypeScript language so that .ts files activate typescript-mode when opened. We’re also adding a hook to typescript-mode-hook to call lsp-deferred so that we activate lsp-mode to get LSP features every time we edit TypeScript code.
(use-package typescript-mode
:mode "\\.ts\\'"
:hook (typescript-mode . lsp-deferred)
:config
(setq typescript-indent-level 2))
Important note! For lsp-mode to work with TypeScript (and JavaScript) you will need to install a language server on your machine. If you have Node.js installed, the easiest way to do that is by running the following command:
npm install -g typescript-language-server typescript
This will install the typescript-language-server and the TypeScript compiler package.
We use lsp-mode and dap-mode to provide a more complete development environment for Python in Emacs. Check out the pyls configuration in the lsp-mode documentation for more details.
Make sure you have the pyls language server installed before trying lsp-mode!
pip install --user "python-language-server[all]"
There are a number of other language servers for Python so if you find that pyls doesn’t work for you, consult the lsp-mode language configuration documentation to try the others!
(use-package python-mode
:ensure t
:hook (python-mode . lsp-deferred)
:custom
;; NOTE: Set these if Python 3 is called "python3" on your system!
;; (python-shell-interpreter "python3")
;; (dap-python-executable "python3")
(dap-python-debugger 'debugpy)
:config
(require 'dap-python))
You can use the pyvenv package to use virtualenv environments in Emacs. The pyvenv-activate command should configure Emacs to cause lsp-mode and dap-mode to use the virtual environment when they are loaded, just select the path to your virtual environment before loading your project.
(use-package pyvenv
:after python-mode
:config
(pyvenv-mode 1))
(setq package-selected-packages '(lsp-mode yasnippet lsp-treemacs helm-lsp
projectile hydra clang-format+ flycheck company avy helm-xref dap-mode))
(when (cl-find-if-not #'package-installed-p package-selected-packages)
(package-refresh-contents)
(mapc #'package-install package-selected-packages))
;; sample `helm' configuration use https://github.com/emacs-helm/helm/ for details
(helm-mode)
(require 'helm-xref)
(require 'clang-format+)
;; (add-hook 'c-mode-common-hook #'clang-format+-mode)
;; (setq clang-format+-always-enable t)
(which-key-mode)
(dolist (mode '(c-mode-hook
c++-mode-hook))
(add-hook mode 'lsp)
(require 'projectile)
(semantic-mode 1)
(require 'dap-cpptools)
(add-hook mode (lambda () (lsp-mode t)))
(add-hook mode (lambda () (lsp-ui-mode t)))
(add-hook mode (lambda () (setq emacs-clang-rename-compile-commands-file (concat (projectile-project-root) "build/compile_commands.json"))))
(add-hook mode (lambda () (setq projectile-project-compile-cmd "cmake --build . -j")))
(add-hook mode (lambda () (setq projectile-project-test-cmd "ctest -vv")))
(add-hook mode (lambda () (setq projectile-project-configure-cmd (concat "rm -rf " (projectile-project-root) "build/* && cmake ../ -B ./ -DCMAKE_PREFIX_PATH=$HOME/install -DCMAKE_EXPORT_COMPILE_COMMANDS=1 -DCMAKE_BUILD_TYPE=Debug")))))
(setq gc-cons-threshold (* 100 1024 1024)
read-process-output-max (* 1024 1024)
treemacs-space-between-root-nodes nil
company-idle-delay 0.0
company-minimum-prefix-length 1
lsp-idle-delay 0.1) ;; clangd is fast
(with-eval-after-load 'lsp-mode
(add-hook 'lsp-mode-hook #'lsp-enable-which-key-integration)
(require 'dap-cpptools)
(yas-global-mode))Company Mode provides a nicer in-buffer completion interface than completion-at-point which is more reminiscent of what you would expect from an IDE. We add a simple configuration to make the keybindings a little more useful (TAB now completes the selection and initiates completion at the current location if needed).
We also use company-box to further enhance the look of the completions with icons and better overall presentation.
(use-package company
:after lsp-mode
:hook (lsp-mode . company-mode)
:bind (:map company-active-map
("<tab>" . company-complete-selection))
(:map lsp-mode-map
("<tab>" . company-indent-or-complete-common))
:custom
(company-minimum-prefix-length 1)
(company-idle-delay 0.0))
(use-package company-box
:hook (company-mode . company-box-mode))
Projectile is a project management library for Emacs which makes it a lot easier to navigate around code projects for various languages. Many packages integrate with Projectile so it’s a good idea to have it installed even if you don’t use its commands directly.
(use-package projectile
:diminish projectile-mode
:config (projectile-mode)
:custom ((projectile-completion-system 'ivy))
:bind-keymap
("C-c p" . projectile-command-map)
:init
;; NOTE: Set this to the folder where you keep your Git repos!
(when (file-directory-p "~/projects")
(setq projectile-project-search-path '("~/projects")))
(setq projectile-switch-project-action #'projectile-dired))
(use-package counsel-projectile
:after projectile
:config (counsel-projectile-mode))(use-package tramp
:config
(eval-after-load 'tramp '(setenv "SHELL" "/bin/bash")))
(setq tramp-chunksize 500)
(setq tramp-default-method "sshx")
(add-to-list 'tramp-remote-path "/mnt/common/hdevarajan/stage/spack/var/spack/environments/emacs/.spack-env/view/bin")Magit is the best Git interface I’ve ever used. Common Git operations are easy to execute quickly using Magit’s command panel system.
(use-package magit
:commands magit-status
:custom
(magit-display-buffer-function #'magit-display-buffer-same-window-except-diff-v1))
;; NOTE: Make sure to configure a GitHub token before using this package!
;; - https://magit.vc/manual/forge/Token-Creation.html#Token-Creation
;; - https://magit.vc/manual/ghub/Getting-Started.html#Getting-Started
(use-package forge
:after magit)
Emacs’ built in commenting functionality comment-dwim (usually bound to M-;) doesn’t always comment things in the way you might expect so we use evil-nerd-commenter to provide a more familiar behavior. I’ve bound it to M-/ since other editors sometimes use this binding but you could also replace Emacs’ M-; binding with this command.
(use-package evil-nerd-commenter
:bind ("M-/" . evilnc-comment-or-uncomment-lines))
rainbow-delimiters is useful in programming modes because it colorizes nested parentheses and brackets according to their nesting depth. This makes it a lot easier to visually match parentheses in Emacs Lisp code without having to count them yourself.
(use-package rainbow-delimiters
:hook (prog-mode . rainbow-delimiters-mode))
term-mode is a built-in terminal emulator in Emacs. Because it is written in Emacs Lisp, you can start using it immediately with very little configuration. If you are on Linux or macOS, term-mode is a great choice to get started because it supports fairly complex terminal applications (htop, vim, etc) and works pretty reliably. However, because it is written in Emacs Lisp, it can be slower than other options like vterm. The speed will only be an issue if you regularly run console apps with a lot of output.
One important thing to understand is line-mode versus char-mode. line-mode enables you to use normal Emacs keybindings while moving around in the terminal buffer while char-mode sends most of your keypresses to the underlying terminal. While using term-mode, you will want to be in char-mode for any terminal applications that have their own keybindings. If you’re just in your usual shell, line-mode is sufficient and feels more integrated with Emacs.
With evil-collection installed, you will automatically switch to char-mode when you enter Evil’s insert mode (press i). You will automatically be switched back to line-mode when you enter Evil’s normal mode (press ESC).
Run a terminal with M-x term!
Useful key bindings:
C-c C-p/C-c C-n- go back and forward in the buffer’s prompts (also[[and]]with evil-mode)C-c C-k- Enter char-modeC-c C-j- Return to line-mode- If you have
evil-collectioninstalled,term-modewill enter char mode when you use Evil’s Insert mode
(use-package term
:commands term
:config
(setq explicit-shell-file-name "bash") ;; Change this to zsh, etc
;;(setq explicit-zsh-args '()) ;; Use 'explicit-<shell>-args for shell-specific args
;; Match the default Bash shell prompt. Update this if you have a custom prompt
(setq term-prompt-regexp "^[^#$%>\n]*[#$%>] *"))
The eterm-256color package enhances the output of term-mode to enable handling of a wider range of color codes so that many popular terminal applications look as you would expect them to. Keep in mind that this package requires ncurses to be installed on your machine so that it has access to the tic program. Most Linux distributions come with this program installed already so you may not have to do anything extra to use it.
(use-package eterm-256color
:hook (term-mode . eterm-256color-mode))
vterm is an improved terminal emulator package which uses a compiled native module to interact with the underlying terminal applications. This enables it to be much faster than term-mode and to also provide a more complete terminal emulation experience.
Make sure that you have the necessary dependencies installed before trying to use vterm because there is a module that will need to be compiled before you can use it successfully.
(use-package vterm
:commands vterm
:config
(setq term-prompt-regexp "^[^#$%>\n]*[#$%>] *") ;; Set this to match your custom shell prompt
;;(setq vterm-shell "zsh") ;; Set this to customize the shell to launch
(setq vterm-max-scrollback 10000))
shell-mode is a middle ground between term-mode and Eshell. It is not a terminal emulator so more complex terminal programs will not run inside of it. It does have much better integration with Emacs because all command input in this mode is handled by Emacs and then sent to the underlying shell once you press Enter. This means that you can use evil-mode’s editing motions on the command line, unlike in the terminal emulator modes above.
Useful key bindings:
C-c C-p/C-c C-n- go back and forward in the buffer’s prompts (also[[and]]with evil-mode)M-p/M-n- go back and forward in the input historyC-c C-u- delete the current input string backwards up to the cursorcounsel-shell-history- A searchable history of commands typed into the shell
One advantage of shell-mode on Windows is that it’s the only way to run cmd.exe, PowerShell, Git Bash, etc from within Emacs. Here’s an example of how you would set up shell-mode to run PowerShell on Windows:
(when (eq system-type 'windows-nt)
(setq explicit-shell-file-name "powershell.exe")
(setq explicit-powershell.exe-args '()))
Eshell is Emacs’ own shell implementation written in Emacs Lisp. It provides you with a cross-platform implementation (even on Windows!) of the common GNU utilities you would find on Linux and macOS (ls, rm, mv, grep, etc). It also allows you to call Emacs Lisp functions directly from the shell and you can even set up aliases (like aliasing vim to find-file). Eshell is also an Emacs Lisp REPL which allows you to evaluate full expressions at the shell.
The downsides to Eshell are that it can be harder to configure than other packages due to the particularity of where you need to set some options for them to go into effect, the lack of shell completions (by default) for some useful things like Git commands, and that REPL programs sometimes don’t work as well. However, many of these limitations can be dealt with by good configuration and installing external packages, so don’t let that discourage you from trying it!
Useful key bindings:
C-c C-p/C-c C-n- go back and forward in the buffer’s prompts (also[[and]]with evil-mode)M-p/M-n- go back and forward in the input historyC-c C-u- delete the current input string backwards up to the cursorcounsel-esh-history- A searchable history of commands typed into Eshell
We will be covering Eshell more in future videos highlighting other things you can do with it.
For more thoughts on Eshell, check out these articles by Pierre Neidhardt:
- https://ambrevar.xyz/emacs-eshell/index.html
- https://ambrevar.xyz/emacs-eshell-versus-shell/index.html
(defun efs/configure-eshell ()
;; Save command history when commands are entered
(add-hook 'eshell-pre-command-hook 'eshell-save-some-history)
;; Truncate buffer for performance
(add-to-list 'eshell-output-filter-functions 'eshell-truncate-buffer)
;; Bind some useful keys for evil-mode
(evil-define-key '(normal insert visual) eshell-mode-map (kbd "C-r") 'counsel-esh-history)
(evil-define-key '(normal insert visual) eshell-mode-map (kbd "<home>") 'eshell-bol)
(evil-normalize-keymaps)
(setq eshell-history-size 10000
eshell-buffer-maximum-lines 10000
eshell-hist-ignoredups t
eshell-scroll-to-bottom-on-input t))
(use-package eshell-git-prompt
:after eshell)
(use-package eshell
:hook (eshell-first-time-mode . efs/configure-eshell)
:config
(with-eval-after-load 'esh-opt
(setq eshell-destroy-buffer-when-process-dies t)
(setq eshell-visual-commands '("htop" "zsh" "vim" "ps")))
(eshell-git-prompt-use-theme 'powerline))
Dired is a built-in file manager for Emacs that does some pretty amazing things! Here are some key bindings you should try out:
(use-package dired-sidebar
:ensure t
:commands (dired-sidebar-toggle-sidebar)
:bind (("C-x C-n" . dired-sidebar-toggle-sidebar)))Emacs / Evil
n/j- next linep/k- previous linej/J- jump to file in bufferRET- select file or directory^- go to parent directoryS-RET/g O- Open file in “other” windowM-RET- Show file in other window without focusing (previewing files)g o(dired-view-file) - Open file but in a “preview” mode, close withqg/g rRefresh the buffer withrevert-bufferafter changing configuration (and after filesystem changes!)
m- Marks a fileu- Unmarks a fileU- Unmarks all files in buffer* t/t- Inverts marked files in buffer% m- Mark files in buffer using regular expression*- Lots of other auto-marking functionsk/K- “Kill” marked items (refresh buffer withg/g rto get them back)- Many operations can be done on a single file if there are no active marks!
C- Copy marked files (or if no files are marked, the current file)- Copying single and multiple files
U- Unmark all files in bufferR- Rename marked files, renaming multiple is a move!% R- Rename based on regular expression:^test,old-\&
Power command: C-x C-q (dired-toggle-read-only) - Makes all file names in the buffer editable directly to rename them! Press Z Z to confirm renaming or Z Q to abort.
D- Delete marked filed- Mark file for deletionx- Execute deletion for marksdelete-by-moving-to-trash- Move to trash instead of deleting permanently
Z- Compress or uncompress a file or folder to (.tar.gz)c- Compress selection to a specific filedired-compress-files-alist- Bind compression commands to file extension
T- Touch (change timestamp)M- Change file modeO- Change file ownerG- Change file groupS- Create a symbolic link to this fileL- Load an Emacs Lisp file into Emacs
(use-package dired
:ensure nil
:commands (dired dired-jump)
:bind (("C-x C-j" . dired-jump))
:custom ((dired-listing-switches "-agho --group-directories-first"))
:config
(evil-collection-define-key 'normal 'dired-mode-map
"h" 'dired-single-up-directory
"l" 'dired-single-buffer))
(use-package dired-single
:commands (dired dired-jump))
(use-package all-the-icons-dired
:hook (dired-mode . all-the-icons-dired-mode))
(use-package dired-open
:commands (dired dired-jump)
:config
;; Doesn't work as expected!
;;(add-to-list 'dired-open-functions #'dired-open-xdg t)
(setq dired-open-extensions '(("png" . "feh")
("mkv" . "mpv"))))
(use-package dired-hide-dotfiles
:hook (dired-mode . dired-hide-dotfiles-mode)
:config
(evil-collection-define-key 'normal 'dired-mode-map
"H" 'dired-hide-dotfiles-mode))
This is an example of configuring another non-Emacs application using org-mode. Not only do we write out the configuration at .config/some-app/config, we also compute the value that gets stored in this configuration from the Emacs Lisp block above it.
(+ 55 100)
NOTE: Set the :tangle parameter below to .config/some-app/config for this to work!
value=<<the-value()>>
Dial the GC threshold back down so that garbage collection happens more frequently but in less time.
;; Make gc pauses faster by decreasing the threshold.
(setq gc-cons-threshold (* 2 1000 1000))