build.gradle

task testBackend(type:Exec) {
    workingDir './backend'
    commandLine 'lein', 'test'
}

task testFrontend(type:Exec) {
    workingDir './frontend'
    commandLine 'yarn', 'test-run'
}

task testAll {
    dependsOn tasks.testBackend
    dependsOn tasks.testFrontend
}

task buildBackendUberJar(type:Exec) {
    dependsOn tasks.testBackend
    workingDir './backend'
    commandLine 'lein', 'do', 'clean,', 'ring', 'uberjar'
}

task buildBackendContainer(type:Exec) {
    dependsOn tasks.buildBackendUberJar
    workingDir './backend'
    commandLine 'docker', 'build', '-t', 'keeponherdin-backend', '.'
}

task buildFrontendContainer(type:Exec) {
    dependsOn tasks.testFrontend
    workingDir './frontend'
    commandLine 'docker', 'build', '-t', 'keeponherdin-frontend', '.'
}

task buildAllContainers {
    dependsOn tasks.buildBackendContainer
    dependsOn tasks.buildFrontendContainer
}

task pushBackend {
    dependsOn tasks.buildBackendContainer
    doLast {
        exec {
            commandLine 'docker', 'tag', 'keeponherdin-backend:latest', DOCKER_REPO_URL + 'keeponherdin-backend:latest'
        }
        exec {
            commandLine 'docker', 'push', DOCKER_REPO_URL + 'keeponherdin-backend:latest'
        }
    }
}

task pushFrontend {
    dependsOn tasks.buildFrontendContainer
    doLast {
        exec {
            commandLine 'docker', 'tag', 'keeponherdin-frontend:latest', DOCKER_REPO_URL + 'keeponherdin-frontend:latest'
        }
        exec {
            commandLine 'docker', 'push', DOCKER_REPO_URL + 'keeponherdin-frontend:latest'
        }
    }
}

task pushAll {
    dependsOn tasks.pushBackend
    dependsOn tasks.pushFrontend
}

task deployBackend {
    dependsOn tasks.pushBackend
    doLast {
        exec {
            commandLine 'gcloud', 'run', 'deploy', 'keeponherdin-backend', '--image', DOCKER_REPO_URL + 'keeponherdin-backend', '--region', 'us-central1', '--port', '8000', '--allow-unauthenticated'
        }
    }
}

task deployFrontend {
    dependsOn tasks.pushFrontend
    doLast {
        exec {
            commandLine 'gcloud', 'run', 'deploy', 'keeponherdin-frontend', '--image', DOCKER_REPO_URL + 'keeponherdin-frontend', '--region', 'us-central1', '--port', '80', '--allow-unauthenticated'
        }
    }
}

task deployAll {
    dependsOn tasks.deployFrontend
    dependsOn tasks.deployBackend
}