build.gradle

plugins {
    id 'java'
    id 'com.github.johnrengelman.shadow' version '8.1.1'
}

group = 'fr.hashtek.spigot'
version = 'D0.0.4-SNAPSHOT'

def hashrc = '/home/shuvly/Hashtek/hashrc'
def libsFolder = 'libs'

repositories {
    mavenCentral()
}

configurations {
    implementation.canBeResolved = true
}

dependencies {
    implementation fileTree(dir: libsFolder, include: ['*.jar'])
}

def targetJavaVersion = 16
java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'

    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        options.release.set(targetJavaVersion)
    }
}

processResources {
    def props = [
        name: rootProject.name,
        version: version
    ]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }
}

shadowJar {
    exclude '**/Tekore-*.jar'
    exclude '**/spigot-*.jar'

    archiveClassifier.set('')

    mergeServiceFiles()
    minimize()
}

tasks.register('make', Copy) {
    from ('build/libs/')
    into hashrc
    include '*.jar'
}

tasks.make.dependsOn shadowJar