-
Notifications
You must be signed in to change notification settings - Fork 6
/
Copy pathadvanced_observer.sma
1787 lines (1399 loc) · 40.2 KB
/
advanced_observer.sma
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
// AdvancedObserver by lonewolf <[email protected]>
// https://github.com/igorkelvin/amxx-plugins
#include <amxmodx>
#include <hamsandwich>
#include <cstrike>
#include <engine>
#include <fakemeta>
#include <fakemeta_stocks>
#include <xs>
#define PLUGIN "Advanced Observer"
#define VERSION "0.6.4"
#define AUTHOR "lonewolf"
#define URL "https://github.com/igorkelvin/amxx-plugins"
#define PREFIX "^4[AdvancedObserver]^1"
#define DEBUG_ENABLED true
#if DEBUG_ENABLED == true
#define DEBUG(%1) client_print(%1)
#else
public do_nothing(...) {}
#define DEBUG(%1) do_nothing(%1)
#endif /* DEBUG_ENABLED == true */
#define USER_ENABLED(%1) (camera_enabled_bits & (1 << ((%1) - 1)))
#define IS_CAMERA_GRENADE_SET(%1) (camera_grenade_bits & (1 << ((%1) - 1)))
#define IS_THIS_GRENADE_C4(%1) (get_ent_data((%1), "CGrenade", "m_bIsC4"))
#define IS_THIS_A_POPPED_SMOKE(%1) (get_ent_data((%1), "CGrenade", "m_SGSmoke"))
// https://github.com/s1lentq/ReGameDLL_CS/blob/efb06a7a201829bdbe13218bc5f5342e1f2ed8f1/regamedll/pm_shared/pm_shared.h#L66
#define PM_VEC_DUCK_VIEW 12
#define PM_VEC_VIEW 17
#define TASK_ID_DEBUG 11515
#define TASK_ID_FAKEINPUT 47653
enum
{
CAMERA_MODE_SPEC_ANYONE = 0,
CAMERA_MODE_SPEC_ONLY_TEAM,
CAMERA_MODE_SPEC_ONLY_FIRST_PERSON
};
static const FLAG_CLASSNAME[] = "ctf_flag";
static const Float:zeros[3] = {0.0, 0.0, 0.0};
static const colors[CsTeams][3] =
{
{ 0, 0, 0},
{255, 50, 0},
{ 0, 50, 255},
{ 0, 0, 0},
};
new MSG_ID_SCREENFADE;
new MSG_ID_CROSSHAIR;
new MSG_ID_SPECHEALTH;
new MSG_ID_BARTIME;
new MSG_ID_BARTIME2;
new entities_flag[CsTeams];
new entity_c4 = 0;
new Float:next_action[MAX_PLAYERS+1];
new player_aimed[MAX_PLAYERS+1];
new last_target[MAX_PLAYERS+1];
new bool:player_fixangle[MAX_PLAYERS+1];
enum FlagEvent
{
FLAG_STOLEN = 0,
FLAG_PICKED,
FLAG_DROPPED,
FLAG_MANUALDROP,
FLAG_RETURNED,
FLAG_CAPTURED,
FLAG_AUTORETURN,
FLAG_ADMINRETURN
};
enum Direction
{
NO_DIRECTION = 0,
RIGHT,
LEFT,
FORWARD,
BACK
};
enum Entities
{
NO_ENTITY = 0,
C4,
FLAG_RED,
FLAG_BLUE
};
new Entities:player_follow[MAX_PLAYERS+1];
new bool:player_follow_once[MAX_PLAYERS+1];
new camera_hooked[MAX_PLAYERS + 1];
new camera_grenade_to_follow[MAX_PLAYERS+1];
new camera_ent_to_follow[MAX_PLAYERS+1];
new camera_grenade_bits = 0x00000000;
new camera_enabled_bits = 0x00000000;
new camera_debug_bits = 0x00000000;
new cvar_fadetoblack;
new cvar_forcechasecam;
new cvar_forcecamera;
new hudsync1;
new menuid_fakeinput;
public plugin_init()
{
register_plugin(PLUGIN, VERSION, AUTHOR);
register_clcmd("say /obs", "cmd_obs");
register_clcmd("say /obsdebug", "cmd_obsdebug", ADMIN_CVAR);
register_clcmd("+camera_c4", "camera_ent_c4");
register_clcmd("-camera_c4", "camera_ent_unset");
register_clcmd("+camera_flag_red", "camera_ent_flag_red");
register_clcmd("-camera_flag_red", "camera_ent_unset");
register_clcmd("+camera_flag_blue", "camera_ent_flag_blue");
register_clcmd("-camera_flag_blue", "camera_ent_unset");
register_clcmd("+camera_chase", "camera_chase_set");
register_clcmd("-camera_chase", "camera_chase_unset");
register_clcmd("+camera_hook", "camera_hook_set");
register_clcmd("-camera_hook", "camera_hook_unset");
register_clcmd("+camera_grenade", "camera_grenade_set");
register_clcmd("-camera_grenade", "camera_grenade_unset");
register_clcmd("say /debug", "debug_print", ADMIN_CVAR);
MSG_ID_SCREENFADE = get_user_msgid("ScreenFade");
MSG_ID_CROSSHAIR = get_user_msgid("Crosshair");
MSG_ID_SPECHEALTH = get_user_msgid("SpecHealth");
MSG_ID_BARTIME = get_user_msgid("BarTime");
MSG_ID_BARTIME2 = get_user_msgid("BarTime2");
// register_event("ScreenFade", "event_flashed", "b", "7=255");
register_message(MSG_ID_SCREENFADE, "msg_ScreenFade");
// RegisterHam(Ham_Spawn, "player", "event_player_spawned", .Post = true);
RegisterHam(Ham_Killed, "player", "event_player_killed", .Post = true);
RegisterHam(Ham_Think, "grenade", "think_grenade");
register_event("TeamInfo", "event_player_joined_team", "a");
register_event("ScoreAttrib", "event_pickedthebomb", "bc", "2=2");
register_logevent("event_droppedthebomb", 3, "2=Dropped_The_Bomb");
register_logevent("event_plantedthebomb", 3, "2=Planted_The_Bomb");
cvar_fadetoblack = get_cvar_pointer("mp_fadetoblack");
cvar_forcechasecam = get_cvar_pointer("mp_forcechasecam");
cvar_forcecamera = get_cvar_pointer("mp_forcecamera");
hudsync1 = CreateHudSyncObj();
menuid_fakeinput = register_menuid("fakeinput");
register_menucmd(menuid_fakeinput, 1023, "menu_fakeinput_handler");
new task_id = 5032;
set_task(5.0, "task_find_flag_holders", task_id);
}
public event_pickedthebomb()
{
new id = read_data(1);
if (is_user_alive(id))
{
entity_c4 = id;
}
}
public event_droppedthebomb()
{
set_task(0.1, "event_droppedthebomb_delayed", 25263);
}
public event_droppedthebomb_delayed()
{
new c4_ent = find_ent_by_class(0, "weapon_c4");
if (!c4_ent)
{
entity_c4 = 0;
return;
}
new weaponbox = entity_get_edict(c4_ent, EV_ENT_owner);
if (is_user_connected(weaponbox)) // owner is still a player, not the weaponbox
{
entity_c4 = 0;
set_task(0.1, "event_droppedthebomb_delayed", 25263);
return;
}
entity_c4 = weaponbox;
}
public event_plantedthebomb()
{
new c4_ent = -1;
new is_c4 = 0;
while((c4_ent = find_ent_by_class(c4_ent, "grenade")))
{
is_c4 = IS_THIS_GRENADE_C4(c4_ent);
if (is_c4)
{
break;
}
}
if ((c4_ent <= 0) || !is_c4)
{
return;
}
entity_c4 = c4_ent;
}
public debug_print(id)
{
if (!camera_debug_bits)
{
return PLUGIN_HANDLED;
}
for (new id = 1; id < MAX_PLAYERS; ++id)
{
if (!(camera_debug_bits & (1 << id-1)))
{
continue;
}
new observer_target = get_ent_data_entity(id, "CBasePlayer", "m_hObserverTarget");
new observer_lastmode = get_ent_data(id, "CBasePlayer", "m_iObserverLastMode");
new observer_wasfollowing = get_ent_data(id, "CBasePlayer", "m_bWasFollowing");
new observer_canswitch = get_ent_data(id, "CBasePlayer", "m_canSwitchObserverModes");
DEBUG(id, print_chat, "[DEBUG 1/3] target: %d, lastmode: %d, wasfollowing: %s, canswitch: %s", observer_target, observer_lastmode, observer_wasfollowing ? "true" : "false", observer_canswitch ? "true" : "false");
new iuser1 = entity_get_int(id, EV_INT_iuser1);
new iuser2 = entity_get_int(id, EV_INT_iuser2);
new iuser3 = entity_get_int(id, EV_INT_iuser3);
DEBUG(id, print_chat, "[DEBUG 2/3] iuser{1,2,3}: {%d, %d, %d}", iuser1, iuser2, iuser3);
new Float:next_observer_input = get_ent_data_float(id, "CBasePlayer", "m_flNextObserverInput");
DEBUG(id, print_chat, "[DEBUG 3/3] m_flNextObserverInput: %.1f", next_observer_input);
}
return PLUGIN_HANDLED;
}
public client_cmdStart(id)
{
if (!is_user_connected(id) || is_user_alive(id) || !USER_ENABLED(id))
{
return PLUGIN_CONTINUE;
}
new buttons = get_usercmd(usercmd_buttons);
new oldbuttons = get_user_oldbutton(id);
new pressed = (buttons ^ oldbuttons) & buttons;
new released = (buttons ^ oldbuttons) & oldbuttons;
if (released & IN_RELOAD)
{
camera_grenade_unset(id);
}
if (!(pressed & (IN_JUMP | IN_ATTACK | IN_ATTACK2 | IN_RELOAD | IN_MOVELEFT | IN_MOVERIGHT | IN_BACK | IN_FORWARD)))
{
return PLUGIN_CONTINUE;
}
new Float:now = get_gametime();
if (now < next_action[id])
{
return PLUGIN_CONTINUE;
}
next_action[id] = now + 0.2;
if (pressed & IN_JUMP)
{
new mode = entity_get_int(id, EV_INT_iuser1);
new nextmode;
switch (mode)
{
case OBS_CHASE_LOCKED: nextmode = OBS_IN_EYE;
case OBS_CHASE_FREE: nextmode = OBS_IN_EYE;
case OBS_IN_EYE: nextmode = OBS_ROAMING;
case OBS_ROAMING: nextmode = OBS_IN_EYE;
case OBS_MAP_FREE: nextmode = OBS_IN_EYE;
default: nextmode = OBS_IN_EYE;
}
observer_set_mode(id, nextmode);
}
else if (pressed & IN_ATTACK)
{
new obs_mode = entity_get_int(id, EV_INT_iuser1);
if (obs_mode == OBS_ROAMING)
{
new closest = observer_find_next_player_direction(id, FORWARD, 2000.0, _, .target=id);
if (closest)
{
observer_set_mode(id, OBS_IN_EYE);
}
}
else
{
observer_find_next_player(id, .reverse=false);
}
}
else if (pressed & IN_ATTACK2)
{
new obs_mode = entity_get_int(id, EV_INT_iuser1);
if (obs_mode == OBS_ROAMING)
{
observer_set_mode(id, OBS_IN_EYE);
}
else
{
observer_find_next_player(id, .reverse=true, .target=last_target[id]);
}
}
else if (pressed & IN_RELOAD)
{
camera_grenade_set(id);
}
else
{
new obs_mode = entity_get_int(id, EV_INT_iuser1);
if (obs_mode != OBS_ROAMING)
{
if (pressed & IN_MOVERIGHT)
{
observer_find_next_player_direction(id, RIGHT, .maxdistance=2000.0);
}
else if (pressed & IN_MOVELEFT)
{
observer_find_next_player_direction(id, LEFT, .maxdistance=2000.0);
}
else if (pressed & IN_FORWARD)
{
observer_find_next_player_direction(id, FORWARD, .maxdistance=2000.0);
}
else if (pressed & IN_BACK)
{
observer_find_next_player_direction(id, BACK, .maxdistance=2000.0);
}
}
}
return PLUGIN_CONTINUE;
}
stock observer_update_client_effects(id, old_mode)
{
new bool:clear_progress = false;
new bool:clear_blindness = false;
new bool:clear_nightvision = false;
new bool:blindness_ok = get_pcvar_num(cvar_fadetoblack) == 0;
if (entity_get_int(id, EV_INT_iuser1) == OBS_IN_EYE)
{
clear_progress = true;
clear_blindness = true;
clear_nightvision = true;
new player = get_ent_data_entity(id, "CBasePlayer", "m_hObserverTarget");
if (is_user_connected(player))
{
new Float:progress_start = get_ent_data_float(player, "CBasePlayer", "m_progressStart");
if (progress_start > 0.0)
{
new Float:progress_end = get_ent_data_float(player, "CBasePlayer", "m_progressEnd");
if (progress_end > progress_start)
{
new Float:now = get_gametime();
if (progress_end > now)
{
new Float:percent_remaining = now - progress_start;
new bar_time = floatround(progress_end - progress_start, floatround_floor);
CBasePlayer_SetProgressBarTime2(id, bar_time, percent_remaining);
clear_progress = false;
}
}
}
if (blindness_ok)
{
new Float:start_time = get_ent_data_float(player, "CBasePlayer", "m_blindStartTime");
new Float:fade_time = get_ent_data_float(player, "CBasePlayer", "m_blindFadeTime");
if (start_time != 0.0 && fade_time != 0.0)
{
new Float:hold_time = get_ent_data_float(player, "CBasePlayer", "m_blindHoldTime");
new Float:end_time = fade_time + hold_time + start_time;
new Float:now = get_gametime();
if (end_time > now)
{
clear_blindness = false;
new alpha = get_ent_data(player, "CBasePlayer", "m_blindAlpha");
hold_time = hold_time + start_time - now;
if (hold_time <= 0.0)
{
hold_time = 0.0;
new Float:ratio = (end_time - now) / fade_time;
alpha = floatround(float(alpha) * ratio);
fade_time *= ratio;
}
if (alpha == 255)
{
fade_screen(id, hold_time, fade_time, 0, 255, 255, 255, 180);
set_hudmessage(200, 50, 0, -1.0, -1.0, 1, hold_time, hold_time, 0.1, 0.1, -1);
ShowSyncHudMsg(id, hudsync1, "[FLASHED]");
}
else
{
fade_screen(id, hold_time, fade_time, 0, 255, 255, 255, alpha);
ClearSyncHud(id, hudsync1);
}
}
}
}
// TODO
// clear nightvision
}
}
else if (old_mode == OBS_IN_EYE)
{
clear_progress = true;
clear_blindness = true;
clear_nightvision = true;
}
if (clear_progress)
{
CBasePlayer_SetProgressBarTime(id, 0);
}
if (blindness_ok && clear_blindness)
{
fade_screen(id, 0.001, 0.0, 0, 0, 0, 0, 0);
ClearSyncHud(id, hudsync1);
}
// TODO
// if (clear_nightvision)
// {
// }
}
stock CBasePlayer_SetProgressBarTime(id, time = 0)
{
if (time)
{
new Float:now = get_gametime();
set_ent_data_float(id, "CBasePlayer", "m_progressStart", now);
set_ent_data_float(id, "CBasePlayer", "m_progressEnd", now + time);
}
else
{
set_ent_data_float(id, "CBasePlayer", "m_progressStart", 0.0);
set_ent_data_float(id, "CBasePlayer", "m_progressEnd", 0.0);
}
message_begin(MSG_ONE_UNRELIABLE, MSG_ID_BARTIME, _, id);
write_short(time);
message_end();
}
stock CBasePlayer_SetProgressBarTime2(id, time = 0, Float:time_elapsed)
{
new Float:progress_start = 0.0;
new Float:progress_end = 0.0;
if (time)
{
new Float:now = get_gametime();
progress_start = now - time_elapsed;
progress_end = now + time - time_elapsed;
set_ent_data_float(id, "CBasePlayer", "m_progressStart", progress_start);
set_ent_data_float(id, "CBasePlayer", "m_progressEnd", progress_end);
}
else
{
time_elapsed = 0.0;
set_ent_data_float(id, "CBasePlayer", "m_progressStart", 0.0);
set_ent_data_float(id, "CBasePlayer", "m_progressEnd", 0.0);
}
new start_percent = floatround((time_elapsed * 100.0) / (progress_end - progress_start));
message_begin(MSG_ONE_UNRELIABLE, MSG_ID_BARTIME2, _, id);
write_short(time);
write_short(start_percent);
message_end();
}
stock observer_find_next_player(id, reverse=false, target=0, CsTeams:force_team=CS_TEAM_UNASSIGNED)
{
new CsTeams:team = cs_get_user_team(id);
new bool:same_team = get_force_camera() != CAMERA_MODE_SPEC_ANYONE && team != CS_TEAM_SPECTATOR;
new start = get_ent_data_entity(id, "CBasePlayer", "m_hObserverTarget");
new newtarget = 0;
if (target)
{
newtarget = observer_is_valid_target(id, target, same_team, force_team);
}
else
{
new dir = reverse ? -1 : 1;
if (!is_user_connected(start))
{
start = id;
}
new current = start;
new count = 0;
do
{
current += dir;
if (current >= MaxClients)
{
current = 1;
}
else if (current < 1)
{
current = MaxClients;
}
newtarget = observer_is_valid_target(id, current, same_team, force_team);
if (newtarget)
{
break;
}
count++;
}
while (current != start || count > 32)
}
if (newtarget)
{
if (start && start != newtarget)
{
last_target[id] = start;
}
camera_move_to_eyes(id);
set_ent_data_entity(id, "CBasePlayer", "m_hObserverTarget", newtarget);
new Float:health = entity_get_float(newtarget, EV_FL_health);
if (health < 0.0)
{
entity_set_float(newtarget, EV_FL_health, 0.0);
}
message_begin(MSG_ONE_UNRELIABLE, MSG_ID_SPECHEALTH, _, id);
write_byte(floatround(health));
message_end();
new mode = entity_get_int(id, EV_INT_iuser1);
if (mode != OBS_ROAMING)
{
entity_set_int(id, EV_INT_iuser2, newtarget);
}
observer_update_client_effects(id, mode);
}
return newtarget;
}
stock observer_find_next_player_direction(id, Direction:dir, Float:maxdistance = 500.0, CsTeams:force_team=CS_TEAM_UNASSIGNED, target=0)
{
new current = target;
if (!is_user_connected(target))
{
current = get_ent_data_entity(id, "CBasePlayer", "m_hObserverTarget");
if (!is_valid_ent(current))
{
return 0;
}
}
new Float:id_origin[3];
entity_get_vector(current, EV_VEC_origin, id_origin);
new Float:angles[3];
entity_get_vector(current, EV_VEC_v_angle, angles)
angles[0] = 0.0;
angles[2] = 0.0;
EF_MakeVectors(angles);
new Float:closest_distance = 9999.9;
new closest = 0;
new Float:direction[3];
switch (dir)
{
case NO_DIRECTION:
{
return closest;
}
case RIGHT:
{
get_global_vector(GL_v_right, direction);
}
case LEFT:
{
get_global_vector(GL_v_right, direction);
xs_vec_neg(direction, direction);
}
case FORWARD:
{
get_global_vector(GL_v_forward, direction);
}
case BACK:
{
get_global_vector(GL_v_forward, direction);
xs_vec_neg(direction, direction);
}
}
new CsTeams:team = cs_get_user_team(id);
new bool:same_team = get_force_camera() != CAMERA_MODE_SPEC_ANYONE && team != CS_TEAM_SPECTATOR;
for (new target = 1; target <= MaxClients; ++target)
{
if (id == target || target == current || !is_user_alive(target))
{
continue;
}
target = observer_is_valid_target(id, target, same_team, force_team);
if (!target)
{
continue;
}
new Float:target_origin[3];
entity_get_vector(target, EV_VEC_origin, target_origin);
target_origin[2] *= 2.0; // Prioritize targets in the same height
new Float:distance = xs_vec_distance(id_origin, target_origin);
target_origin[2] *= 0.5;
if (distance > maxdistance || distance > closest_distance)
{
continue;
}
xs_vec_sub(target_origin, id_origin, target_origin);
xs_vec_normalize(target_origin, target_origin);
new Float:cosine = xs_vec_dot(target_origin, direction);
new Float:angle = floatacos(cosine, degrees);
if (angle <= 45.0)
{
closest_distance = distance;
closest = target;
}
}
if (closest)
{
if (current && current != closest)
{
last_target[id] = current;
}
camera_move_to_eyes(id);
set_ent_data_entity(id, "CBasePlayer", "m_hObserverTarget", closest);
new Float:health = entity_get_float(closest, EV_FL_health);
if (health < 0.0)
{
entity_set_float(closest, EV_FL_health, 0.0);
}
message_begin(MSG_ONE_UNRELIABLE, MSG_ID_SPECHEALTH, _, id);
write_byte(floatround(health));
message_end();
new mode = entity_get_int(id, EV_INT_iuser1);
if (mode != OBS_ROAMING)
{
entity_set_int(id, EV_INT_iuser2, closest);
}
observer_update_client_effects(id, mode);
}
return closest;
}
public get_force_camera()
{
new ret;
new fadetoblack = get_pcvar_num(cvar_fadetoblack);
if (!fadetoblack)
{
ret = get_pcvar_num(cvar_forcechasecam);
if (ret == CAMERA_MODE_SPEC_ANYONE)
{
ret = get_pcvar_num(cvar_forcecamera);
}
}
else
{
ret = CAMERA_MODE_SPEC_ONLY_FIRST_PERSON;
}
return ret;
}
stock observer_is_valid_target(id, target, bool:same_team=false, CsTeams:team=CS_TEAM_UNASSIGNED)
{
if (id == target || !is_user_alive(target))
{
return 0;
}
new obs_mode = entity_get_int(target, EV_INT_iuser1);
new effects = entity_get_int(target, EV_INT_effects);
new CsTeams:team_target = cs_get_user_team(target);
new CsTeams:team_id = cs_get_user_team(id);
new bool:is_observer = (obs_mode != OBS_NONE);
new bool:cannot_see_entities = bool:(effects & EF_NODRAW);
new bool:not_playing = (team_target != CS_TEAM_T && team_target != CS_TEAM_CT);
new bool:not_in_same_team = (same_team && (team_target != team_id && team_id != CS_TEAM_SPECTATOR));
new bool:not_in_wanted_team = (team && (team_target != team));
if (is_observer || cannot_see_entities || not_playing || not_in_same_team || not_in_wanted_team)
{
return 0;
}
return target;
}
public observer_set_mode(id, mode)
{
if (!is_user_connected(id))
{
return;
}
new old_mode = entity_get_int(id, EV_INT_iuser1);
if (old_mode == mode)
{
return;
}
new forcecamera = get_force_camera();
new CsTeams:team = cs_get_user_team(id);
if (team != CS_TEAM_SPECTATOR)
{
if (forcecamera == CAMERA_MODE_SPEC_ONLY_TEAM)
{
if (mode == OBS_ROAMING)
{
mode = OBS_MAP_FREE; // is this correct?
}
}
else if (forcecamera == CAMERA_MODE_SPEC_ONLY_FIRST_PERSON)
{
mode = OBS_IN_EYE;
}
}
new target = get_ent_data_entity(id, "CBasePlayer", "m_hObserverTarget");
if (target)
{
target = observer_is_valid_target(id, target);
}
entity_set_int(id, EV_INT_iuser1, mode);
if (mode == OBS_ROAMING)
{
target = 0;
}
else
{
if (!target)
{
target = observer_find_next_player(id);
if (!target)
{
mode = OBS_ROAMING;
entity_set_int(id, EV_INT_iuser1, OBS_ROAMING);
}
}
}
entity_set_int(id, EV_INT_iuser2, target);
entity_set_int(id, EV_INT_iuser3, 0);
camera_move_to_eyes(id);
set_observer_crosshair(id, mode);
set_ent_data(id, "CBasePlayer", "m_iObserverLastMode", mode);
set_ent_data(id, "CBasePlayer", "m_bWasFollowing", 0);
observer_update_client_effects(id, old_mode);
}
public client_PostThink(id)
{
if (!is_user_connected(id) || is_user_alive(id) || !USER_ENABLED(id))
{
return PLUGIN_CONTINUE;
}
new grenade = camera_grenade_to_follow[id];
if (is_valid_ent(grenade))
{
new grenade_owner = entity_get_edict(grenade, EV_ENT_owner);
if (is_user_connected(grenade_owner))
{
camera_follow_grenade(id, grenade);
}
return PLUGIN_CONTINUE;
}
camera_grenade_to_follow[id] = 0;
new Entities:follow = player_follow[id];
switch (follow)
{
case NO_ENTITY: {}
case C4: camera_follow_c4(id);
case FLAG_RED: camera_follow_flag(id, follow);
case FLAG_BLUE: camera_follow_flag(id, follow);
}
if (follow && player_follow_once[id])
{
player_follow[id] = NO_ENTITY;
}
return PLUGIN_CONTINUE;
}
public camera_follow_grenade(id, grenade)
{
new Float:origin[3];
new Float:spec_origin[3];
new Float:velocity[3];
new Float:angles[3];
entity_get_vector(grenade, EV_VEC_origin, origin);
entity_get_vector(grenade, EV_VEC_velocity, velocity);
new Float:speed = xs_vec_len(velocity);
if (speed < 5.0)
{
return PLUGIN_CONTINUE;
}
xs_vec_copy(origin, spec_origin);
xs_vec_div_scalar(velocity, speed, velocity);
// https://github.com/s1lentq/ReGameDLL_CS/blob/f57d28fe721ea4d57d10c010d15d45f05f2f5bad/regamedll/dlls/wpn_shared/wpn_flashbang.cpp#L191
// Max grenade speed should be 750
speed = 100 + 0.2 * speed;
xs_vec_add_scaled(spec_origin, velocity, -1.0 * speed, spec_origin);
spec_origin[2] += 10.0;
new trace;
new Float:fraction;
engfunc(EngFunc_TraceLine, origin, spec_origin, IGNORE_MONSTERS, 0, trace);
get_tr2(trace, TR_flFraction, fraction);
if (fraction < 1.0)
{
spec_origin[0] += velocity[0] * speed * (1 - (fraction * 0.8));
spec_origin[1] += velocity[1] * speed * (1 - (fraction * 0.8));
spec_origin[2] += velocity[2] * speed * (1 - (fraction * 0.8));
}
new Float:dir[3];
xs_vec_sub(origin, spec_origin, dir);
vector_to_angle(dir, angles);
angles[0] *= -1.0;
observer_set_mode(id, OBS_ROAMING);
entity_set_origin(id, spec_origin);
entity_set_vector(id, EV_VEC_angles, angles);
entity_set_vector(id, EV_VEC_v_angle, angles);
entity_set_vector(id, EV_VEC_punchangle, zeros);
entity_set_int(id, EV_INT_fixangle, 1);
return PLUGIN_HANDLED;
}
public camera_move_to_eyes(id)
{
if (is_user_alive(id))
{
return PLUGIN_CONTINUE;
}
new target = get_ent_data_entity(id, "CBasePlayer", "m_hObserverTarget");
if (!is_user_alive(target))
{
return PLUGIN_CONTINUE;
}
new Float:eyes[3];
new Float:view_ofs[3];
entity_get_vector(target, EV_VEC_origin, eyes);
entity_get_vector(target, EV_VEC_view_ofs, view_ofs);
xs_vec_add(eyes, view_ofs, eyes);
new Float:angles[3];
entity_get_vector(target, EV_VEC_v_angle, angles);
EF_MakeVectors(angles);
new Float:v_forward[3];
get_global_vector(GL_v_forward, v_forward);
eyes[0] += v_forward[0] * 10;
eyes[1] += v_forward[1] * 10;
entity_set_origin(id, eyes);