build.gradle

buildscript {
    repositories {
        google()
    }
    dependencies {
        classpath libs.oss.plugin
        classpath libs.navigation.safeargs
        classpath libs.gms.plugin
        classpath libs.firebase.crashlytics.plugin
        classpath libs.firebase.performance.plugin
    }
}

plugins {
    alias(libs.plugins.android.application) apply false
    alias(libs.plugins.android.library) apply false
    alias(libs.plugins.android.test) apply false
    alias(libs.plugins.android.kotlin) apply false
    alias(libs.plugins.jacoco.android) apply false
    alias(libs.plugins.junit5.android) apply false
    alias(libs.plugins.hilt) apply false
    alias(libs.plugins.compose.compiler.report) apply false
    alias(libs.plugins.detekt)
}

allprojects {
    apply plugin: "io.gitlab.arturbosch.detekt"
    apply from: "${this.rootDir}/gradle/groups.gradle"
    apply from: "${this.rootDir}/gradle/config.gradle"

    detekt detektOption

    dependencies {
        detektPlugins libs.bundles.detekt.rules
    }
}

// https://docs.gradle.org/current/userguide/performance.html#disable_reports
tasks.withType(Test).configureEach {
    reports.html.required = System.getenv("CI").toBoolean()
    reports.junitXml.required = System.getenv("CI").toBoolean()
}

apply plugin: "android-reporting"