how to make the minibuffer grow when invoking eldoc with eldoc-display-in-echo-area enabled

[fommil]

Hi all,

I use the following eldoc setup with eglot so that I can manually trigger a call to eldoc only when I want it show me the docs (not on hovers or point movements or anything like that). Apologies if this is outdated, I haven't touched it in a year or so...

(add-hook
 'eglot-managed-mode-hook
 (lambda ()
   ;; we want eglot to setup callbacks from eldoc, but we don't want eldoc
   ;; running after every command. So we disable it after we just enabled it.
   (eldoc-mode -1)))
(defun eldoc-fancy (arg)
  "`eldoc' but uses the echo area by default and a prefix will swap to a buffer."
  ;; https://github.com/joaotavora/eglot/discussions/1328
  (interactive "P")
  (let (_)
    (defvar eldoc-display-functions)
    (setq eldoc-display-functions
          (if arg '(eldoc-display-in-buffer) '(eldoc-display-in-echo-area)))
    (eldoc t)))

However, even though I use the default eldoc-echo-area-use-multiline-p (truncate-sym-name-if-fit, but I also tried setting it to t), when the docs are echoed to the minibuffer it never grows more than 1 line. I don't have any custom value for max-mini-window-height (it's still the default 0.25).

When I prefix my command and therefore force it to use eldoc-display-in-buffer then I can see that sometimes the information is multi-line.

Here's an example of something I see from the rust-analyzer in the buffer

// Implements notable traits: Iterator<Item = (&String, &Lease)>
// size = 48 (0x30), align = 0x8
let available: Filter<Iter<'_, String, Lease>, impl FnMut(&(&String, &Lease)) -> bool>

but when I see this in the echo area it only gives me the first line. Notably there is no truncation message here (as per eldoc-echo-area-display-truncation-message which is t).

(as an aside, if I was given the power to customise the way this is truncated, I'd choose the last line not the first, but as a first step I'd like to be able to see everything)

My full emacs config, if anybody is so inclined to dig deeper, is https://gitlab.com/fommil/dotfiles/-/tree/master/.emacs.d

[joaotavora]

I think eldoc-display-in-echo-area, the display function, is already setup to display the "short" version of each documentation function in eldoc-documentation-functions (there may be many, and Eglot normally uses 3) . eldoc-display-in-buffer is not and it displays the full version. So eldoc-display-in-echo-area displays multiple short versions of each doc function, and it is that pre-filtered whole that honours eldoc-echo-area-use-multiline-p ,not each documentation excerpt separately.

Therefore, what you possibly want is to replace one of Eglot's documentation functions with one of your own doing:

(defun my/special-eglot-hover-function (cb)
  "Same as `eglot-hover-eldoc-function`, but throw away its short :echo cookie"
  (eglot-hover-eldoc-function (lambda (info &rest _ignore)
                                ;; ignore the :echo cookie that eglot-hover-eldoc-function offers
                                (funcall cb info))))

(add-hook
 'eglot-managed-mode-hook
 (lambda ()
   (setq-local eldoc-documentation-functions (cl-substitute #'my/special-eglot-hover-function 'eglot-hover-eldoc-function eldoc-documentation-functions))
   ;; we want eglot to setup callbacks from eldoc, but we don't want eldoc
   ;; running after every command. So we disable it after we just enabled it.
   (eldoc-mode -1)))

[fommil]

that's great, thank you! Do you have any appetite to provide a setting that would make eldoc-display-in-echo-area use the full version instead of the short version? The echo area already has a mechanism to truncate the output so it wouldn't be opening pandora's box completely.

[joaotavora]

That is possible yes, but there are already so many settings controlling the display of that very limited area and so many (believe me, MANY) different user preferences, that I tend to think it just adds more noise. At least that was my opinion when I mantained eldoc. I don't anymore, so feel free to request this in the bug list. No need to put me in CC. Maybe to avoid making a new custom option you can overload the existing eldoc-echo-area-use-multiline-p with new value or a function. Good luck!